Microsoft Excel

Herbers Excel/VBA-Archiv

Informationen und Beispiele zum Thema CommandButton
BildScreenshot zu CommandButton CommandButton-Seite mit Beispielarbeitsmappe aufrufen

CommandButton ausblenden | Herbers Excel-Forum


Betrifft: CommandButton ausblenden von: Frank H.
Geschrieben am: 15.12.2009 11:52:37

Hallo Zusammen!!!

Ich grüße euch alle herzlich und bitte um Hilfe! Mittels folgendem Code blende ich bspw. den Button37 aus.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

If ActiveSheet.Cells(1, 16) = 1 Then
CommandButton37.Visible = True
Else
CommandButton37.Visible = False
End If

Jetzt habe ich aber in diesem Blatt noch weitere Button, diese haben mir das Erstellen der Datei erleichtert, aber werden dann vom Anwender nicht mehr benötigt, wie kann ich diese und nur diese, denn bestimmte sollen auf dem Blatt erhalten bleiben, ausblenden. Es sollen die CommandButton 37 - 108 sein???

Für jeden Rat wie immer dankbar!!!

Gruß Frank H.

  

Betrifft: AW: CommandButton ausblenden von: Philipp
Geschrieben am: 15.12.2009 11:59:30

Versteh die Frage nicht. . Mit z.B. CommandButton37.Visible sprichst du ja bestimmte Buttons an.

Oder willst du sie mit einer Schleife ausblenden (37-108 )

Wie meinst du das genau

Philipp


  

Betrifft: AW: CommandButton ausblenden von: Frank H.
Geschrieben am: 15.12.2009 12:06:15

Hallo Philipp!

Wenn es mit einer Schleife funzt, na klar. Es sollen die Button 37 - 108 verschwinden wenn keine 1 in Zelle P1 steht.

Kannst du helfen?

Gruß Frank H.


  

Betrifft: AW: CommandButton ausblenden von: Uduuh
Geschrieben am: 15.12.2009 12:20:33

Hallo,

Sub ttt()
  Dim oOle As OLEObject
  If Cells(1, 16) = 1 Then
    For Each oOle In ActiveSheet.OLEObjects
      If LCase(oOle.Name) Like "commandbutton*" Then
        Select Case CInt(Replace(LCase(oOle.Name), "commandbutton", ""))
          Case 37 To 108
            oOle.Visible = False
          Case Else
            oOle.Visible = True
        End Select
      End If
    Next
  End If
End Sub

Gruß aus’m Pott
Udo



  

Betrifft: Alternativ über Zählschleife von: {Boris}
Geschrieben am: 15.12.2009 12:36:15

Hi Frank,

Option Explicit

Sub wech_damit()
Dim i As Long
If [p1] <> 1 Then
   With Tabelle1 'Codename der Tabelle - ggfls. anpassen!!
      For i = 37 To 108
       .OLEObjects("CommandButton" & i).Visible = Not .OLEObjects("CommandButton" & i).Visible
      Next i
   End With
End If
End Sub
Das erneute Ausführen des Codes blendet die Buttons wieder ein.

Grüße Boris


  

Betrifft: AW: Alternativ über Zählschleife von: Frank H.
Geschrieben am: 15.12.2009 14:01:37

Hallo Ihr Zwei!!!

Danke für die schnelle Hilfe, konnte erst jetzt probieren und leider funzt es nicht so wie ich es gern hätte!

Der Code von Udo lässt die Button verschwinden, aber sie kommen nicht wie gewünscht wieder.

Der Code von Boris läuft leider nicht, wenn ich es in diese Codezeile packe

Private Sub Worksheet_SelectionChange(ByVal Target As Range).

Aber ich möchte nicht noch einen zusätzlichen sichtbaren Button für die User die anschließend damit arbeiten sollen!

Könnt ihr noch einmal drauf schauen??? Es wäre sehr nett!!!

Danke und Gruß Frank H.


  

Betrifft: AW: Alternativ über Zählschleife von: {Boris}
Geschrieben am: 15.12.2009 14:24:13

Hi Frank,

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim i As Long
With Me
   For i = 37 To 108
      .OLEObjects("CommandButton" & i).Visible = .Range("P1") = 1
   Next i
End With
End Sub
Grüße Boris


  

Betrifft: AW: Alternativ über Zählschleife von: Uduuh
Geschrieben am: 15.12.2009 14:27:18

Hallo,
dann so:

Sub ttt()
  Dim oOle As OLEObject
    For Each oOle In ActiveSheet.OLEObjects
      If LCase(oOle.Name) Like "commandbutton*" Then
        Select Case CInt(Replace(LCase(oOle.Name), "commandbutton", ""))
          Case 37 To 108
            oOle.Visible = Not (Cells(1, 16) = 1)
          Case Else
            oOle.Visible = True
        End Select
      End If
    Next
End Sub

Gruß aus'm Pott
Udo


  

Betrifft: AW: Alternativ über Zählschleife von: Frank H.
Geschrieben am: 15.12.2009 14:43:11

Hallo Zusammen!!!

Ihr seid Spitze, der allerherzlichste Dank und noch 'ne schöne Vorweihnachtszeit wünscht

ehrfürchtig

Frank H.


Beiträge aus den Excel-Beispielen zum Thema "CommandButton ausblenden"