Microsoft Excel

Herbers Excel/VBA-Archiv

Informationen und Beispiele zum Thema InputBox
BildScreenshot zu InputBox InputBox-Seite mit Beispielarbeitsmappe aufrufen

Zellen mit Formeln einer Zeile kopieren | Herbers Excel-Forum


Betrifft: Zellen mit Formeln einer Zeile kopieren von: Jürgen
Geschrieben am: 13.12.2009 15:05:34

Hallo VBA-Profis,

da ich hinsichtlich VBA ein Anfänger bin, hoffe ich hier im Forum Hilfe zu bekommen.

Ausgangslage:

In größeren Excel-Tabellen sind neben Daten auch Formeln vorhanden.
Tabelle beginnt z.B. ab A4 und erstreckt sich bis Z800 (Zeile 4 sind Überschriften)
In den Spalten, sagen wir mal "D", "H", "J", "L", "O" und "W", also nicht zusammen hängend, sind in der Zeile 5 Formeln
In der Spalte "A" z.B. die lfd. Nr.

Folgendes möchte ich erreichen:

Gesteuert durch ein Makro sollen alle Zellen mit Formeln (und nur diese) der Zeile "Auswahl durch eine Inputbox" ausgewählt werden (hier die Zeile "5") und im Zweiten Schritt so weit nach unten kopiert bzw. ausgefüllt, wie Dateneinträge in der Spalte "Auswahl auch durch Inputbox" (hier "A") werden.

Den Vorteil mit den Inputboxen sehe ich darin, dass das Makro für alle Tabellen verwendbar wird, egal ab welcher Zeile eine Tabelle beginnt und egal auf welche Spalte der Bezug zum ermitteln der letzten Zeile genommen wird (im Normalfall "A" oder die linke Begrenzug der Tabelle).
Meist sind ja noch andere Informationen oben drüber, oder links daneben.

Vielen Dank schon einmal vorab für Eure Hilfe

und eine besinnliche Vorweihnachtszeit

Jürgen

  

Betrifft: AW: Zellen mit Formeln einer Zeile kopieren von: Josef Ehrensberger
Geschrieben am: 13.12.2009 15:54:18

Hallo Jürgen,

probier mal.

' **********************************************************************
' Modul: Modul3 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Sub copyFormulas()
  Dim rng As Range, rngFormula As Range
  Dim lngRow As Long, lngLast As Long, lngCol As Long, lngLastCol As Long
  
  On Error Resume Next
  Set rng = Application.InputBox("Bitte wählen Sie die gewünschte Zeile aus", _
    "Zeile wählen", ActiveCell.Address, Type:=8)
  
  lngRow = rng.Cells(1, 1).Row
  If lngRow = 0 Then Exit Sub
  
  Set rng = Nothing
  
  Set rng = _
    Application.InputBox("Bitte wählen Sie Spalte zur Ermittlung des Datenbereiches aus", _
    "Spalte wählen", ActiveCell.Address, Type:=8)
  
  lngCol = rng.Cells(1, 1).Column
  If lngCol = 0 Then Exit Sub
  
  lngLast = Application.Max(Cells(Rows.Count, lngCol).End(xlUp).Row, lngRow)
  lngLastCol = Application.Max(Cells(lngRow, Columns.Count).End(xlToLeft).Column, _
    lngCol)
  
  Set rng = Range(Cells(lngRow, lngCol), Cells(lngRow, lngLastCol))
  
  Set rngFormula = rng.SpecialCells(xlCellTypeFormulas)
  On Error GoTo 0
  
  If Not rngFormula Is Nothing Then
    For Each rng In rngFormula
      rng.Resize(lngLast - lngRow + 1, 1).FillDown
    Next
  End If
  
  Set rng = Nothing
  Set rngFormula = Nothing
End Sub



Gruß Sepp



  

Betrifft: AW: Zellen mit Formeln einer Zeile kopieren von: Jürgen
Geschrieben am: 13.12.2009 17:54:20

Hallo Sepp,

genau das war es, was ich mir vorgestellt hatte. Einfach Klasse, wie schnell und unkompliziert man in diesem Forum Hilfe bekommt. Herzlichen Dank.

Schöne und besinnliche Weihnachtszeit

Jürgen, der Dankbare :-)


Beiträge aus den Excel-Beispielen zum Thema "Zellen mit Formeln einer Zeile kopieren"