Seitenumbruch vor Zeile mit Text

Forumthread: Seitenumbruch vor Zeile mit Text

14.01.2014 10:32:32

Daniel

Hallo mal wieder,
nachdem die letzten Probleme so wunderbar gelöst wurden, möchte ich euch noch einmal belasten. Ich möchte automatisiert Seitenumbrüche einfügen.
Hier das Beispiel: https://www.herber.de/bbs/user/88797.xlsx
(Den Seitenumbruch habe ich jeweils mit einem Unterstrich markiert.)
Wie ihr seht, ist der Seitenumbruch in Beispiel 1 bezogen auf den Text der in Spalte A steht und in Beispiel 2 bezogen auf Spalte K.
Mal sind Leerzeilen zwischendrin, mal nicht.
Letzlich sind es immer thematische Blöcke die hierarchisch aufgebaut sind (und zum Teil aus Pivottabellen kommen) und die ich auf einzelnen Seiten beim Ausdrucken aufzeigen will.
Liste umfasst gerne mal 10.000 Zeilen mit 200-300 solcher thematischen Blöcke, daher ist manuelle Arbeit immer aufwändig nach einem Update der Zahlen (und damit auch der Anzahl Zeilen).
Ich sollte weiterhin in der Lage sein, manuelle Seitenumbrüche einzufügen.
Jemand eine Idee dazu?
Danke schonmal vorab
Daniel

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Seitenumbruch vor Zeile mit Text

14.01.2014 11:26:04

Rudi
AW: Seitenumbruch vor Zeile mit Text

14.01.2014 11:28:56

UweD
AW: Seitenumbruch vor Zeile mit Text

14.01.2014 11:46:40

Daniel

AW: Seitenumbruch vor Zeile mit Text

14.01.2014 11:26:04

Rudi

Hallo,

Sub PageBreaksKategorie()
Dim rngC As Range
ActiveWindow.View = xlPageBreakPreview
With ActiveSheet
.ResetAllPageBreaks
For Each rngC In .Columns(1).SpecialCells(xlCellTypeConstants)
If rngC.Row > 1 And Len(Trim(rngC)) Then
.HPageBreaks.Add rngC
End If
Next
End With
ActiveWindow.View = xlNormalView
End Sub

Sub PageBreaksThema()
Dim rngC As Range
ActiveWindow.View = xlPageBreakPreview
With ActiveSheet
.ResetAllPageBreaks
For Each rngC In .Columns(4).SpecialCells(xlCellTypeConstants)
If rngC.Row > 1 And Len(Trim(rngC)) Then
If Len(Trim(rngC.Offset(1))) Then
Else
.HPageBreaks.Add rngC.Offset(1, -3)
End If
End If
Next
End With
ActiveWindow.View = xlNormalView
End Sub

Gruß
Rudi

AW: Seitenumbruch vor Zeile mit Text

14.01.2014 11:28:56

UweD

Hallo
so ?

Sub Gruppe_SeitenWechsel()
On Error GoTo Fehler
Dim i&, SP$, Spalte%
Dim RR&, CC%, EZ%, VN$
Application.ScreenUpdating = False
RR = ActiveSheet.Cells.SpecialCells(xlCellTypeLastCell).Row 'Letzte Zeile des gesamten  _
Blattes
CC = ActiveSheet.Cells.SpecialCells(xlCellTypeLastCell).Column 'Letzte Spalte des gesamten  _
Blattes
EZ = 4 'erste Zeile mit Daten
SP = InputBox("Gruppenwechsel in welcher Spalte?", , "A")
Spalte = Asc(UCase(SP)) - 64
If Spalte > CC Then
MsgBox "Spalte auserhalb Datenbereich"
Exit Sub
End If
VN = UCase(InputBox("Gruppenwechsel (V)or / (N)ach der Zeile?", , "V"))
ActiveSheet.ResetAllPageBreaks
For i = EZ To RR
If VN = "V" Then
If ActiveSheet.Cells(i, Spalte).Value  "" Then
ActiveWindow.ActiveSheet.HPageBreaks.Add Before:=Rows(i)
End If
ElseIf VN = "N" Then
If ActiveSheet.Cells(i, Spalte).Value  "" And ActiveSheet.Cells(i + 1, Spalte). _
Value = "" Then
ActiveWindow.ActiveSheet.HPageBreaks.Add Before:=Rows(i + 1)
End If
End If
Next
Err.Clear
Fehler:
If Err.Number  0 Then MsgBox "Fehler: " & Err.Number & vbLf & Err.Description: Err.Clear
End Sub

Gruß UweD

AW: Seitenumbruch vor Zeile mit Text

14.01.2014 11:46:40

Daniel

Hallo Rudi, hallo Uwe,
funktioniert beides wunderbar, danke für eure Mühe. Immer schön zu sehen, dass unterschiedliche Ansätze zum selben Ergebnis kommen.
Besten Dank
Daniel

Beliebteste Forumthreads (12 Monate)

Forumthread: Seitenumbruch vor Zeile mit Text

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread