Microsoft Excel

Herbers Excel/VBA-Archiv

Dateiname und Speicherzeit auslesen und anpassen | Herbers Excel-Forum


Betrifft: Dateiname und Speicherzeit auslesen und anpassen von: MB
Geschrieben am: 03.12.2009 11:45:11

Hallo Excelexperten,

ich habe in einem Ordner Bilder gespeichert.
Ich möchte das Verzeichnis auslesen und eine Excelliste mit Dateinnamen und Speicherzeitpunkt erstellen. Die Liste wird dann ergänzt um einen Spalte mit alternativen Namen für die Bilder.
Wichtig: Die Bilder in dem Verzeichnis sollen dann in den alternativen Namen umbenannt werden.

Lässt sich so etwas machen und wenn ja - wie?

Besten Dank im Voraus!

Michael

  

Betrifft: Machbar ? - JA ! - Wie ? - später mehr ;-) _oT von: NoNet
Geschrieben am: 03.12.2009 13:10:26

_oT = "ohne Text" (gehe jetzt etwas essen ;-)


  

Betrifft: AW: Machbar ? - JA ! - Wie ? - später mehr ;-) _oT von: MB
Geschrieben am: 03.12.2009 17:15:46

Hallo NoNet,

haben Sie jetzt einen Tip für mich?

Danke und liebe Grüße
Michael


  

Betrifft: AW: Machbar ? - JA ! - Wie ? - später mehr ;-) _oT von: Ramses
Geschrieben am: 03.12.2009 20:57:55

Hallo

Probier mal

Option Explicit

Const filePath As String = "D:\DeinPfad\"

Sub Bilddateien_in_Tabelle_auflisten()
    'Ramses
    Dim gefFile As String
    Dim myFSO As Object, myFile As Object, strInfo As String
    Dim chkFile As String
    Dim rowCounter As Long
    Set myFSO = CreateObject("Scripting.FileSystemObject")
    gefFile = Dir(filePath & "*.*") 'oder nur JPG Dateien: Dir(filePath & "*.jpg")
    Application.ScreenUpdating = False
    rowCounter = 1
    Do While Datei <> ""
        Set myFile = myFSO.getfile(gefFile)
        'Dateiname in Spalte A
        Cells(rowCounter, 1) = myFile.Name
        'Speicherdatum in Spalte B
        Cells(rowCounter, 1) = myFile.datelastmodified
        gefFile = Dir()
        rowCounter = rowCounter + 1
    Loop
    Application.ScreenUpdating = True
End Sub

Sub Bilddateien_umbenennen()
    'neuer Name muss mit Dateierweiterung in Spalte C stehen
    'spalte C = 3
    Dim i As Long
    For i = 1 To Cells(Rows.Count, 1).End(xlUp).Row
        Name Cells(i, 1).Text As Cells(i, 3).Text
    Next i
End Sub


Gruss Rainer


  

Betrifft: AW: Machbar ? - JA ! - Wie ? - später mehr ;-) _oT von: MB
Geschrieben am: 04.12.2009 09:48:18

Hallo Rainer,
recht herzlichen Dank! Hab den code gleich mal probiert.
Scheint als würde die Schleife nicht laufen, außerdem erhalte ich eine Fehlermeldung, dass die Variable ("Datei") nicht deklariert ist.
Kannst Du bitte nochmal auf die Schleife schauen, da komme ich nicht weiter! Danke.

Liebe Grüße
Michael


  

Betrifft: oT von: MB
Geschrieben am: 04.12.2009 09:52:08

oT


  

Betrifft: AW: Machbar ? - JA ! - Wie ? - später mehr ;-) _oT von: Ramses
Geschrieben am: 04.12.2009 10:13:00

Hallo

Sorry,... Fehler meinerseits.
jetzt sollte es tun

Option Explicit

'Mit Backslash am Ende
Const filePath As String = "D:\Dein_Pfad\"

Sub Bilddateien_in_Tabelle_auflisten()
    'Ramses
    Dim gefFile As String
    Dim myFSO As Object, myFile As Object, strInfo As String
    Dim chkFile As String
    Dim rowCounter As Long
    ChDir filePath
    Set myFSO = CreateObject("Scripting.FileSystemObject")
    gefFile = Dir(filePath & "*.*") 'oder nur JPG Dateien: Dir(filePath & "*.jpg")
    Application.ScreenUpdating = False
    rowCounter = 1
    Do While gefFile <> ""
        Set myFile = myFSO.getfile(gefFile)
        'Dateiname in Spalte A
        Cells(rowCounter, 1) = myFile.Name
        'Speicherdatum in Spalte B
        Cells(rowCounter, 2) = myFile.dateLastModified
        gefFile = Dir()
        rowCounter = rowCounter + 1
    Loop
    Application.ScreenUpdating = True
End Sub

Sub Bilddateien_umbenennen()
    'neuer Name muss mit Dateierweiterung in Spalte C stehen
    'spalte C = 3
    Dim i As Long
    ChDir filePath
    For i = 1 To Cells(Rows.Count, 1).End(xlUp).Row
        Name Cells(i, 1).Text As Cells(i, 3).Text
    Next i
End Sub


Gruss Rainer


  

Betrifft: Danke - läuft prima! von: MB
Geschrieben am: 04.12.2009 11:14:45

Hallo Rainer,

super, funktioniert wunderbar. Das mit dem getfile muss ich mir noch anschauen, kenne ich so gar nicht.
Danke und ein schönes Wochenende!
Liebe Grüße
Michael


Beiträge aus den Excel-Beispielen zum Thema "Dateiname und Speicherzeit auslesen und anpassen"