textbox.exit für bestimmte Textboxen

Private Sub Textbox3_Exit(ByVal Cancel As msforms.ReturnBoolean) If Textbox3 = "" Then Exit Sub Elseif Not IsNumeric(Me.TextBox3) Then TextBox3.BackColor = RGB(100, 100, 199) MsgBox ("Eingabe ist nicht vom Type Numeric!") Elseif TextBox3 > 1 Then TextBox.Backcolor = RGB(255, 255, 255) Me.TextBox 3 = Format(Me.TextBox3, "#,##0.00") Else TextBox3.BackColor = RGB(255, 255, 255) Me.TextBox3 = Format(Me.Textbox3, "0.00") End if End Sub

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Private Sub TXT_Kw_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger) Select Case KeyAscii Case 48 To 57 ' Pr?fen ob Eingabe Zahl Case Else: KeyAscii = 0 ' alle anderen Eingaben l?schen End Select End Sub

Hi
wenn dir das mit der Klassenprogrammierung zu komplex erscheint, mach folgendes:
1. Schreibe ins Modul der Userform diese Funktion:

Function TextBoxPrüfung(crtl As Control) As Boolean
If crtl = "" Then
Exit Function
ElseIf Not IsNumeric(crtl) Then
crtl.BackColor = RGB(100, 100, 199)
MsgBox ("Eingabe ist nicht vom Type Numeric!")
TextBoxPrüfung = True
ElseIf crtl > 1 Then
crtl.BackColor = RGB(255, 255, 255)
crtl = Format(crtl, "#,##0.00")
Else
crtl.BackColor = RGB(255, 255, 255)
crtl = Format(crtl, "0.00")
End If
End Function

Du musst dann zwar immer noch für jede betroffene TextBox das Exit-Eventmakro erstellen, aber dieses sieht dann so aus, dh es besteht nur noch aus einer Zeile, die für alle Makros gleich ist:
Du kannst also diesen Code kopieren, entsprechend oft einfügen und passt dann nur noch den Textboxnamen in der Kopfzeile an.

Private Sub TextBox1_Exit(ByVal Cancel As MSForms.ReturnBoolean)
Call TextBoxPrüfung(ActiveControl)
End Sub

wenn du Cancel nutzen willst (Eingabefeld darf nur bei korrekter Eingabe verlassen werden), schreibe den Code so:

Private Sub TextBox1_Exit(ByVal Cancel As MSForms.ReturnBoolean)
Cancel =  TextBoxPrüfung(ActiveControl)
End Sub

in VBA kann eine Function nicht nur als Function, sondern auch wie eine Sub verwendet werden.
der Rückgabewert wird dann nicht genutzt.
Gruß Daniel

Hallo Berg,
in das Modul deines UserForms:

Option Explicit

Private mobjTextBoxCollection As Collection

Private Sub UserForm_Initialize()
    Dim objTextboxClass As clsTextBox
    Dim lngIndex As Long
    Set mobjTextBoxCollection = New Collection
    For lngIndex = 4 To 15
        Set objTextboxClass = New clsTextBox
        Set objTextboxClass.TextBox = Controls("TextBox" & CStr(lngIndex))
        Call mobjTextBoxCollection.Add(Item:=objTextboxClass)
        Set objTextboxClass = Nothing
    Next
End Sub

Private Sub UserForm_Terminate()
    Set mobjTextBoxCollection = Nothing
End Sub

In ein Klassenmodul mit dem Namen "clsTextBox":

Option Explicit

Private WithEvents mobjTextBox As MSForms.TextBox

Private Sub Class_Terminate()
    Set TextBox = Nothing
End Sub

Friend Property Set TextBox(ByRef probjTextBox As MSForms.TextBox)
    Set mobjTextBox = probjTextBox
End Property

Private Sub mobjTextBox_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
    Select Case KeyAscii
        Case 48 To 57
        Case Else: KeyAscii = 0
    End Select
End Sub

Gruß
Nepumuk

Beliebteste Forumthreads (12 Monate)

textbox.exit für bestimmte Textboxen

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

300 Forumthreads zu ähnlichen Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

textbox.exit für bestimmte Textboxen

8 Beiträge zum Forumthread Beiträge zu diesem Forumthread

300 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread