Worksheet_Change Problem mit doppeltem Namen

Bild

Betrifft: Worksheet_Change Problem mit doppeltem Namen
von: Matthias
Geschrieben am: 10.11.2015 01:57:06

Hallo,
ich habe ein Problem und würde mich über etwas Hilfe sehr freuen da ich jetzt schon Stunden im Internet lese und rumprobiere und es leider selbst nicht hinbekomme. Ich habe 2 Worksheet_Change Makros mit leicht unterschiedlichen Angaben und ich habe auch beide einzeln schon zum laufen bekommen aber sobald ich beide aktivieren möchte kommt aufgrund der gleichen Namen immer ein Fehler und ich habe es bis jetzt nicht geschafft die beiden zusammenzufügen.
Wäre sehr dankbar wenn mir jemand dabei helfen könnte, da ich in Excel und VBA noch nicht so gut bin.
Hier mal die 2 getrennten Makros:

Sub Worksheet_Change(ByVal target As Range)
    Set target = Intersect(target, Range("C:G,I:I,K:M"))
    If target Is Nothing Then Exit Sub
    Cells(target.Row, 15) = Now
    Set target = Nothing
End Sub
Sub Worksheet_Change(ByVal target As Range)
    Set target = Intersect(target, Range("H:H,J:J"))
    If target Is Nothing Then Exit Sub
    Cells(target.Row, 14) = Now
    Cells(target.Row, 15) = ""
    Set target = Nothing
End Sub
LG
Matthias

Bild

Betrifft: Es gibt nur EIN Worksheet_Change-Ereignis ...
von: Luc:-?
Geschrieben am: 10.11.2015 02:48:50
…und folglich ist auch nur eine EreignisProzedur auf dem betroffenen Blatt möglich, Matthias!
Würdest du mal ins Archiv schauen, würdest du das Thema x-mal finden, auch, was man stattdessen machen muss/kann:
1. Alles in die eine Prozedur integrieren und dabei die unterschiedlichen Aktionen davon abhängig machen, in welchem Bereich sich Target befindet, was man u.a. mit der vbFkt Intersect feststellen kann.
2. Eines der anderen beiden …_Change-Ereignisse nutzen: Workbook_SheetChange bzw das vorbereitete, aber erst noch anzulegende Application_WorkbookChange, was idR und sicher auch in diesem Fall reine Verschwendung wäre, wenn es nur für ein Blatt einer Mappe gelten soll.
Gruß, Luc :-?

Besser informiert mit …

Bild

Betrifft: AW: Es gibt nur EIN Worksheet_Change-Ereignis ...
von: Matthias
Geschrieben am: 10.11.2015 03:03:30
Erstmal Danke für deine Antwort.
Natürlich habe ich erstmal verusucht es selbst hinzubekommen und habe bei Google und unter anderem auch hier im Forum nach Lösungen gesucht und auch herausgefunden das man die 2 Ereignisse zusammenführen muss allerdings hat nichts davon bei mir funktioniert. Bin wie gesagt noch totaler Neuling auf dem Gebiet. Und ja es soll nur für ein Blatt einer Mappe sein.
Gruss
Matthias

Bild

Betrifft: Das könnte so fktionieren, ...
von: Luc:-?
Geschrieben am: 10.11.2015 03:47:38
…Matthias (geht auch noch etwas kürzer):

Sub Worksheet_Change(ByVal Target As Range)
    Const adRelBer1$ = "H:H,J:J", adRelBer2$ = "C:G,I:I,K:M"
    With Application
        .EnableEvents = False
        If Not Intersect(Target, Me.Range(adRelBer1)) Is Nothing Then
            Me.Cells(Target.Row, 14) = Now
        ElseIf Not Intersect(Target, Me.Range(adRelBer2)) Is Nothing Then
            Me.Cells(Target.Row, 15) = Now
        End If
        .EnableEvents = True
    End With
    Set target = Nothing
End Sub
Morrn, Luc :-?

Bild

Betrifft: AW: Das könnte so fktionieren, ...
von: Matthias
Geschrieben am: 10.11.2015 04:37:09
Super, vielen Dank es hat so funktioniert. Musste nur noch beim ersten Bereich die Zeile einfügen das er die Spalte 15 löscht aber jetzt läuft alles :)
Gruss
Matthias

Bild

Betrifft: AW: Worksheet_Change
von: Gerd L
Geschrieben am: 10.11.2015 07:03:44
Moin!

Sub Worksheet_Change(ByVal Target As Range)
    
          
             On Error GoTo errExit
        
             If Intersect(Target, Range("H:M")) Is Nothing Then Exit Sub
             Application.EnableEvents = False
             Select Case Target.Column
             Case 8, 10: Cells(Target.Row, 15) = Now
             Case Else: Cells(Target.Row, 15) = "": Cells(Target.Row, 14) = Now
             End Select
            
errExit:
            If Err.Number <> 0 Then Err.Clear
            Application.EnableEvents = True
        
    
End Sub

Gruß Gerd

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Worksheet_Change Problem mit doppeltem Namen"