Live-Forum - Die aktuellen Beiträge
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Anzahl ungleiche Zellen mit einer Bedingung zählen

Anzahl ungleiche Zellen mit einer Bedingung zählen
Ingo4711
Hallo Forum,
ich möchte euch um Hilfe beim Zählen bitten.
Ich habe rund 5.000 Zeilen mit Auftragsdaten. Für alle Artikel eines jeden Auftrags möchte ich die Anzahl der unterschiedlichen Lieferanten zählen. Mit der Formel Summenprodukt bekomme ich die Bedingung 'zähle nur unterschiedliche' nicht kombiniert.
Rohdaten:
Auftragsnr. Lieferant Menge
1 A 1
1 C 1
1 A 1
2 B 1
3 B 1
3 B 5
4 B 1
4 C 1
……
rund 5.000 Zeilen
In einer Hilfsspalte ermittele ich die unterschiedlichen Aufträge:

WENN(MAX(A:A)=MAX(E$3:E3);"";KGRÖSSTE(A:A;ZÄHLENWENN(A:A;">"&E3))) (Danke ans Forum!)
Auftragsnr. ZIEL: Anzahl der unterschiedliche Lieferanten zählen für einen bestimmten Auftrag
1 2 (da A+C)
2 1 (nur B)
3 1 (nur B)
4 2 (B und C)
Das Ziel erreiche ich leider nicht.
Viele Grüße
Ingo

6
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Benutzer
Anzeige
AW: Anzahl ungleiche Zellen mit einer Bedingung zählen
28.10.2011 11:51:26
guentherh
Lässt sich mit Pivot und einer Anzahl-Formel lösen
https://www.herber.de/bbs/user/77254.zip (Tabelle2)
Gruß,
Günther
AW: Anzahl ungleiche Zellen mit einer Bedingung zählen
28.10.2011 13:17:36
Ingo4711
Moin Günther,
herzlichen Dank für den Ansatz! Da bin ich nicht drauf gekommen.
So funktioniert es.
Viele Grüße
Ingo
Bedingte Anzahl ohne Duplikate - excelformeln
28.10.2011 11:55:59
Erich
Hi Ingo,
mit Formeln ginge das auch so:
 ABCDEFG
2NrLiefMenge    
31A1  Nr. 334Nr. 418
41C1 NrAnz Lieffalsch
51A1 122
62B1 211
73B1 310
83B5 420
94B1    
104C1    

Formeln der Tabelle
ZelleFormel
E5=A3
F5{=SUMME((VERGLEICH(A$3:A$5000&B$3:B$5000;A$3:A$5000&B$3:B$5000;0)=ZEILE($1:$4998)*(A$3:A$5000=E5)*(B$3:B$5000<>""))*1)}
G5=SUMMENPRODUKT((VERGLEICH(B$3:B$5000&"";B$3:B$5000&"";)=ZEILE($1:$4998))*(A$3:A$5000=E5)*(B$3:B$5000<>""))
E6=WENN(MAX(A:A)=MAX(E$5:E5); "";KGRÖSSTE(A:A;ZÄHLENWENN(A:A;">"&E5)))
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen

Die Formeln in F5 und G5 sind von www.excelformeln.de, wobei die in G5 leider falsch rechnet.
( siehe http://www.online-excel.de/fom/fo_read.php?f=1&bzh=0&h=59114 )
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: Bedingte Anzahl ohne Duplikate - excelformeln
28.10.2011 14:00:15
Ingo4711
Hallo Erich,
auch diese elegante Variante funktioniert wunderbar! Dankeschön.
Kannst du mir bitte auch erklären, was die Formel F5 tut?
Besten Dank
Ingo
Zwischenergebnisse
28.10.2011 17:06:24
Erich
Hi Ingo,
ehe ich mich in langen, umständlichen, unverständlichen Erklärungen versuche, hier mal eine Serie Zwischenergebnisse
für die Formel - reduziert auf die Zeilen 3 bis 10:
 A
1=SUMME((VERGLEICH(A$3:A$10&B$3:B$10;A$3:A$10&B$3:B$10;0)=ZEILE($1:$8)*(A$3:A$10=E5)*(B$3:B$10<>""))*1)
2=SUMME((VERGLEICH({"1A";"1C";"1A";"2B";"3B";"3B";"4B";"4C"};{"1A";"1C";"1A";"2B";"3B";"3B";"4B";"4C"};0)=ZEILE($1:$8)*(A$3:A$10=E5)*(B$3:B$10<>""))*1)
3=SUMME(({1;2;1;4;5;5;7;8}=ZEILE($1:$8)*(A$3:A$10=E5)*(B$3:B$10<>""))*1)
4=SUMME(({1;2;1;4;5;5;7;8}={1;2;3;4;5;6;7;8}*(A$3:A$10=E5)*(B$3:B$10<>""))*1)
5=SUMME(({1;2;1;4;5;5;7;8}={1;2;3;4;5;6;7;8}*({1;1;1;2;3;3;4;4}=1)*(B$3:B$10<>""))*1)
6=SUMME(({1;2;1;4;5;5;7;8}={1;2;3;4;5;6;7;8}*{WAHR;WAHR;WAHR;FALSCH;FALSCH;FALSCH;FALSCH;FALSCH}*(B$3:B$10<>""))*1)
7=SUMME(({1;2;1;4;5;5;7;8}={1;2;3;0;0;0;0;0}*(B$3:B$10<>""))*1)
8=SUMME(({1;2;1;4;5;5;7;8}={1;2;3;0;0;0;0;0}*({"A";"C";"A";"B";"B";"B";"B";"C"}<>""))*1)
9=SUMME(({1;2;1;4;5;5;7;8}={1;2;3;0;0;0;0;0}*{WAHR;WAHR;WAHR;WAHR;WAHR;WAHR;WAHR;WAHR})*1)
10=SUMME(({1;2;1;4;5;5;7;8}={1;2;3;0;0;0;0;0})*1)
11=SUMME(({WAHR;WAHR;FALSCH;FALSCH;FALSCH;FALSCH;FALSCH;FALSCH})*1)
12=SUMME({1;1;0;0;0;0;0;0})
13=2

Du kannst diese Zwischenergebnisse leicht herstellen, indem du den jeweils zu berechnenden Formelteil markierst
und dann F9 drückst.
Nun noch ein Hinweis auf die Idee, die sich hinter der Formel verbirgt:
Gezählt wird, wenn eine Kombination (z. B. "1C") zum ersten Mal auftritt - hier in der 2. Zeile des Bereichs.
Viel Spaß beim Knobeln! Wenn bestimmte Übergänge unklar bleiben - bitte melde dich wieder!
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort und: Schönes Wochenende!
Anzeige
AW: Zwischenergebnisse
31.10.2011 16:48:17
Ingo4711
Moin Erich,
das ist echt großartig! Nochmals herzlichen Dank!
Auch danke für die F9.
Beste Grüße
Ingo

431 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige