Microsoft Excel

Herbers Excel/VBA-Archiv

Informationen und Beispiele zum Thema ListBox
BildScreenshot zu ListBox ListBox-Seite mit Beispielarbeitsmappe aufrufen

Ausgeblendete Tabellen Drucken VBA

Betrifft: Ausgeblendete Tabellen Drucken VBA von: BER
Geschrieben am: 20.11.2014 14:00:36

Hallo Leute,

ich hab es ja hinbekommen das die schaltfläche sichbar wird für die ausgeblendeten Tabellen gerade versucht zu drucken das geht leider nicht :(
die vorschau geht ebenfalls nicht aber das drucken ist mir wichtiger....

hier die datei mit dem VBA geht es mit nem code das man einblendet druckt udn wieder ausblendet anhand dem code in meiner datei ?!?

LG

https://www.herber.de/bbs/user/93911.xls

  

Betrifft: Probier das mal.... Gruß? von: robert
Geschrieben am: 20.11.2014 14:47:24

https://www.herber.de/bbs/user/93914.xls


  

Betrifft: AW: Ausgeblendete Tabellen Drucken VBA von: Rudi Maintaire
Geschrieben am: 20.11.2014 14:54:01

Hallo,

Sub Drucken(Optional Vorschau As Boolean = False)
  Dim Blaetter(), j%, i%, wks
  Dim arrSheets()
  ReDim arrSheets(1 To Sheets.Count, 1 To 2)
  j% = 0
  For i = 1 To Sheets.Count
    arrSheets(i, 1) = Sheets(i).Name
    arrSheets(i, 2) = Sheets(i).Visible
  Next i
  Set wks = ActiveSheet
  For i = 0 To Me.ListBox_Tabellen.ListCount - 1
    If Me.ListBox_Tabellen.Selected(i) = True Then
      j = j + 1
      ReDim Preserve Blaetter(1 To j)
      Blaetter(j) = Me.ListBox_Tabellen.List(i, 0)
      Sheets(Blaetter(j)).Visible = xlSheetVisible
    End If
  Next
  Me.Hide
  If Me.OB_Druck_gruppiert = True Then
    If Vorschau = True Then
      ActiveWorkbook.Sheets(Blaetter).PrintPreview
    Else
      ActiveWorkbook.Sheets(Blaetter).PrintOut
    End If
  Else
    For i = LBound(Blaetter) To UBound(Blaetter)
      If Vorschau = True Then
        ActiveWorkbook.Sheets(Blaetter(i)).PrintPreview
      Else
        ActiveWorkbook.Sheets(Blaetter(i)).PrintOut
      End If
    Next i
  End If
  wks.Select
  For i = 1 To UBound(arrSheets)
    Sheets(arrSheets(i, 1)).Visible = arrSheets(i, 2)
  Next
End Sub

Gruß
Rudi


  

Betrifft: So macht es eben der Profi... ;-)) owT von: robert
Geschrieben am: 20.11.2014 16:02:33




  

Betrifft: AW: So macht es eben der Profi... ;-)) owT von: BER
Geschrieben am: 21.11.2014 08:38:01

wow super, das ist Perfekt zeigt unsichtbare tabellen als vorschau an und alles genau was ich haben wollte :)

das kann nur ein Profi sein ;)

Vielen Lieben dank !!!!


 

Beiträge aus den Excel-Beispielen zum Thema "Ausgeblendete Tabellen Drucken VBA"