Summenbildung mit Sverweis

Forumthread: Summenbildung mit Sverweis

25.02.2024 18:11:45

Uli

Hallo, guten Abend,

ich habe eine Tabelle mit 13 Blättern (Monate und Jahreswerte). In der Tabelle Jahreswerte möchte ich die Summen der einzelnen Blätter bilden, und zwar nicht mit =Summe(Jan:Dez!A1) sondern mit Sverweis, da ich häufiger verschiedene Sortierungen habe.
Als Anschauung habe ich eine Beispieldatei hochgeladen:

https://www.herber.de/bbs/user/167328.xlsx

Vielen Dank schon mal
Uli

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Summenbildung mit Sverweis

25.02.2024 18:26:12

{Boris}
AW: Summenbildung mit Sverweis

25.02.2024 18:31:53

RPP63
AW: Summenbildung mit Sverweis

25.02.2024 18:43:28

Eifeljoi 5
Wegen Excelversion...

25.02.2024 18:29:51

{Boris}

AW: Summenbildung mit Sverweis

25.02.2024 18:26:12

{Boris}

Hi,

H7:
=SUMME(SUMMEWENN(INDIREKT("'"&TEXT(DATUM(;SEQUENZ(12);1);"MMM")&"'!B7:B11");[@Mitarbeiter];INDIREKT("'"&TEXT(DATUM(;SEQUENZ(12);1);"MMM")&"'!D7:D11")))

F7:
=SUMME(SUMMEWENN(INDIREKT("'"&TEXT(DATUM(;SEQUENZ(12);1);"MMM")&"'!B7:B11");[@Mitarbeiter];INDIREKT("'"&TEXT(DATUM(;SEQUENZ(12);1);"MMM")&"'!F7:F11")))

G7:
=SUMME(SUMMEWENN(INDIREKT("'"&TEXT(DATUM(;SEQUENZ(12);1);"MMM")&"'!B7:B11");[@Mitarbeiter];INDIREKT("'"&TEXT(DATUM(;SEQUENZ(12);1);"MMM")&"'!G7:G11")))

VG, Boris

AW: Summenbildung mit Sverweis

25.02.2024 18:31:53

RPP63

Moin!
Mir ist klar, dass Du folgendes nicht lesen willst, aber dennoch:
Verzichte auf die Monatsblätter, nimm ein einziges Blatt mit 2^20 aka 1.048.576 Zeilen und nutze eine eine Zusatzspalte mit Datum oder meinethalben auch nur dem Monat.
Dann kannst Du problemlos mittels Formeln oder Pivot-Tabellen alles auswerten, was Du Dir erträumst. ;)
Gerade weil Du Dich als Anfänger bezeichnest:
Die Tabellenblätter in Excel sind keinesfalls als "Register" in einem Aktenordner zu sehen, sondern Hilfsmittel, um 3D-Bezüge herzustellen.
Quasi "Normalisierung light".

Gruß Ralf

AW: Summenbildung mit Sverweis

25.02.2024 18:43:28

Eifeljoi 5

Hallo

Hier eine alternative als PQ Lösung
https://www.herber.de/bbs/user/167329.xlsx

Wegen Excelversion...

25.02.2024 18:29:51

{Boris}

Hi,

...bitte überall SEQUENZ(12) austauschen durch ZEILE(1:12). Außerdem hatte ich mich vertippt: H7 sollte D7 heißen.

Also nochmal alle:

D7:
=SUMME(SUMMEWENN(INDIREKT("'"&TEXT(DATUM(;ZEILE(1:12);1);"MMM")&"'!B7:B11");[@Mitarbeiter];INDIREKT("'"&TEXT(DATUM(;ZEILE(1:12);1);"MMM")&"'!D7:D11")))

F7:
=SUMME(SUMMEWENN(INDIREKT("'"&TEXT(DATUM(;ZEILE(1:12);1);"MMM")&"'!B7:B11");[@Mitarbeiter];INDIREKT("'"&TEXT(DATUM(;ZEILE(1:12);1);"MMM")&"'!F7:F11")))

G7:
=SUMME(SUMMEWENN(INDIREKT("'"&TEXT(DATUM(;ZEILE(1:12);1);"MMM")&"'!B7:B11");[@Mitarbeiter];INDIREKT("'"&TEXT(DATUM(;ZEILE(1:12);1);"MMM")&"'!G7:G11")))

VG, Boris

Beliebteste Forumthreads (12 Monate)

Forumthread: Summenbildung mit Sverweis

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread