Rechte Maustaste / Kopieren und Einfügen

Public Sub KonText_Neu() Dim Ctrl As CommandBarButton Dim intZahl As Integer For intZahl = CommandBars("Cell").Controls.Count To 1 Step -1 CommandBars("Cell").Controls(intZahl).Delete Next Set Ctrl = CommandBars("Cell").Controls.Add(msoControlButton) With Ctrl .Caption = "einfügen" .OnAction = "einfügen" End With Set Ctrl = Nothing End Sub

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Public Sub KonText_Neu() Dim Ctrl As CommandBarButton Dim intZahl As Integer For intZahl = CommandBars("Cell").Controls.Count To 1 Step -1 CommandBars("Cell").Controls(intZahl).Delete Next Set Ctrl = CommandBars("Cell").Controls.Add(msoControlButton) With Ctrl .Caption = "einfügen" .OnAction = "einfügen" End With Set Ctrl = CommandBars("Cell").Controls.Add(msoControlButton) With Ctrl .Caption = "kopieren" .OnAction = "kopieren" End With Set Ctrl = Nothing End Sub Public Sub einfügen() On Error Resume Next ActiveCell.PasteSpecial Paste:=xlPasteValues, _ Operation:=xlNone, SkipBlanks:=False, Transpose:=False End Sub Public Sub kopieren() On Error Resume Next ActiveCell.Copy End Sub Public Sub KonText_Reset() CommandBars("Cell").Reset End Sub

Hallo Micha,
es ist keine gute Idee das Zell-Kontextmenü von Excel zu verbiegen. Erstelle ein eigenes Popup und zeige das an.
Beispiel:
In das Modul "DieseArbeitsmappe":

Option Explicit

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    If Not Saved Then
        Select Case MsgBox("Sollen Ihre Änderungen in '" & Name & _
                    "' gespeichert werden", vbExclamation Or vbYesNoCancel)
            Case vbYes
                Save
            Case vbNo
                Saved = True
            Case vbCancel
                Cancel = True
        End Select
    End If
    If Not Cancel Then Call DeleteCommandbar
End Sub

Private Sub Workbook_Open()
    Call CreateCommandbar
End Sub

In das Modul der Tabelle:

Option Explicit

Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)

    Cancel = True

    CommandBars(COMMANDBAR_CELL).ShowPopup

End Sub

In ein Standardmodul (Menüleiste im VBA-Editor - Einfügen - Modul):

Option Explicit
Option Private Module

Private Declare PtrSafe Function IsClipboardFormatAvailable Lib "user32.dll" ( _
    ByVal wFormat As Long) As Long

Private Const CF_TEXT As Long = 1

Public Const COMMANDBAR_CELL As String = "Copy&Paste"

Public Sub CreateCommandbar()

    Dim objCommandBar As CommandBar
    Dim objCommandBarButton As CommandBarButton

    Call DeleteCommandbar

    Set objCommandBar = CommandBars.Add(Name:=COMMANDBAR_CELL, _
        Position:=msoBarPopup, Temporary:=True)

    Set objCommandBarButton = objCommandBar.Controls.Add( _
        Type:=msoControlButton)

    With objCommandBarButton

        .Caption = "Kopieren"
        .OnAction = "CopyFromRange"
        .FaceId = 19

    End With

    Set objCommandBarButton = objCommandBar.Controls.Add( _
        Type:=msoControlButton)

    With objCommandBarButton

        .Caption = "Einfügen"
        .OnAction = "PasteInRange"
        .FaceId = 22

    End With

    Set objCommandBarButton = Nothing
    Set objCommandBar = Nothing

End Sub

Public Sub DeleteCommandbar()

    Dim objCommandBar As CommandBar

    For Each objCommandBar In CommandBars

        If objCommandBar.Name = COMMANDBAR_CELL Then _
            objCommandBar.Delete

    Next
End Sub

Public Sub CopyFromRange()
    Call Selection.Copy
End Sub

Public Sub PasteInRange()
    If IsClipboardFormatAvailable(CF_TEXT) = 1 Then
        Call ActiveCell.PasteSpecial(Paste:=xlPasteValues)
    Else
        Call Beep
    End If
End Sub

Gruß
Nepumuk

Beliebteste Forumthreads (12 Monate)

Rechte Maustaste / Kopieren und Einfügen

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

336 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Rechte Maustaste / Kopieren und Einfügen

6 Beiträge zum Forumthread Beiträge zu diesem Forumthread

336 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread