Import CommandButton

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
Bild

Betrifft: Import CommandButton
von: DerNoob 2015
Geschrieben am: 24.11.2015 11:54:09

Hallo Experten,
ich bin leider ein absoluter Neuling in VBA, ich hoffe ihr könnt mir hier helfen. Ich versuche eine Makro zu erstellen und zwar soll über das CommandButton ein Import einer externen Datei stattfinden. Ich bin in der Datei „Test_Import“ (C:\Users\bia5le\Desktop\Test_Import.xlsx) dort habe ich ein Button erstellt:

Private Sub CommandButton1_Click()
Call datei_import
End Sub
Nun will ich im Module „datei_import“ definieren, das wenn man den Button klickt die externe Datei „Umsatz 2014“ (C:\Users\bia5le\Desktop\Umsatz 2014.xlsx) in „Test_Import“ (C:\Users\bia5le\Desktop\Test_Import.xlsx) in der Tabelle1 ab der Zeile A14 den Inhalt einfügt.
Kann mir hier jemand helfen? :(
Vielen lieben Dank für jegliche Antwort.

Bild

Betrifft: AW: Import CommandButton
von: fcs
Geschrieben am: 25.11.2015 13:09:15
Hallo DerNoob,
als Ansatz mal das folgende Makro
Gruß
Franz

Sub datei_import()
  Dim wksZiel As Worksheet
  Dim wkbQuelle As Workbook, strQuelle As String
  Dim wksQuelle As Worksheet
  Dim Zeile_Q As Long
  Dim Zeile_Z As Long
  Dim Zeile_Z1 As Long
  
  
  strQuelle = "C:\Users\bia5le\Desktop\Umsatz 2014.xlsx" 'ggf. anpaasen
  If Dir(Pathname:=strQuelle) = "" Then
    MsgBox "Datei nicht gefunden!" & vbLf & strQuelle, vbOKOnly, "Import Daten"
  Else
    Set wksZiel = ActiveWorkbook.Worksheets(1) 'oder Worksheets("Tabelle1")
    Application.ScreenUpdating = False
    With wksZiel
      Zeile_Z1 = 14
      Zeile_Z = .UsedRange.Row + .UsedRange.Rows.Count - 1
      If Zeile_Z >= Zeile_Z1 Then
        'Altinhalte löschen
        .Range(.Rows(Zeile_Z1), .Rows(Zeile_Z)).Clear
      End If
    End With
    'Quelldatei schreibgeschützt öffnen
    Set wkbQuelle = Application.Workbooks.Open(Filename:=strQuelle, ReadOnly:=True)
    Set wksQuelle = wkbQuelle.Sheets(1) 'ggf. anpassen
    With wksQuelle
      Zeile_Q = .UsedRange.Row + .UsedRange.Rows.Count - 1
      .Range(.Rows(1), .Rows(Zeile_Q)).Copy wksZiel.Cells(Zeile_Z1, 1)
    End With
    Application.CutCopyMode = False
    wkbQuelle.Close savechanges:=False
    Application.ScreenUpdating = True
  End If
  
End Sub


Bild

Betrifft: AW: Import CommandButton
von: DerNoob 2015
Geschrieben am: 26.11.2015 20:03:19
Perfekt, funktioniert super, hab nur noch einen Befehl eingefügt damit Bilder und Diagramme ebenfalls vor dem Import entfernt werden. Dankeschön :)

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Import CommandButton"