VBA für Datei Suchen und einfügen in Email

Forumthread: VBA für Datei Suchen und einfügen in Email

30.05.2018 15:25:30

Patrick

Hallo zusammen,
ich hoffe ihr könnt mir helfen. Ich würde mich über ein Makro freuen was für mich eine Datei im festgelegten Ordner sucht (Information kommt aus zb. Zelle A1) und mir diese in eine Email einfügt. Danach soll die Datei in einem Order abgelegt werden die zb der Vormonat ist (Beispiel: April). Also aktueller Monat Mai, Ablage in Ordner April. Ordner liegt im Ordner wo vorher gesucht wurde durch Excel. Vielen Dank für eure Unterstützung.
Grüße

1
Beitrag zum Forumthread

Beitrag zu diesem Forumthread

Betreff

Datum

Anwender

AW: VBA für Datei Suchen und einfügen in Email

30.05.2018 18:38:15

Dieter

AW: VBA für Datei Suchen und einfügen in Email

30.05.2018 18:38:15

Dieter

Hallo Patrick,
ich habe ein Demonstrationsbeispiel von mir etwas angepasst und füge es dir als Anhaltspunkt bei.

Sub E_Mail_Verschicken()
Dim Anlage As String
Dim Betreff As String
Dim Datei As String
Dim Empfänger As String
Dim Mail_Text As String
Dim olAktiviert As Boolean
Dim olApp As Outlook.Application
Dim olMI As Outlook.MailItem
Dim Pfad As String
Dim PfadVormonat As String
Dim Vormonat As String
Pfad = "C:\Temp\"
Datei = ThisWorkbook.Worksheets(1).Range("A1")
Empfänger = "xyz@fantasie.de"
Betreff = "Unterlagen für Budgetplanung"
Mail_Text = "In der Anlage sind die neuen Planungsunterlagen " & _
"beigefügt: " & vbNewLine & _
Datei & vbNewLine & _
Format$(Now, "dd.mm.yyyy hh:mm:ss")
Anlage = Pfad & Datei
If Dir(Anlage) = "" Then
MsgBox Anlage & " existiert nicht"
Exit Sub
End If
On Error Resume Next
Set olApp = GetObject(Class:="Outlook.Application")
If Err  0 Then
Set olApp = CreateObject("Outlook.Application")
olAktiviert = True
End If
On Error GoTo 0
Set olMI = olApp.CreateItem(olMailItem)
With olMI
.Body = Mail_Text
.To = Empfänger
.Subject = Betreff
.Attachments.Add Source:=Anlage, _
Type:=olByValue
.Send
End With
If olAktiviert Then
olApp.Quit
End If
Set olMI = Nothing
Set olApp = Nothing
' Datei ablegen
Vormonat = MonthName(Month(DateAdd("m", -1, Date)))
PfadVormonat = Pfad & Vormonat & "\"
If Dir(PfadVormonat, vbDirectory) = "" Then
MsgBox PfadVormonat & " existiert nicht"
Exit Sub
End If
FileCopy Source:=Anlage, _
Destination:=PfadVormonat & Datei
End Sub

https://www.herber.de/bbs/user/121894.xlsm
Viele Grüße
Dieter

Beliebteste Forumthreads (12 Monate)

VBA für Datei Suchen und einfügen in Email

Forumthread: VBA für Datei Suchen und einfügen in Email

1 Beitrag zum Forumthread Beitrag zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

1
Beitrag zum Forumthread

Beitrag zu diesem Forumthread