Microsoft Excel

Herbers Excel/VBA-Archiv

In Zeile Anzahl Zellen mit Text "HF"ermitteln | Herbers Excel-Forum


Betrifft: In Zeile Anzahl Zellen mit Text "HF"ermitteln von: Marcel Vollenweider
Geschrieben am: 31.01.2012 01:54:06

Für einen Ferienplan mit 20 Mitarbeiter möchte ich in einer Tabelle mit 365 Spalten für 365 Tage und 20 Zeilen für 20 Mitarbeiter die Anzahl eingetragener Ferientage, und die Anzahl der dazugekommenen Ferientage für Arbeiten an Samstagen und Sonntagen berechnen.
Pro Mitarbeiter Zeile sollten alle Zellen von Mo - FR mit dem Texteintrag FE als ganztägigen Ferientag und alle Zellen mit Eintrag HF als Halbtägigen Ferientag als Bezogene Tage zusammengezählt werden.
Einträge mit FE und oder HF an den Wochenenden also Sa - So hingegen sollten als zusätzliche Ferientage zusammengezählt werden.
Daraus sollte dan die Berechnung (Guthaben - Bezogene FT + Gutgeschriebene FT = Ferien Saldo) erfolgen.
Spalte A Mitarbeitername
Spalte B Ferien guthaben
Spalte C Bezogene Ferientage
Spalte D Gutgeschrieben Ferientage
Spalte E Ferien Saldo
Spalte F bis NH Tage 1. Januar bis 1. Dezember

Mit den Funktionen ZÄHLENWENN, ZÄHLENWENNS und ANZAHL, ANZAHL2 konnte ich keine Lösung finden, da damit Zellen mit einem bestimmten Text nur in einem einzigen zusammenhängenden Zellenbereich gezählt werden.
Meine Bereiche sind jedoch in 52 x Mo-Fr und 52 x Sa-So unterteilt.
Kennt jemand eine Lösung?

  

Betrifft: AW: In Zeile Anzahl Zellen mit Text "HF"ermitteln von: hary
Geschrieben am: 31.01.2012 02:20:25

Moin Marcel
meinst Du sowas?

Tabelle1

 ABCDEFGHIJ
1    SoMoDiMiDoFrSaSo
2WocheWE01.01.201202.01.201203.01.201204.01.201205.01.201206.01.201207.01.201208.01.2012
33,53HFFEFEHFFE  FEFE

verwendete Formeln
Zelle Formel Bereich
A3 =SUMMENPRODUKT((WOCHENTAG(C2:K2;2)<6)*(C3:K3="FE"))+(SUMMENPRODUKT((WOCHENTAG(C2:K2;2)<6)*(C3:K3="HF"))/2) 
B3 =SUMMENPRODUKT((WOCHENTAG(C2:K2;2)>5)*(C3:K3="FE"))+SUMMENPRODUKT((WOCHENTAG(C2:K2;2)>5)*(C3:K3="HF")) 

Tabellendarstellung in Foren Version 5.30


gruss hary


  

Betrifft: und noch zwei... von: Erich G.
Geschrieben am: 31.01.2012 08:01:13

Hi zusammen,
in A4:B5 noch zwei Alternativen-Paare zu Harys Formeln:

 ABCDEFGHIJ
1  SoMoDiMiDoFrSaSo
2Mo-FrSa-So01.01.201202.01.201203.01.201204.01.201205.01.201206.01.201207.01.201208.01.2012
33,53HFFEFEHFFE  FEFE
43,53        
53,53        

Formeln der Tabelle
ZelleFormel
A3=SUMMENPRODUKT((WOCHENTAG(C2:K2;2)<6)*(C3:K3="FE"))+(SUMMENPRODUKT((WOCHENTAG(C2:K2;2)<6)*(C3:K3="HF"))/2)
B3=SUMMENPRODUKT((WOCHENTAG(C2:K2;2)>5)*(C3:K3="FE"))+SUMMENPRODUKT((WOCHENTAG(C2:K2;2)>5)*(C3:K3="HF"))
A4=SUMMENPRODUKT((WOCHENTAG(C2:K2;2)<6)*((C3:K3="FE")+(C3:K3="HF")/2))
B4=SUMMENPRODUKT((WOCHENTAG(C2:K2;2)>5)*((C3:K3="FE")+(C3:K3="HF")))
A5=SUMMENPRODUKT((REST(C2:K2;7)>1)*((C3:K3="FE")+(C3:K3="HF")/2))
B5=SUMMENPRODUKT((REST(C2:K2;7)<2)*((C3:K3="FE")+(C3:K3="HF")))

Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich


Beiträge aus den Excel-Beispielen zum Thema "In Zeile Anzahl Zellen mit Text "HF"ermitteln"