Zellen mit Formelinhalt transponieren

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Andreas,
... ich hab Dir eine Formellösung zusammengestellt, verweise aber trotzdem nochmal auf meine Aussagen hier: https://www.herber.de/forum/archiv/1360to1364/t1363148.htm#1363148
Die Zeile 1 hab ich als Hilfszeile genutzt (kannst Du auch z.B. in die Zeile 9876 oder ... legen , musst dann nur die Formel in B4 entsprechend anpassen)
Den Stadtnamen in A1 kannst Du auch gleich in B3 schreiben, musst dann halt nur die Formeln in der Zeile 3 ab C3 entsprechend anpassen. An Stelle den Stadtnamen zu schreiben, würde ich ja gleich eine Dropdownzelle anbieten, was ich mir hier jedoch gespart habe)
Die Formeln B1:B3 entsprechend weit nach rechts kopieren.
Die Formel A4 nach unten und die Formel B4 nach rechts und unten. letzteren Bereich den Zellen das ein benutzerdefiniertes Zahlenformat mitgegeben, welches die FormelErgebniss-0-Werte (wo in der Datentabelle nichts steht, nicht dargestellt werden; z.B. so: 0,00;;)

	A	B	C	D
1	Hamburg	2	6	8
2	Datum	05.02.2012	11.11.2013	02.06.2014
3	Ort	Hamburg	Hamburg	Hamburg
4	Läufer	A	A	A
5	Zeit	3,21	3,21	4,50
6	Läufer	B	B	D
7	Zeit	2,90	2,90	1,80
8	Läufer	C	C	C
9	Zeit	1,70	1,70	3,80
10	Läufer	D	D	G
11	Zeit	2,30	2,30	1,80
12	Läufer		E
13	Zeit		1,70
14
15

Formeln der Tabelle

Zelle	Formel
B1	=WENN(B3="";"";VERWEIS(9;1/(Dateneingabe!$C1:$C999=B2)/(Dateneingabe!$D1:$D999=B3); ZEILE(A:A)))
B2	{=WENN(B3="";"";INDEX(Dateneingabe!$C:$C;KKLEINSTE(WENN(Dateneingabe!$D1:$D999=B3;ZEILE(1:999)); SPALTE(A1))))}
B3	=WENN(SPALTE(A1)>ZÄHLENWENN(Dateneingabe!$D:$D;$A1); "";$A1)
A4	=WENN(SUMME(B4:ZZ5)>0;INDEX({"Läufer";"Zeit"};REST(ZEILE(); 2)+1); "")
B4	=INDEX(INDEX(Dateneingabe!$E:$E;B$1):INDEX(Dateneingabe!$ZZ:$ZZ;B$1); ZEILE(A1))

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...

Hallo Andreas,
... nachfolgend sind alle maßgeblichen Formeln auf die neue Bedingung entsprechend angepasst.
Die Formel in B4 benötigt übrigens keine WENNFEHLER() Abfrage. Hier muss nur geprüft werden, ob an diesem Tag in der jeweiligen Stadt überhaupt ein Lauf registriert ist.
Auswertung_neu

	A	B	C	D
1		3	10
2	Wien	08.02.2012	08.06.2014
3	Erwachsene	Wien	Wien
4	Läufer	A	I
5	Zeit	4,37	3,50
6	Läufer	B	F
7	Zeit	2,30	3,70
8	Läufer	C	H
9	Zeit	2,90	4,37
10	Läufer	D	B
11	Zeit	2,90
12	Läufer	E
13	Zeit	3,21
14

Formeln der Tabelle

Zelle	Formel
B1	=WENN(B3="";"";VERWEIS(9;1/(Dateneingabe!$A1:$A999=B2)/(Dateneingabe!$B1:$B999=B3)/(Dateneingabe!$C1:$C999=$A3); ZEILE(A:A)))
B2	{=WENN(B3="";"";INDEX(Dateneingabe!$A:$A;KKLEINSTE(WENN((Dateneingabe!$B1:$B999=B3)*(Dateneingabe!$C1:$C999=$A3); ZEILE(1:999)); SPALTE(A1))))}
B3	=WENN(SPALTE(A2)>ZÄHLENWENNS(Dateneingabe!$B:$B;$A2;Dateneingabe!$C:$C;$A3); "";$A2)
A4	=WENN(SUMME(B4:ZZ5)>0;INDEX({"Läufer";"Zeit"};REST(ZEILE(); 2)+1); "")
B4	=WENN(B$2="";"";INDEX(INDEX(Dateneingabe!$D:$D;B$1):INDEX(Dateneingabe!$ZY:$ZY;B$1); ZEILE(A1)))

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Datengültigkeit der Tabelle

Zelle	Zulassen	Daten	Eingabe 1	Eingabe 2
A2	Liste		=Städte
A3	Liste		Erwachsene;Jugend

Namen in Formeln

Zelle	Name	Bezieht sich auf
A2	Städte	=Tabelle3!$A$2:$A$5

Namen verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Mit der Anwendung eines Autofilter in Deiner Dateneingabetabelle hättest Du das gleiche Ergebnis ohne Aufwendung und noch flexibel erhalten, eben nur "horizontal" und nicht vertikal gelistet. ;-)
Aber nun verrate mir doch bitte, was Du da für eine Zeiterfassung vornimmst? Dezimalwerte? Warum keine Zeitmessdaten. Excel bietet doch dieses spez. Zahlenformat an.
Gruß Werner
.. , - ...

Beliebteste Forumthreads (12 Monate)

Zellen mit Formelinhalt transponieren

11
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

326 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Zellen mit Formelinhalt transponieren

11 Beiträge zum Forumthread Beiträge zu diesem Forumthread

326 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

11
Beiträge zum Forumthread

Beiträge zu diesem Forumthread