Microsoft Excel

Herbers Excel/VBA-Archiv

Anzahl von Buchstaben pro Zelle

Betrifft: Anzahl von Buchstaben pro Zelle von: steffex
Geschrieben am: 15.08.2008 07:55:40

Guten Morgen zusammen!

Ich habe folgende Aufgabe:

Ich will mir mittels einer Formel o.ä. die Anzahl von Buchstaben in einer Zelle darstellen lassen, d.h. es kann vorkommen, dass in einer Zelle der Eintrag "Hauptstr. 7" steht. Die Formel soll mir dann das Ergebnis 8 liefern.....8= Anzahl der Buchstaben.

Wäre so etwas möglich!

Vielen Dank an alle!

  

Betrifft: AW: Anzahl von Buchstaben pro Zelle von: Tino
Geschrieben am: 15.08.2008 08:11:51

Hallo,
hier mal mit einer VBA Funktion.

https://www.herber.de/bbs/user/54618.xls

Gruß Tino


  

Betrifft: AW: Anzahl von Buchstaben pro Zelle von: Jens
Geschrieben am: 15.08.2008 08:14:14

Hallo Steffex

Text in A1.
Formel in B1:
{=SUMME((TEIL(A1;SPALTE(1:1);1)={"a";"b";"c";"d";"e";"f";"g";"h";"i";"j";"k";"l";"m";"n";"o";"p";"q"; "r";"s";"t";"u";"v";"w";"x";"y";"z";"ß";"ä";"ü";"ö"})*1) }

(Matrix-Formel. Formel mit STRG+SHIFT+ENTER abschliessen)

Vielleicht geht das auch noch kürzer, wüsste jetzt aber nicht, wie.

Gruß aus dem Sauerland

Jens


  

Betrifft: AW: Anzahl von Buchstaben pro Zelle von: ransi
Geschrieben am: 15.08.2008 08:15:27

HAllo Steffex

Etwsa gescheiteres fällt mir dazu grad nicht ein:

Tabelle1

 ABC
1Hauptstr. 78ABCDEFGHIJKLMNOPQRSTUVWXYZÄÖÜß
2Testen6 
3   

Formeln der Tabelle
ZelleFormel
B1{=SUMME((ZÄHLENWENN($C$1;"*" & TEIL(A1;ZEILE(INDIREKT("a1:A" &LÄNGE(A1))); 1)&"*")))}
B2{=SUMME((ZÄHLENWENN($C$1;"*" & TEIL(A2;ZEILE(INDIREKT("a1:A" &LÄNGE(A2))); 1)&"*")))}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4


ransi


  

Betrifft: AW: Anzahl von Buchstaben pro Zelle von: ransi
Geschrieben am: 15.08.2008 08:52:18

HAllo

Hier nach was ohne Hilfsspalte:
Tabelle1

 AB
1TesteTnä8

Formeln der Tabelle
ZelleFormel
B1{=SUMME(ISTZAHL(SUCHEN(TEIL(A1;ZEILE(INDIREKT("a1:A" &LÄNGE(A1))); 1); "ABDEFGHIJKLMNOPQRSTUVWXYZÄÖÜß";1))*1)}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4


ransi


  

Betrifft: AW: Anzahl von Buchstaben pro Zelle von: AndrRo
Geschrieben am: 15.08.2008 08:19:20

Hallo Steffex,

anbei die Folmel:

=SUMMENPRODUKT((CODE(GROSS(TEIL(A1;ZEILE(INDIREKT("1:"&LÄNGE(A1)));1)))>64)*(CODE(GROSS(TEIL(A1; ZEILE(INDIREKT("1:"&LÄNGE(A1)));1)))<91))

gruss

AndrRo


  

Betrifft: AW: Anzahl von Buchstaben pro Zelle von: ransi
Geschrieben am: 15.08.2008 08:28:34

HAllo Andro


ÄÖÜß
Die müssen aber auch mit rein ...

ransi


  

Betrifft: AW: Anzahl von Buchstaben pro Zelle von: AndrRo
Geschrieben am: 15.08.2008 09:07:13

Hallo ransi,

anbei die Formel ohne Matrix:

=SUMMENPRODUKT((REST(VERGLEICH(CODE(TEIL(A1;ZEILE(INDIREKT("1:"&LÄNGE(A1)));1)); {0.65.91.97.123.196.197.214.215.220.221.223.224.228.229.246.247.252.253};1);2)=0)*1)

gruss

AndrRo


  

Betrifft: AW: Anzahl von Buchstaben pro Zelle von: steffex
Geschrieben am: 15.08.2008 08:53:28

Super, vielen Dank an alle.


  

Betrifft: Anzahl Buchstaben usw. von: FP
Geschrieben am: 15.08.2008 11:15:10

Hallo,

hier eine kleine Auswahl verschiedener Zählvarianten:

AnzZeichen
 ABCDEFGHIJKL
1TextAnzBAnzBaAnzBa2AnzKBAnzVBAnzVKBAnzVZeichAnzVZeich2 AnzBAnzahl der Buchstaben
2Hauptstr. 78887761010 AnzBaAnzahl der Buchstaben per Arrayformel
3Hauptstraße 711111110871111 AnzBa2Anzahl der Buchstaben per Arrayformel 2
4AAaa1111144421132 AnzKBAnzahl Kleinbuchstaben
5Aa1234522211176 AnzVBAnzahl verschiedene Buchstaben
6AaaBbCc?*ÿÿÿ77743396 AnzVKBAnzahl verschiedene Kleinbuchstaben
7`{@AZ[22202066 AnzVZeichAnzahl verschiedene Zeichen
8Hüpfingen 109998761111 AnzVZeich2Anzahl verschiedene Zeichen ( A + a = 1 Z )
9Mövenpickplatz 1a1515151412111515   
10Am Gefängnisplatz 11616161413131715   
Formeln der Tabelle
B2 : =HÄUFIGKEIT(CODE(TEIL(KLEIN(A2); SPALTE(2:2); 1)&"@"); {122.96})+LÄNGE(A2)*4-SUMME(LÄNGE(WECHSELN(A2;{"ä"."ö"."ü"."ß"};"")))
C2 : {=ANZAHL(SUCHEN("~"&TEIL(A2;ZEILE(INDIREKT("1:"&LÄNGE(A2))); 1); "abcdefghijklmnopqrstuvwxyzäöüß"))}
D2 : {=ANZAHL(SUCHEN("~"&LINKS(TEIL(A2;SPALTE(1:1); 1)&"ÿ"); "abcdefghijklmnopqrstuvwxyzäöüß"))}
E2 : {=ANZAHL(FINDEN(LINKS(TEIL(A2;SPALTE(1:1); 1)&"ÿ"); "abcdefghijklmnopqrstuvwxyzäöüß"))}
F2 : {=ANZAHL(SUCHEN(TEIL("abcdefghijklmnopqrstuvwxyzäöüß";SPALTE(A:AA); 1); A2))}
G2 : {=ANZAHL(FINDEN(TEIL("abcdefghijklmnopqrstuvwxyzäöüß";SPALTE(A:AA); 1); A2))}
H2 : =SUMME(N(HÄUFIGKEIT(CODE(TEIL(A2;SPALTE(1:1); 1)&ZEICHEN(10)); SPALTE(1:1)-1)>0))-1
I2 : =SUMME(N(HÄUFIGKEIT(CODE(TEIL(KLEIN(A2); SPALTE(2:2); 1)&ZEICHEN(10)); CODE(TEIL(KLEIN(A2); SPALTE(2:2); 1)&ZEICHEN(10)))>0))-1

Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
 
Diagramm - Grafik - Excel Tabellen einfach im Web darstellen    Excel Jeanie HTML  3.0    Download  


Servus aus dem Salzkammergut
Franz


 

Beiträge aus den Excel-Beispielen zum Thema "Anzahl von Buchstaben pro Zelle"