PDF umwandeln und automatisch versenden

andreas · 2013-10-07T11:59:55+00:00

Hallo Guten Morgen Spezialisten, vll. kann man mir weiterhelfen? Brauche einen Code. Ich habe in einem Tabellenblatt ein kleines Formular erstellt. Nun möchte ich eine Befehlsschaltfläche erstellen, die nach Betätigung mir das Formular in eine PDF Datei umwandelt und anschließen an eine bestimmte Email weiterleitet. Ich wie nicht ob solch eine Funktion möglich ist, hoffe auf euere Hilfe  Habe die xls. Datei angehängt. https://www.herber.de/bbs/user/87561.xls Danke schon mal im Voraus. Gruß Andreas

Hallo Andreas,
hier mal ein Code, den Du Deinen Bedürfnissen nach anpassen kannst:


Option Explicit
Private Sub CommandButton1_Click()
Dim objOutlook As Object
Dim strSignature As String
Dim strDateiname As String
strDateiname = ThisWorkbook.FullName & ".pdf"
ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=strDateiname, _
IncludeDocProperties:=False, _
IgnorePrintAreas:=False, _
OpenAfterPublish:=False
Set objOutlook = CreateObject("Outlook.Application")
With objOutlook.CreateItem(0)
.GetInspector.Display 'Signatur abfragen
strSignature = .Body 'Signatur zwischenspeichern
.To = "max@mustermann.de"
'                 .Cc =
'                 .Bcc =
.Subject = "PDF umwandeln und automatisch versenden"
.Body = "Ihr Text..." & strSignature 'Signatur wieder einfügen
.attachments.Add strDateiname
'Mail anzeigen
.Display
'mit dem folgenden Befehl kann direkt gesendet werden:
'mail.send
Kill strDateiname
End With
End Sub

Gruß, Bastian

Hallo,
evtl. so:

Sub Start_PDFPrint_Job()
Dim objOutlook As Object
Dim strSignature As String
Dim strDateiname As String
Dim strPfad As String
With ActiveWorkbook
strDateiname = Left(.Name, Len(.Name) - 4) & "-" & ActiveSheet.Name
strPfad = .Path
End With
ChDrive (Left(strPfad, 2))
ChDir strPfad
strDateiname = strPfad & "\" & strDateiname
ActiveSheet.PrintOut ActivePrinter:="Acrobat PDFWriter auf LPT1:", _
PrintToFile:=True, PrToFilename:=strDateiname
Set objOutlook = CreateObject("Outlook.Application")
With objOutlook.CreateItem(0)
.GetInspector.Display 'Signatur abfragen
strSignature = .Body 'Signatur zwischenspeichern
.To = "max@mustermann.de"
'                 .Cc =
'                 .Bcc =
.Subject = "PDF umwandeln und automatisch versenden"
.Body = "Ihr Text..." & strSignature 'Signatur wieder einfügen
.attachments.Add strDateiname & ".pdf"
'Mail anzeigen
.Display
'mit dem folgenden Befehl kann direkt gesendet werden:
'mail.send
Kill strDateiname
End With
End Sub

Gruß
Rudi

PDF umwandeln und automatisch versenden

Forumthread: PDF umwandeln und automatisch versenden

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Infobox / Tutorial