Microsoft Excel

Herbers Excel/VBA-Archiv

Informationen und Beispiele zum Thema MsgBox
BildScreenshot zu MsgBox MsgBox-Seite mit Beispielarbeitsmappe aufrufen

Per Code in Workbook_Open Ereignis schreiben

Betrifft: Per Code in Workbook_Open Ereignis schreiben von: chrdohmen
Geschrieben am: 21.08.2008 08:46:17

Hallo Zusammen,

ich würde gerne per VBA Code eine Zeile in das Workbook_Open Ereignis schreiben.
Wie ich einzelne Module hinzufüge weiß ich, allerdings gelingt es mir nicht eine Zeile
Code in das Ereignis zu schreiben.

Kann mir wer helfen bzw. sagen wo ich darüber etwas lesen kann?

Im Voraus vielen Dank

  

Betrifft: AW: Per Code in Workbook_Open Ereignis schreiben von: Heiko S.
Geschrieben am: 21.08.2008 09:26:23

Hallo ???


hast du keinen Namen ?!


z.B. so:

Sub VBA_Code_Rein()
Dim lngI As Long

On Error GoTo Errorhandler
' Erstmal die Zeile finden wo Workbooks_Open beginnt
With ActiveWorkbook.VBProject.VBComponents("DieseArbeitsmappe").CodeModule
    For lngI = 1 To .CountOfLines
        If InStr(.Lines(lngI, 1), "Workbook_Open") > 0 Then
            'MsgBox .Lines(lngI, 1)
            Exit For
        End If
    Next lngI
    ' Und nun in die nächste Zeile den neuen Code einfügen
    .InsertLines lngI + 1, "Msgbox ""Hello"""
   
End With
Exit Sub
' Bei Fehlernummer 1004, diese Meldung ausgeben.
Errorhandler:
If Err.Number = 1004 Then
    MsgBox "Das Löschen des VBA Codes ist fehlgeschlagen!" & vbCr & _
       "Bitte überprüfen Sie folgende Einstellung! " & vbCr & _
       "EXTRAS -> MAKRO -> SICHERHEIT -> Vertrauenwürdige Quellen." & vbCr & _
       "'Zugriff auf Visual Basic Projekt vertrauen' muss aktiviert sein! ", vbCritical, _
       " Meldung vom Makro VBA_Code_Rein"
Else
    MsgBox "Err.Number = " & Err.Number & ".   " & Err.Description, vbCritical
End If
End Sub





Gruß Heiko

PS: Rückmeldung wäre nett !


  

Betrifft: AW: Per Code in Workbook_Open Ereignis schreiben von: chrdohmen
Geschrieben am: 25.08.2008 19:44:11

Sorry für die verspätete Rückantwort. Hatte aber heute leider erst Zeit mich
zu melden da ich meine Programmierung fertigstellen musste. Dein Beispiel
hat mir sehr weitergeholfen

Gruß
Christian


 

Beiträge aus den Excel-Beispielen zum Thema "Per Code in Workbook_Open Ereignis schreiben"