Herbers Excel/VBA-Archiv

Werte aus anderen Tabelle übernehmen.

• Werte aus anderen Tabelle übernehmen. von Stan vom 20.10.2014 14:42:51
• AW: Werte aus anderen Tabelle übernehmen. - von Rudi Maintaire am 20.10.2014 15:04:37
• AW: Werte aus anderen Tabelle übernehmen. - von Daniel am 20.10.2014 15:05:18
  • AW: Werte aus anderen Tabelle übernehmen. - von Stan am 20.10.2014 15:21:39
    • AW: Werte aus anderen Tabelle übernehmen. - von Daniel am 20.10.2014 15:30:19
• man kann es mit einer Formel lösen ... - von neopa C (paneo) am 20.10.2014 15:17:47
  • AW: man kann es mit einer Formel lösen ... - von Stan am 20.10.2014 15:44:44
• AW: Werte aus anderen Tabelle übernehmen. - von UweD am 20.10.2014 15:19:39

Betrifft: Werte aus anderen Tabelle übernehmen. von: Stan
Geschrieben am: 20.10.2014 14:42:51

Hallo zusammen,
Ich muss bestimmte Werte aus Tabelle Quelle in die Tabelle Ziel übernehmen. Ich kann kein Verweis machen, weil in der Quelle nach Ort und Nummer gesucht werden muss. Was für Funktion kann ich hier nutzen? Dateien Angehängt https://www.herber.de/bbs/user/93249.xlsx
https://www.herber.de/bbs/user/93248.xlsx

Gruß Stan

Betrifft: AW: Werte aus anderen Tabelle übernehmen. von: Rudi Maintaire
Geschrieben am: 20.10.2014 15:04:37

Hallo,
bau in deine Quelle ein eindeutigen Suchkriterium ein (z.B. E2: =A2&B2)
In der Zieltabelle: D4: =INDEX([93248.xlsx]Daten!$D:$D;VERGLEICH(D1&A3;[93248.xlsx]Daten!$E:$E;))

Gruß
Rudi

Betrifft: AW: Werte aus anderen Tabelle übernehmen. von: Daniel
Geschrieben am: 20.10.2014 15:05:18

Hi
was ist den die Quelltabelle und die Zieltabelle?
sollte dies aus dem Dateinamen erkennbar gewesen sein?
kommt in der Auflistung "Daten" (Datei 93248.xlsx) jede Stadt immer genau 3x vor?

wenn ja, dann ggf diese Formel fürs Geweicht:

=INDEX('[Kopie von 93248.xlsx]Daten'!$D:$D;VERGLEICH(D$1;'[Kopie von 93248.xlsx]Daten'!$A:$A;0) +ZEILE()-3) 

und diese für GGE:

=INDEX('[Kopie von 93248.xlsx]Daten'!$C:$C;VERGLEICH(D$1;'[Kopie von 93248.xlsx]Daten'!$A:$A;0) +ZEILE()-3) 

aber wie gesagt, es setzt halt einen regelmäßigen aufbau der Quelldatei voraus.

Gruß Daniel

Betrifft: AW: Werte aus anderen Tabelle übernehmen. von: Stan
Geschrieben am: 20.10.2014 15:21:39

Hallo Daniel,
jede Stadt kommt 26 mal vor. Habe auch 6 Städte. habe nur abgekürzt auf 3.In de Quelle gibt auch mehrere Spalten. habe nur die Wichtige herauskopiert.

Betrifft: AW: Werte aus anderen Tabelle übernehmen. von: Daniel
Geschrieben am: 20.10.2014 15:30:19

wenn jede Stadt immer 26mal vor kommt und die Werte immer in der gleichen Reihenfolge stehen, dann kannst du das Prinzip genauso übernehmen wie mit 3.
Gruß Daniel

Betrifft: man kann es mit einer Formel lösen ... von: neopa C (paneo)
Geschrieben am: 20.10.2014 15:17:47

Hallo Stan,

... allerdings ist dies womöglich schwierig nachzuvollziehen.

Formel B3 nach rechts und unten kopieren.

Tabelle1

	A	B	C	D	E	F	G
1		München		Stuttgart		Berlin
2	Nr	Gewicht	GGE	Gewicht	GGE	Gewicht	GGE
3	210	1574,73	39,9	411,6	11,3	3008,61	76,3
4	220	3303,82	84,5	224,03	5,6	2132,57	53,4
5	230	1152,49	27,1	4175,21	103,2	1206,81	30,1

Formeln der Tabelle

Zelle Formel B3 =WENNFEHLER(VERWEIS(9;1/([93248.xlsx]Daten!$A$1:$A$15=INDEX($1:$1;KÜRZEN(SPALTE(B1)/2;)*2))/([93248.xlsx]Daten!$B$1:$B$15=$A3); INDEX([93248.xlsx]Daten!$C$1:$D$15;;VERGLEICH(B$2;[93248.xlsx]Daten!$C$1:$D$1;))); "")

Daten

	A	B	C	D
1	Ort	Nr	GGE	Gewicht
2	Stuttgart	210	11,3	411,6
3	Stuttgart	220	5,6	224,03
4	Stuttgart	230	103,2	4175,21
5	Berlin	210	76,3	3008,61
6	Berlin	220	53,4	2132,57
7	Berlin	230	30,1	1206,81
8	München	210	39,9	1574,73
9	München	220	84,5	3303,82
10	München	230	27,1	1152,49
11

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4



Gruß Werner
.. , - ...

Betrifft: AW: man kann es mit einer Formel lösen ... von: Stan
Geschrieben am: 20.10.2014 15:44:44

Hallo,
Danke, habe in den richtigen tabellen eingefügt und so funktioniert.
prima.
danke an alle.
Gruß Stan

Betrifft: AW: Werte aus anderen Tabelle übernehmen. von: UweD
Geschrieben am: 20.10.2014 15:19:39

Hallo

hier per Formel(n)



Tabelle1

	A	B	C	D	E	F	G
1		München		Stuttgart		Berlin
2	Nr	Gewicht	GGE	Gewicht	GGE	Gewicht	GGE
3	210	1574,73	39,9	411,6	11,3	3008,61	76,3
4	220	3303,82	84,5	224,03	5,6	2132,57	53,4
5	230	1152,49	27,1	4175,21	103,2	1206,81	30,1

verbundene Zellen

B1:C1

D1:E1

F1:G1

verwendete Formeln
Zelle	Formel	Bereich
B3	=VERWEIS(2;1/([93248.xlsx]Daten!$A:$A&[93248.xlsx]Daten!$B:$B=B$1&$A3);[93248.xlsx]Daten!$D:$D)
C3	=VERWEIS(2;1/([93248.xlsx]Daten!$A:$A&[93248.xlsx]Daten!$B:$B=B$1&$A3);[93248.xlsx]Daten!$C:$C)

Tabellendarstellung in Foren Version 5.49





Gruß UweD

Beiträge aus den Excel-Beispielen zum Thema "Werte aus anderen Tabelle übernehmen."