Live-Forum - Die aktuellen Beiträge
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

RGP ohne ausgeblendete Zeilen

RGP ohne ausgeblendete Zeilen
07.11.2013 09:38:57
Wolfango
Hallo Experten,
Ich habe zwei Werte-Reihen in Spalten und mache eine einfache Regressionsanalyse.
Ich benutze dazu die Excel-Funktion RGP.
Mein Ziel: Ich möchte Zeilen ausblenden können, und die ausgeblendeten Zeilen sollen dann nicht mehr von der Funktion RGP berücksichtigt werden!
(…so, wie das im Rahmen der Funktion TEILERGEBNIS mit einer Vielzahl von Berechnungen möglich ist, aber da ist RGP nicht dabei…)
Geht das irgendwie?
Danke und Gruß,
Wo

5
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: RGP ohne ausgeblendete Zeilen
07.11.2013 11:38:01
Bastian
Hallo Wolfgang,
du könntest natürlich "zu Fuß" rechnen. Dann hast Du nur Summen, und für die gibt es TEILERGEBNIS()
Im Beispiel hab ich links mit RGP gerechnet und rechts "zu Fuß".
Gruß, Bastian
 ABCDEFGHIJKLM
1Y-WerteX- Wertemb X^2y*xSumme xSumme yn mb
22,510,52 12,5435275,529 0,52
332   46      
43,53   910,5      
544   1616      
64,55   2522,5      
756   3630      
85,57   4938,5      
968   6448      
106,59   8158,5      
11710   10070      
127,511   12182,5      
13812   14496      
148,513   169110,5      
15914   196126      
169,515   225142,5      
171016   256160      
1810,517   289178,5      
191118   324198      
2011,519   361218,5      
211220   400240      
2212,521   441262,5      
231322   484286      
2413,523   529310,5      
251424   576336      
2614,525   625362,5      
271526   676390      
2815,527   729418,5      
291628   784448      
3016,529   841478,5      
31     85555147,5      

Formeln der Tabelle
ZelleFormel
C2{=RGP(A2:A30;B2:B30)}
D2{=RGP(A2:A30;B2:B30)}
F2=B2^2
G2=A2*B2
H2=TEILERGEBNIS(109;B2:B30)
I2=TEILERGEBNIS(109;A2:A30)
J2=TEILERGEBNIS(102;A2:A30)
L2=(J2*G31-H2*I2)/(J2*F31-H2^2)
M2=(F31*I2-H2*G31)/(J2*F31-H2^2)
F31=TEILERGEBNIS(109;F2:F30)
G31=TEILERGEBNIS(109;G2:G30)
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4

Anzeige
AW: RGP ohne ausgeblendete Zeilen
07.11.2013 11:49:10
Bastian
oder ohne die Hilfsspalten für x^2 und x*y:
 ABCDEFGHIJKLM
1Y-WerteX- Wertemb Summe(X^2)Summe(y*x)Summe xSumme yn mb
22,510,52 85555147,5435275,529 0,52
332           
43,53           
544           
64,55           
756           
85,57           
968           
106,59           
11710           
127,511           
13812           
148,513           
15914           
169,515           
171016           
1810,517           
191118           
2011,519           
211220           
2212,521           
231322           
2413,523           
251424           
2614,525           
271526           
2815,527           
291628           
3016,529           

Formeln der Tabelle
ZelleFormel
C2{=RGP(A2:A30;B2:B30)}
D2{=RGP(A2:A30;B2:B30)}
F2=SUMMENPRODUKT(TEILERGEBNIS(109;INDIREKT("B"&ZEILE(2:1000)))*TEILERGEBNIS(109;INDIREKT("B"&ZEILE(2:1000))))
G2=SUMMENPRODUKT(TEILERGEBNIS(109;INDIREKT("B"&ZEILE(2:1000)))*TEILERGEBNIS(109;INDIREKT("A"&ZEILE(2:1000))))
H2=TEILERGEBNIS(109;B2:B1000)
I2=TEILERGEBNIS(109;A2:A1000)
J2=TEILERGEBNIS(102;A2:A1000)
L2=(J2*G2-H2*I2)/(J2*F2-H2^2)
M2=(F2*I2-H2*G2)/(J2*F2-H2^2)
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß, Bastain

Anzeige
AW: RGP ohne ausgeblendete Zeilen
07.11.2013 16:09:52
Wolfango
....aufwendiger, als ich dachte....aber es klappt! Danke!
Gruß, Wo

... geht mE nicht mit RGB() ...
07.11.2013 14:24:05
neopa
Hallo Wolfgang,
... und zwar z.B. im Prinzip so wie es Bastian in seinem Beispiel bereits aufgezeigt hat. Nur könnte man dort in den Teilformeln F2 und G2 noch jeweils ein TEILERGEBNIS()-Formelteil einsparen und die Formelteile in je eine Endformel eingliedern. Dazu siehe unten.
Eine Ermittlung der Ergebnisse mit RGB() ist mE deswegen ausgeschlossen, weil die Funktion nicht in der Lage (ist bzw.) scheint, Leerzellen oder Textwerte aus der der Berechnung auszuschließen. Ich hab jedenfalls dazu mit den sonst so üblichen Methoden (mittels z.B. WENN() etc.) jedenfalls keinen Weg gefunden. Vielleicht aber findet einen solchen Weg ja jemand anders doch noch. Wäre schon interessant.
Die Ersatzformeln sind zwar sehr lang, dafür aber sehr flexibel in der Auswertung und einer evtl. zusätzlichen bedingten Anpassung.
 ABCD
1Y-WerteX- Wertemb
22,510,52
332  
43,53  
544  
64,55  
756  
85,57  

Formeln der Tabelle
ZelleFormel
C2=(TEILERGEBNIS(102;A2:A999)*SUMMENPRODUKT(TEILERGEBNIS(109;INDIREKT("B"&ZEILE(2:999)))*A2:A999)-TEILERGEBNIS(109;B2:B999)*TEILERGEBNIS(109;A2:A999))/(TEILERGEBNIS(102;A2:A999)*SUMMENPRODUKT(TEILERGEBNIS(109;INDIREKT("B"&ZEILE(2:999)))*B2:B999)-TEILERGEBNIS(109;B2:B999)^2)
D2=(SUMMENPRODUKT(TEILERGEBNIS(109;INDIREKT("B"&ZEILE(2:999)))*B2:B999)*TEILERGEBNIS(109;A2:A999)-TEILERGEBNIS(109;B2:B999)*SUMMENPRODUKT(TEILERGEBNIS(109;INDIREKT("B"&ZEILE(2:999)))*A2:A999))/(TEILERGEBNIS(102;A2:A999)*SUMMENPRODUKT(TEILERGEBNIS(109;INDIREKT("B"&ZEILE(2:999)))*B2:B999)-TEILERGEBNIS(109;B2:B999)^2)


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...

Anzeige
AW: ... geht mE nicht mit RGB() ...
07.11.2013 16:10:37
Wolfango
...jepp. Ist noch ein wenig einfacher!
Danke!
Gruß,
Wo

324 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige