Microsoft Excel

Herbers Excel/VBA-Archiv

Formel ändern für 5 Tage Woche

Betrifft: Formel ändern für 5 Tage Woche von: rieckmann
Geschrieben am: 07.11.2014 09:04:29

Hallo und guten Morgen

Ich habe hier eine Formel die mir die Anzahl der Urlaubstage ausgibt.
Ich gebe das Datum vom Anfang des Urlaubes in B4, und das Ende des Urlaubes in C4 ein.
Abgezogen werden die Sonntage und die Feiertage.
Ausgelegt ist das aber für eine 6 Tage Woche, also wird der Samstag mitgezählt.

Nun brauche ich aber die selbe Formel für eine 5 Tage Woche, also ohne Samstag und Sonntag.

Was muss man hier bei dieser Formel ändern ?

Gruß
Fred

=WENN(ODER(B4="";C4="");"";C4+1-B4-GANZZAHL((WOCHENTAG(B4;2)+C4-B4)/7) -SUMME(WENN((Feiertage!$A$1:$A$12>=B4)*(Feiertage!$A$1:$A$12<=C4) *(WOCHENTAG(Feiertage!$A$1:$A$12;2)<7);1;0)))

  

Betrifft: AW: Formel ändern für 5 Tage Woche von: {Boris}
Geschrieben am: 07.11.2014 09:22:54

Hi,

ein etwas anderer Ansatz (ist damit auch keine {Array}-Formel mehr):

=WENN(ODER(B4="";C4="");"";SUMMENPRODUKT(N(WOCHENTAG(ZEILE(INDIREKT(B4&":"&C4+1));2)<6)) -SUMMENPRODUKT((Feiertage!$A$1:$A$12>=B4)*(Feiertage!$A$1:$A$12<=C4) *(WOCHENTAG(Feiertage!$A$1:$A$12;2)<6)))

VG, Boris


  

Betrifft: Sorry - das +1 muss weg ...oT von: {Boris}
Geschrieben am: 07.11.2014 09:55:06

VG, Boris


  

Betrifft: AW: Formel ändern für 5 Tage Woche von: {Boris}
Geschrieben am: 07.11.2014 09:24:15

Hi,

ein etwas anderer Ansatz (ist damit auch keine {Array}-Formel mehr):

=WENN(ODER(B4="";C4="");"";SUMMENPRODUKT(N(WOCHENTAG(ZEILE(INDIREKT(B4&":"&C4+1));2)<6)) -SUMMENPRODUKT((Feiertage!$A$1:$A$12>=B4)*(Feiertage!$A$1:$A$12<=C4) *(WOCHENTAG(Feiertage!$A$1:$A$12;2)<6)))

VG, Boris


  

Betrifft: Sorry - der Browser blieb "hängen"...oT von: {Boris}
Geschrieben am: 07.11.2014 09:30:22

...


  

Betrifft: AW: Sorry - der Browser blieb "hängen"...oT von: rieckmann
Geschrieben am: 07.11.2014 10:15:33

Hallo Boris,
danke für deine Lösung.

Wenn ich z.B. 18.05.2015 bis 31.05.2015 eigebe, kommt als Ergebnis 10 heraus.
Der 25.05.2015 ist aber ein Feiertag der auch im Tabellenblatt "Feiertage A7" mit 25.05.2015 so da steht. Er wird also nicht im Ergebnis abgezogen.

Gruß
Fred


  

Betrifft: Ich hatte noch einen Nachtrag gepostet... von: {Boris}
Geschrieben am: 07.11.2014 10:19:07

Hi Fred,

...den hast Du wahrscheinlich nicht gesehen.

Das +1 in der Formel muss weg.

Also korrekt ist:

=WENN(ODER(B4="";C4="");"";SUMMENPRODUKT(N(WOCHENTAG(ZEILE(INDIREKT(B4&":"&C4));2)<6)) -SUMMENPRODUKT((Feiertage!$A$1:$A$12>=B4)*(Feiertage!$A$1:$A$12<=C4) *(WOCHENTAG(Feiertage!$A$1:$A$12;2)<6)))

VG, Boris


  

Betrifft: AW: Sorry - der Browser blieb "hängen"...oT von: rieckmann
Geschrieben am: 07.11.2014 10:19:40

Sorry,
habe das mit den +1 muss weg erst jetzt gesehen !

Nun scheint es zu funktionieren !

Dank und Gruß
Fred


 

Beiträge aus den Excel-Beispielen zum Thema "Formel ändern für 5 Tage Woche"