HERBERS Excel-Forum - das Archiv
Summewenn = Zählenwenn (bei 0)
KLE

Hallo,
habe folgende Frage:Wie kann ich mit der Funktion Zählenwenn "Nullen" (0) zählen ?!
Oder mit der Funktion Summewenn dieses mit der Null ermöglichen ?!
Hintergrund, habe eine komplexe Liste mit 0 oder 1 Werten. Möchte gern eine Summierung nach Namen machen incl. der Nuller und Einser...
Über Summewenn ( Name im Bereich Name - dann Summe Wertspalte 1 etc.) geht, aber wie kann ich nun die Nuller summieren / Zählen ?!?
Grüße aus Berlin
KLE

mit summenprodukt()
heikoS

Hallo ?,
das sollte so gehen:
Tabelle3

 ABCDE
1Klaus0 Thomas3
2Martin1 Martin1
3Thomas0   
4Klaus0   
5Thomas1   
6Thomas0   
7Martin1   
8Jürgen0   
9Martin0   
10Thomas0   

Formeln der Tabelle
ZelleFormel
E1=SUMMENPRODUKT(--($A$1:$A$10=D1); --($B$1:$B$10=0))


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Klappt´s?
Gruß Heiko

AW: mit summenprodukt()
Erich

Hallo Vorname(?), hallo Heiko,
oder so?
=SUMMENPRODUKT(($A$1:$A$10=D1)*(1-$B$1:$B$10))
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

AW: Summewenn = Zählenwenn (bei 0)
KLE

Hallo Heiko, Erich...
Vielen Dank ! scheinbar funktioniert es, aber wenn ich z.B. eine "leere" Zelle in der B-Spalte habe - wird diese gleich NULL gesetzt und mitgezählt ?! Kann ich "nur" die Nullen zählen ?!
@ Heiko, was bedeuten die "--" in Deiner Formel ?! Das habe ich bisher noch nirgends so gesehen ?!
Gruß
KLE

AW: Summewenn = Zählenwenn (bei 0)
heikoS

Hallo Vorname,
das sollte z.B. so funktionieren:
Tabelle3

 ABCDE
1Klaus0 Thomas2
2Martin1 Martin1
3Thomas    
4Klaus0   
5Thomas1   
6Thomas0   
7Martin1   
8Jürgen0   
9Martin0   
10Thomas0   

Formeln der Tabelle
ZelleFormel
E1=SUMMENPRODUKT(--($A$1:$A$10=D1); --(ISTZAHL($B$1:$B$10)); --($B$1:$B$10=0))


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Mit dem Doppelminus werden die Bool'schen Wahrheitswerte in Form von Zahlen weiterverarbeitet.
Klappt´s?
Gruß Heiko

AW: Summewenn = Zählenwenn (bei 0)
Erich

Hallo Vorname(?),
noch zwei Formeln dazu:
 DEFG
1Thomas222
2Martin111

Formeln der Tabelle
ZelleFormel
E1=SUMMENPRODUKT(--($A$1:$A$10=D1); --(ISTZAHL($B$1:$B$10)); --($B$1:$B$10=0))
F1=SUMMENPRODUKT(($A$1:$A$10=D1)*ISTZAHL($B$1:$B$10)*($B$1:$B$10=0))
G1=SUMMENPRODUKT(($A$1:$A$10=D1)*($B$1:$B$10&""="0"))

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

@Erich
heikoS

Hallo Erich,
Respekt - was ist das denn? Ich meine die dritte Variante. In der Form habe ich das bisher noch nicht gesehen. Warum funktioniert das? Woher hast Du das? Fragen über Fragen - für deren selbständige Beantwortung es mir eindeutig zu warm ist. ;-)
Hut ab!
Gruß Heiko

AW: @Erich
Erich

Hallo Heiko,
wenn du (in deinem Beispiel) die Formeln eingibst, werden aus B3 bzw. B4 Texte:
 BC
3
400

Formeln der Tabelle
ZelleFormel
C3=B3&""
C4=B4&""

Und die Texte $B$1:$B$10&"" brauche ich jetzt nur noch mit dem Text "0" zu vergleichen.
Woher ich das habe? Ist vorhin meinem Hirn entsprungen... ;-))
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

AW: @Erich
heikoS

Hallo Erich,
was entspringt denn noch Deinem Hirn? ;-) Arbeitet das erst dann auf voller Leistung, wenn es draußen über 30°C sind? Grundgütiger! Das läßt ja noch einiges erwarten für die kommenden Tage!
Das gefällt mir jedenfalls sehr gut! Eine tolle Variante! Meinen Glückwunsch!
Gruß Heiko