Live-Forum - Die aktuellen Beiträge
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
nur Werte kopieren?
snewi
Hallo ich kopiere Werte über folgenden Syntax:

Sub kopieren()
Dim rngc As Range
Application.ScreenUpdating = False
With Sheets("Tabelle1")
For Each rngc In .Range(.Cells(8, 2), .Cells(Rows.Count, 2).End(xlUp))
If rngc.Offset(, 4) = 1 Then
rngc.Resize(, 4).Copy Sheets("Tabelle2").Cells(Rows.Count, 2).End(xlUp).Offset(1)
End If
Next
End With
End Sub
Ich möchte aber nur die Werte kopieren! Wie sieht dann der Syntax aus?
gruß

2
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Benutzer
Anzeige
Zuerst .Copy und danach .PasteSpecial xlvalues
12.03.2012 13:41:11
NoNet
Hallo snewi,
so geht's :
Sub NurWerteKopieren()
Dim rngc As Range
Application.ScreenUpdating = False
With Sheets("Tabelle1")
For Each rngc In .Range(.Cells(8, 2), .Cells(Rows.Count, 2).End(xlUp))
If rngc.Offset(, 4) = 1 Then
rngc.Resize(, 4).Copy 'zuerst KOPIEREN
Sheets("Tabelle2").Cells(Rows.Count, 2).End(xlUp).Offset(1).PasteSpecial xlValues
End If
Next
Application.CutCopyMode = False 'Kopierrahmen deaktivieren
End With
End Sub
Gruß, NoNet
oder gar nicht kopieren?
12.03.2012 17:56:55
Erich
Hi Snewi,
so ginge es wohl auch (ungetestet):

Sub NurWerteRuebertragen()
Dim rngQ As Range, lngZ As Long, rngC As Range
With Sheets("Tabelle1")
Set rngQ = .Range(.Cells(8, 2), .Cells(Rows.Count, 2).End(xlUp))
End With
Application.ScreenUpdating = False
With Sheets("Tabelle2")
lngZ = .Cells(.Rows.Count, 2).End(xlUp).Row
For Each rngC In rngQ
If rngC.Offset(, 4) = 1 Then
lngZ = lngZ + 1
.Cells(lngZ, 2).Resize(, 4) = rngC.Resize(, 4).Value
End If
Next
End With
End Sub
Nebenbei: Ist der erste Tag des Jahres jetzt klar? Ich meine
https://www.herber.de/forum/archiv/1252to1256/t1254344.htm
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich
Anzeige

320 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige