Auslesen von Wert in anderem Sheet

Forumthread: Auslesen von Wert in anderem Sheet

27.06.2019 16:08:29

Wert

Hallo Zusammen,
Ich habe eine Arbeitsmappe mit über 50 Blättern hier eine verkleinerte Beispieltabelle
https://www.herber.de/bbs/user/130615.xlsx
Ich suche eine Formel für Blatt "HAUPT" Zelle B3 (gelb) in der im Blatt "LAB_E.0233" die Summierung der Werte aus Spalte "WERT B" gemacht wird, wenn in der Spalte A folgende Übereinstimmung gefunden wurde:
Aus Blatt "HAUPT" die alle Zeichen aus Zelle A3 ausser den "?" (alles rote)
E.0233.?.1.?.A
Diese Formel sollte dann entsprechend kopierbar sein in den Bereich B3-D11
Ich weiss es klingt ein wenig kompliziert. Aber ich weiss auch das ihr die besten seid die es zu finden gibt für komplizierte Formeln ;c)
Vielen Dank schon mal vorab,
LG
ChrisW

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Auslesen von Wert in anderem Sheet

27.06.2019 16:14:45

Wert
AW: Auslesen von Wert in anderem Sheet

27.06.2019 17:26:52

Wert
AW: dafür dann INDIREKT() ...

27.06.2019 19:14:48

neopa
DANKE !!!!

28.06.2019 16:00:07

ChrisW
AW: bitteschön owT

28.06.2019 16:19:12

neopa

AW: Auslesen von Wert in anderem Sheet

27.06.2019 16:14:45

Wert

Hola,
=SUMMENPRODUKT((LINKS(LAB_E.0233!$A$2:$A$10;6)=LINKS($A3;6))*(TEIL(LAB_E.0233!$A$2:$A$10;11;3) =TEIL($A3;11;3))*(RECHTS(LAB_E.0233!$A$2:$A$10;2)=RECHTS($A3;2))*(LAB_E.0233!$C$2:$C$10))
Gruß,
steve1da

AW: Auslesen von Wert in anderem Sheet

27.06.2019 17:26:52

Wert

Hallo Steve,
Ja super - vielen Dank, das war die halbe Miete,
aber gibt es noch die Möglichkeit den TAB namen zu automatisieren, wie z.B.
"LAB_" & B2 & "!" um in der Formel
LAB_E.0233! zu ersetzen?
so das aus der Formel (hier in deutsch)
=SUMMENPRODUKT((LINKS(LAB_E.0233!$A$2:$A$10;6)=LINKS($A3;6))*(TEIL(LAB_E.0233!$A$2:$A$10;11;3) =TEIL($A3;11;3))*(RECHTS(LAB_E.0233!$A$2:$A$10;2)=RECHTS($A3;2))*(LAB_E.0233!$C$2:$C$10))
dann folgendes herauskäme: (hier in englisch)
=SUMPRODUCT((LEFT("LAB_" & B2 & "!" & $A$2:$A$10;6)=LEFT($A3;6))*(MID("LAB_" & B2 & "!" & $A$2:$A$10; 11;3) =MID($A3;11;3))*(RIGHT("LAB_" & B2 & "!"& $A$2:$A$10;2)=RIGHT($A3;2)) *("LAB_" & B2 & "!" & $C$2:$C$10))
Hierbei kommt leider "#VALUE" Meldung heraus.
LG
ChrisW

AW: dafür dann INDIREKT() ...

27.06.2019 19:14:48

neopa

Hallo Chris,
... und wenn Du dies zusätzlich noch mit INDEX() und VERGLEICH() kombinierst, hast Du gleichzeitige noch auch die richtige Auswertung für einen wechselnden Vorgabewert in A1.
In B3:
=SUMMENPRODUKT((LINKS(INDIREKT("LAB_"&B$2&"!A2:A99");6)=LINKS($A3;6))*
(TEIL(INDIREKT("LAB_"&B$2&"!A2:A99");11;3) =TEIL($A3;11;3))*
(RECHTS(INDIREKT("LAB_"&B$2&"!A2:A99");2)=RECHTS($A3;2))*
INDEX(INDIREKT("LAB_"&B$2&"!A2:E99");;VERGLEICH($A$1;INDIREKT("LAB_"&B$2&"!1:1");0))))
und bei Bedarf die Formel noch mit WENNFEHLER() klammern und anschließend nach rechts und unten ziehend kopieren.
Gruß Werner
.. , - ...

DANKE !!!!

28.06.2019 16:00:07

ChrisW

Hallo Werner,
wenn auch etwas spät, aber vielen Dank für diese Hilfe.
mit ein wenig Umstellung konnte ich die Formel erfolgreich in meiner Anwendung nutzen, so dass ich jetzt eine ordentliche Übersicht über die wichtigsten Daten der 'zig Tabellen liefern kann.
LG
ChrisW

AW: bitteschön owT

28.06.2019 16:19:12

neopa

Gruß Werner
.. , - ...

Beliebteste Forumthreads (12 Monate)

Auslesen von Wert in anderem Sheet

Forumthread: Auslesen von Wert in anderem Sheet

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread