Microsoft Excel

Herbers Excel/VBA-Archiv

Informationen und Beispiele zum Thema InputBox
BildScreenshot zu InputBox InputBox-Seite mit Beispielarbeitsmappe aufrufen

Seitennumerierung fortführen bei 2. Druckauftrag

Betrifft: Seitennumerierung fortführen bei 2. Druckauftrag von: Huffi
Geschrieben am: 12.11.2014 14:28:48

Hallo Excelfreunde,

gibt es eine Möglichkeit in Excel die Seitennumerierung so ein zu stellen, dass sie beim nächsten Druck fortgeführt wird?

Habe eine Tabelle, in der verschiedene Infos eingetragen werden.
Diese Tabelle muss öfters gedruckt werden, damit sie von den Kunden per Hand ausgefüllt wird.

Die Seitennumerierung soll so aussehen: Seit 1, Seite 2, etc.

Beim ersten Ausdruck brauch ich z.B. 10 mal die Tabelle.

Beim zweiten Ausdruck brauch ich 20 mal die Tabelle.

Excel sollte sich merken, dass die Tabelle bereits 10 mal gedruckt wurden und nun soll Excel die 20 Seiten des zweiten Ausdruckes dazuzählen.
Die Seitennumerierung soll dann mit 11 beginnen und bei 30 enden.

Ich hoffe, dass cih mich klar genug ausgedrückt habe.
Bedanke mich für eure Hilfe

Huffi

  

Betrifft: AW: Seitennumerierung fortführen bei 2. Druckauftrag von: yummi
Geschrieben am: 12.11.2014 15:00:30

Hallo Huffi,

ist ungetestet, aber mal als Idee:

Sub KopfZeile()
   With ActiveSheet
      .PageSetup.LeftHeader = "Seite &P von &N"
      .PrintPreview
   End With
End Sub
wenn du weißt wieviel Seiten du druckst kannst du dir den Wert ja in z.B. einer Zelle merken und dann
so etwas wie "Seite &P+Zelle von &N + Zelle" machen

Gruß
yummi


  

Betrifft: AW: Seitennumerierung fortführen bei 2. Druckauftrag von: fcs
Geschrieben am: 12.11.2014 15:16:10

Hallo Huffi,

man muss per Makro die die Exemplare einzeln drucken und dabei jeweils die Nummer der 1. Seite neu setzen.
Der Ausgabedrucker muss hier ggf. vor dem Start des Druckens gewählt werden.

Das Makro ist unter Excel 2010 erstellt, sollte aber auch unter der 2003er Version funktionieren.

Gruß
Franz

'Makro in einem allgemeinen Modul der Datei oder der persönlichen Makroarbeitsmappe.
Sub Drucken_Seitennummer_erste_Seite()
  Dim Startseite As Integer, StartseiteNeu As Integer
  Dim Anzahl_Exemplare As Integer, Zaehler As Integer
  Dim AnzSeiten As Integer
  Dim wks As Worksheet
  Set wks = ActiveSheet
  With wks
    AnzSeiten = .HPageBreaks.Count + 1 'Anzahl Seiten pro Tabelle. ggf. korrigieren
    
    Anzahl_Exemplare = Application.InputBox("Anzahl Exemplare?", _
        Title:="Aktives Blatt drucken", Default:=1, Type:=1)
    If Anzahl_Exemplare <= 0 Then Exit Sub
    
    Startseite = .PageSetup.FirstPageNumber
    If Startseite = -4104 Then 'Nummer 1. Seite steht auf automatisch
      Startseite = 0
    End If
    StartseiteNeu = Application.InputBox("Startseite für Ausdruck?", _
        Title:="Aktives Blatt " & Anzahl_Exemplare & " mal drucken", _
        Default:=Startseite + 1, Type:=1)
    If StartseiteNeu <= 0 Then Exit Sub
    Startseite = StartseiteNeu - 1
    
    For Zaehler = 1 To Anzahl_Exemplare
      Startseite = Startseite + 1
      .PageSetup.FirstPageNumber = Startseite
      '.PrintPreview
      .PrintOut
      Startseite = Startseite + AnzSeiten - 1
    Next
    .PageSetup.FirstPageNumber = Startseite
  End With
  wks.Parent.Save
End Sub



  

Betrifft: AW: Seitennumerierung fortführen bei 2. Druckauftrag von: Huffi
Geschrieben am: 12.11.2014 16:36:55

Hallo Fcs,

vielen Dank für Deine Hilfe.
Genauso habe ich es mir vorgestellt.

Vielen Dank aus dem sehr verregnetem Italien

Huffi