Live-Forum - Die aktuellen Beiträge
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Bereich einer Tabelle in ext. Workbook speichern?

Forumthread: Bereich einer Tabelle in ext. Workbook speichern?

Bereich einer Tabelle in ext. Workbook speichern?
11.07.2006 19:36:13
Ina
Hallo Forum,
ich habe eine Frage...
Ist es per VBA/Macro möglich, den Bereich einer Tabelle (Tabelle "Test" Bereich C5 - C152) in ein externes Workbook (Workbook "Testende", Tabelle "Test1") im Verzeichnis "D:\TESTEN" zu speichern.
Es wäre schön, wenn das Macro das Verzeichnis aus einer bestimmten Zelle (G3) auslesen könnte, falls der Tabellenbereich in einem andere Workbook gespeichert werden sollte.
Danke für eure Hilfe und wenn möglich, einen Beispiel-Code.
Gruss,
Ina
Anzeige

1
Beitrag zum Forumthread
Beitrag zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Bereich einer Tabelle in ext. Workbook speiche
11.07.2006 23:14:28
Josef
Hallo Ina!
In Tabelle "Test" steht in "G3" der Pfad, in "H3" der Dateiname und in "I3" der Tabellenname.
' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Sub CopyData()
Dim objWB As Workbook
Dim objSh As Worksheet, objShT As Worksheet
Dim strFile As String

Set objSh = ThisWorkbook.Sheets("Test")

strFile = objSh.Range("G3").Text

If Right(strFile, 1) <> "\" Then strFile = strFile & "\"

strFile = strFile & objSh.Range("H3").Text

If Right(strFile, 4) <> ".xls" Then strFile = strFile & ".xls"

If Dir(strFile) = "" Then
  MsgBox "Datei nicht gefunden!", 64, "Hinweis"
  Exit Sub
End If

On Error GoTo ErrExit

With Application
  .ScreenUpdating = False
  .EnableEvents = False
  .DisplayAlerts = False
  .Calculation = xlCalculationManual
  .Cursor = xlWait
End With

Set objWB = Workbooks.Open(strFile)

On Error Resume Next
Set objShT = objWB.Sheets(objSh.Range("I3").Text)
On Error GoTo 0

If objShT Is Nothing Then
  Err.Clear
  MsgBox "Die angegebene Tabelle existiert nicht!", 64, "Hinweis"
  objWB.Close False
  GoTo ErrExit
End If

objSh.Range("C5:C152").Copy

objShT.Range("A1").PasteSpecial xlValues

Application.CutCopyMode = False

objWB.Close True

MsgBox "Daten wurden erfolgreich kopiert!", 64, "Hinweis"

ErrExit:

Set objSh = Nothing
Set objShT = Nothing
Set objWB = Nothing

If Err.Number > 0 Then
  MsgBox Err.Number & vbLf & Err.Description, , "Fehler"
  Err.Clear
End If

With Application
  .ScreenUpdating = True
  .EnableEvents = True
  .DisplayAlerts = True
  .Calculation = xlCalculationAutomatic
  .Cursor = xlDefault
End With

End Sub


Gruß Sepp

Anzeige
;

Forumthreads zu verwandten Themen

Anzeige
Anzeige
Entdecke relevante Threads

Schau dir verwandte Threads basierend auf dem aktuellen Thema an

Alle relevanten Threads mit Inhaltsvorschau entdecken

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Entdecke mehr
Finde genau, was du suchst

Die erweiterte Suchfunktion hilft dir, gezielt die besten Antworten zu finden

Suche nach den besten Antworten
Unsere beliebtesten Threads

Entdecke unsere meistgeklickten Beiträge in der Google Suche

Top 100 Threads jetzt ansehen
Anzeige