Zelleninhalt suchen und Nachbarzelle Rechts aussch

Forumthread: Zelleninhalt suchen und Nachbarzelle Rechts aussch

Valeri

Hallo Excel Freunde,
ich suche nach einem Code der es mir ermöglicht nach einem Zelleninhalt zu suchen.
Das suchwort oder zahl gebe ich in einer textbox in der userform ein, es soll dan die zelle mit diesem
inhalt gefunden werden und dann die zelle rechts daneben in die zwischenablage ausgeschnitten werden.
Gruß Valeri

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

AW: Zelleninhalt suchen und Nachbarzelle Rechts aussch

08.11.2009 00:26:37

IngGi

Hallo Valeri,
versuch's mal so:

Dim vntGesucht As Variant
If IsNumeric(UserForm1.TextBox1) Then
vntGesucht = CDbl(UserForm1.TextBox1)
Else
vntGesucht = UserForm1.TextBox1
End If
With Worksheets("Tabelle1").Cells
If Not .Find(vntGesucht, LookAt:=xlWhole) Is Nothing Then
.Find(vntGesucht, LookAt:=xlWhole).Offset(0, 1).Copy
Else
MsgBox "Inhalt der Textbox nicht gefunden!"
End If
End With

Gruß Ingolf

AW: Zelleninhalt suchen und Nachbarzelle Rechts aussch

08.11.2009 00:47:11

Beate

Hallo Valeri,
in deiner Userform liegt TextBox1 und CommandButton1.
Dann der Code in der Userform:
Private Sub CommandButton1_Click()
    Dim Found As Range, i As String
    Dim oData As New DataObject
    Dim sText As String
    i = TextBox1.Text
    Set Found = ActiveSheet.Cells.Find(what:=i)
    If Found Is Nothing Then
        MsgBox "Nicht gefunden."
    Else
        'siehe http://www.online-excel.de/excel/singsel_vba.php?f=28
        sText = Found.Offset(0, 1)
        With oData
            .SetText sText
            .PutInClipboard
        End With
        Found.Offset(0, 1).ClearContents
    End If
    Unload Me
End Sub

Gruß,
Beate

Genau so! ;o)

08.11.2009 01:26:50

Valeri

Hallo Beate,
Du hast mich genau richtig verstanden. Genau so soll es sein.
Danke!
Gruß Valeri

Verbesserung

08.11.2009 01:28:03

Beate

Hallo Valeri,
nimm lieber diesen Code, um das Makro sowohl für Texte als auch für Werte lauffähig zu haben:
Private Sub CommandButton1_Click()
    Dim Found As Range, i As Variant
    Dim oData As New DataObject
    Dim sText As String
    If IsNumeric(UserForm1.TextBox1) Then
        i = CDbl(UserForm1.TextBox1)
    Else
        i = UserForm1.TextBox1
    End If
    Set Found = ActiveSheet.Cells.Find(what:=i)
    If Found Is Nothing Then
        MsgBox "Nicht gefunden."
    Else
        'siehe http://www.online-excel.de/excel/singsel_vba.php?f=28
        sText = Found.Offset(0, 1)
        With oData
            .SetText sText
            .PutInClipboard
        End With
        Found.Offset(0, 1).ClearContents
    End If
    Unload Me
End Sub

Gruß,
Beate

AW: Verbesserung

11.11.2009 23:07:57

Valeri

Hallo Beate,
vielen dank!
Noch eine frage. Nach dem ich den CommandButton1 geklickt habe und die codeausführung beendet ist, möchte ich das die TextBox1 geleert wird und der körser blinkt wieder in der textbox. Währe schön wenn du mir diesen kleinen wunsch noch erfüllen könntest.
Gruß Valeri

AW: Verbesserung

Beate

Hallo Valeri,
Private Sub CommandButton1_Click()
    Dim Found As Range, i As Variant
    Dim oData As New DataObject
    Dim sText As Variant
    If IsNumeric(Me.TextBox1) Then
        i = CDbl(Me.TextBox1)
    Else
        i = Me.TextBox1
    End If
    Set Found = ActiveSheet.Cells.Find(what:=i)
    If Found Is Nothing Then
        MsgBox "Nicht gefunden."
    Else
        'siehe http://www.online-excel.de/excel/singsel_vba.php?f=28
        sText = Found.Offset(0, 1)
        With oData
            .SetText sText
            .PutInClipboard
        End With
        Found.Offset(0, 1).ClearContents
    End If
    With Me.TextBox1
        .Value = ""
        .SetFocus
    End With
End Sub

Gruß,
Beate

Beliebteste Forumthreads (12 Monate)

Zelleninhalt suchen und Nachbarzelle Rechts aussch

Forumthread: Zelleninhalt suchen und Nachbarzelle Rechts aussch

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Zelleninhalt suchen und Nachbarzelle Rechts aussch

Forumthread: Zelleninhalt suchen und Nachbarzelle Rechts aussch

6 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread