Excel Matrix, Anzeige gleiche Höchstwerte

Bild

Betrifft: Excel Matrix, Anzeige gleiche Höchstwerte
von: Michael
Geschrieben am: 27.07.2015 10:10:42

Hallo, ich habe folgendes Problem in angehängter Matrix:
https://www.herber.de/bbs/user/98942.xlsx
In Zelle J4 würde ich mir gerne den Namen aus Zeile 1 anzeigen lassen welcher den höchsten Wert aus den Zeilen B4 bis I4 anzeigt, unter der Einschränkung eines "A" in Zeile 2 usw.. Das funktioniert soweit dank user "WF" auch hervorragend. Mein Problem ist nun, dass wenn ich 2mal einen gleichen höchsten Wert habe dieser nicht angezeigt wird (am besten in Zelle J5). Ich Ich würde mich über eine Lösung sehr freuen.
Folgende Formel ist im Moment im Einsatz:
{=INDEX(B$1:I$1;VERGLEICH(MAX(WENN(B$2:I$2="A";B4:I4))&"A";B4:I4&B$2:I$2;0))}
VG
Michael

Bild

Betrifft: Du wiederholst Deine Fehler !
von: WF
Geschrieben am: 27.07.2015 12:04:15
Hi,
ich hatte Dir schon mal gesagt, dass die A und B in Zeile 2 Leerzeichen enthalten.
Da kann natürlich nichts funktionieren.
Das, was Du willst, ist lösbar - bin jetzt aber weg.
WF

Bild

Betrifft: AW: Excel Matrix, Anzeige gleiche Höchstwerte
von: Michael
Geschrieben am: 27.07.2015 13:25:36
... jetzt sollte es passen.
https://www.herber.de/bbs/user/99091.xls
VG
Michael

Bild

Betrifft: Anzeige gleicher Höchstwerte bei A
von: WF
Geschrieben am: 27.07.2015 15:37:31
Hi,
in J4:
{=WENNFEHLER(INDEX($B$1:$I$1;KKLEINSTE(WENN($B$2:$I$2="A";WENN($B4:$I4=MAX(WENN($B$2:$I$2="A"; $B4:$I4));SPALTE($A4:$H4)));SPALTE(A1)));"") }
nach rechts und nach unten kopieren
Salut WF

Bild

Betrifft: AW: Anzeige gleicher Höchstwerte bei A
von: Michael
Geschrieben am: 27.07.2015 18:47:20
... unglaublich, Danke schön, es funktioniert :-)
Gruß
Michael

Bild

Betrifft: Schöner ist: Anzeige gleicher Höchstwerte bei A
von: Besserwisser
Geschrieben am: 27.07.2015 23:36:29
schöner finde ich
=WENNFEHLER(INDEX(B$1:I$1;;AGGREGAT(15;6;SPALTE($A1:$H1)/(B$4:I$4=MAX(B$4:I$4*(B$2:I$2="A"))); ZEILE(A1)));"")
nach unten kopieren
Viele Grüße
Christian N.

Bild

Betrifft: so wohl nicht
von: WF
Geschrieben am: 28.07.2015 08:13:52
Hi,
Beim Runterkopieren erscheinen Leerzellen ?
Und was ist mit Kopieren nach rechts ?
WF

Bild

Betrifft: AW: so wohl nicht
von: Besserwisser
Geschrieben am: 28.07.2015 12:16:22
Wieso nach rechts kopieren?
Ergebnisse J4, J5
Bitte noch prüfen, ob nicht Zahlen als Text eingetragen sind.
Viele Grüße
Christian N.

Bild

Betrifft: Du musst schon die Aufgabe ganz lesen
von: WF
Geschrieben am: 28.07.2015 12:24:04
Hi,
Die Ausgangsmatrix steht in dem ersten posting - das sind 14 Zeilen.
Du beziehst Dich nur auf die Korrektur mit einer Zeile.
Rechts kopieren: die Mehrfachtreffer müssen dann logischerweise nebeneinander stehen.
WF

Bild

Betrifft: kürzere Formel für gewünschten Bereich:
von: Besserwisser
Geschrieben am: 02.08.2015 19:56:48
Hallo,
hier mein Ansatz unter Berücksichtigung des gewünschten Bereiches (nachfolgende Formel steht in einer Zelle der 4. Zeile)
=WENNFEHLER(INDEX($B$1:$I$1;;AGGREGAT(15;6;SPALTE($A1:$I1)/($B4:$I4=MAX($B4:$I4*($B$2:$I$2="A"))); SPALTE(A1)));"")
Nun noch nach rechts & unten kopieren.
Viel Spaß!
Viele Grüße
Christian N.

Bild

Betrifft: AW: so wohl nicht
von: Josef B
Geschrieben am: 28.07.2015 13:24:25
Hallo
Der Aufbau der Formel ist schon richtig, aber zum Kopieren der Formel
muss die Zuteilung der $ angepasst werden.
Gruss Sepp

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Excel Matrix, Anzeige gleiche Höchstwerte"