Spalte vor Druck ausblenden/nach Druck einblenden

Forumthread: Spalte vor Druck ausblenden/nach Druck einblenden

Gesa

Hallo,
habe nachfolgendes Makro und möchte gerne, dass es erweitert wird und zwar dass bei anwählen des Markos die Spalte D ausgeblendet wird und nach verlassen der Seitenansicht wieder eingeblendet wird.
Geht das?
Für Hilfe bin ich wie immer :-) dankbar..


Sub Druck_KlasseA()
Dim iRowL As Integer, iRow As Integer
Application.ScreenUpdating = False
Application.EnableEvents = False
ActiveSheet.DisplayPageBreaks = False
iRowL = Cells(Rows.Count, 1).End(xlUp).Row
For iRow = 1 To iRowL
Rows(iRow).Hidden = (IsEmpty(Cells(iRow, 12)) Or Cells(iRow, 12).Value = 0)
Next iRow
ActiveSheet.PrintPreview
Rows.Hidden = False
ActiveSheet.DisplayPageBreaks = True
Application.EnableEvents = True
Application.ScreenUpdating = True
End Sub

LG Gesa

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

Mit Application.OnTime

Tino
AW: Mit Application.OnTime

Gesa
AW: Mit Application.OnTime

Tino

Mit Application.OnTime

27.06.2009 15:48:42

Tino

Hallo,
es gibt zwar das Ereignis Workbook_BeforePrint, aber keins für nach dem Drucken.
Mit Application.OnTime kann man sich aber ein Ereignis nach Print selbst bauen.
Hier ein Beispiel dazu, blendet die Spalte D (4) aus und danach wieder ein.
kommt als Code in DieseArbeitsmappe

Option Explicit 
 
Private Sub Workbook_BeforePrint(Cancel As Boolean) 
Dim strTabelle As String 
 strTabelle = "Tabelle1" 'Tabellenname anpassen 
  
 Sheets(strTabelle).Columns(4).Hidden = True 
 Application.OnTime Now + TimeValue("00:00:01"), "'SpalteEinblenden """ & strTabelle & """'" 
End Sub

kommt als Code in Modul1

Option Explicit 
 
Sub SpalteEinblenden(strSheet As String) 
 Sheets(strSheet).Columns(4).Hidden = False 
End Sub

Gruß Tino

AW: Mit Application.OnTime

27.06.2009 16:59:17

Gesa

Hallo Tino,
zuerst einmal vielen Dank - aber ich versteh leider nur Bahnhof :-(
Kann man das nicht mit in das Makro was ich angegeben habe einbauen?
Habe eine Schaltfläche Druck (mit Straße) und eine Schaltfläche Druck (ohne Straße = Spalte D).
Vielen Dank vorab für die Unterstützung
LG Gesa

AW: Mit Application.OnTime

27.06.2009 17:27:17

Tino

Hallo,
müsste so funktionieren.
Tabellenname musst Du im Code noch anpassen.
kommt als Code in DieseArbeitsmappe

Option Explicit 
 
Private Sub Workbook_BeforePrint(Cancel As Boolean) 
Dim iRowL As Integer, iRow As Integer 
Dim strTabellenName As String 
 
'Tabellenname anpassen ******************* 
strTabellenName = "Tabelle1" 
 
With Application 
 .ScreenUpdating = False 
 .EnableEvents = False 
  
    
       With Sheets(strTabellenName) 
            .DisplayPageBreaks = False 
            iRowL = .Cells(.Rows.Count, 1).End(xlUp).Row 
             
            For iRow = 1 To iRowL 
              .Rows(iRow).Hidden = (IsEmpty(.Cells(iRow, 12)) Or .Cells(iRow, 12).Value = 0) 
            Next iRow 
                 
            .Columns(4).Hidden = True 
        End With 
  
 .EnableEvents = True 
 .ScreenUpdating = True 
 .OnTime Now + TimeValue("00:00:01"), "'SpalteEinblenden """ & strTabellenName & """'" 
End With 
End Sub

kommt als Code in Modul1

Option Explicit 
  
Sub SpalteEinblenden(strSheet As String) 
With Sheets(strSheet) 
 .Rows.Hidden = False 
 .Columns(4).Hidden = False 
 .DisplayPageBreaks = True 
End With 
End Sub

Gruß Tino

Beliebteste Forumthreads (12 Monate)

Spalte vor Druck ausblenden/nach Druck einblenden

Forumthread: Spalte vor Druck ausblenden/nach Druck einblenden

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread