Komma durch Punkt ersetzen

Hallo, liebe Leute,
ich habe seit Excel 2010 folgendes Problem (welches in meiner Vorgängerversion Excel XP nicht aufgetreten ist). Vielleicht kann mir jemand helfen:
Ich bekomme aus einem Zeiterfassungsprogramm eine Auswertung in einer RTF-Datei:
1. Spalte = Datum, welches so aussieht: z.B. 01.06 (für 1. Juni)
2./3. Spalte = Uhrzeit
Jezt soll ich diese drei Spalten in ein Excel-Arbeitsblatt reinkopieren, damit ich die Daten dann weiterverarbeiten kann.
Spalte 2 und 3 sind kein Problem, die verhalten sich genauso wie sie sollen.
Spalte A im Excel-Arbeitsblatt ist als Benutzerdefiniert - TT.MM - formatiert.
Ich nehme im RTF-Dokument also die Tabelle in den Zwischenspeicher und wenn ich im Excel einfüge, dann passiert folgendes:
Die Daten in Spalte 1 werden insofern verändert, als dass aus dem Punkt ein Komma wird: z.B. aus 01.06 wird 1,06.
Wenn ich jetzt händisch das Komma durch einen Punkt ersetzen lasse, habe ich in Spalte A wieder mein Datum.
So weit, so gut.
Jetzt möchte ich aber diesen Ersetzungsvorgang in ein bereits bestehendes Makro, mit welchem ich die Daten anschließend weiterverarbeit, einarbeiten.
Ich habe bereits aufgezeichnet. Code sieht so aus:
Columns("A:C").Select
Selection.Replace What:=",", Replacement:=".", LookAt:=xlPart, _
SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
ReplaceFormat:=False
Range("A1").Select
Wenn ich diesen Code ausführe, dann passiert GAR NICHTS.
UND ICH WEISS NICHT WARUM!!!
Kann mir jemand auf die Sprünge helfen - DANKE!
walter

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

Hallo Walter,
leider kann Excel die Angabe "01.06" aus der RTF-Datei nicht als Datum erkennen und interpretiert diese Angabe als Zahl. Ersetzen von "," durch "." ist unter VBA leider auch problematisch, Datei intern die Dezimalstelle immer ein Punkt ist bzw. das US-Zhalenformat gilt.
Hier kannst du nur mühselig per Makro zellenweise die Zahlen in "TT.MM" umwandeln und mit vorangestelltem Hochkomma als Text in die Zellen schreiben oder die Angabe in ein echtes Excel-Datum umwandeln, indem die Jahreszahl noch hinzugefügt wird. Dann kann man die Zellen auch in Excel als "TT.MM" fromatieren.
Für die Spalten B und C (Uhrzeiten) muss doch eigenlich nichts ersetzt werden.
Gruß
Franz

Sub aatest()
Dim Zelle As Range, varSplit
'In Spalte A in zahlen das Komma durch Punkt ersetzen
With ActiveSheet
For Each Zelle In .Range(.Cells(1, 1), .Cells(Rows.Count, 1).End(xlUp))
If IsNumeric(Zelle) Then
varSplit = Split(Zelle.Text, ",")
Zelle.Value = "'" & Format(varSplit(0), "00") & "." & Format(varSplit(1), "00")
End If
Next Zelle
End With
Columns("B:C").Select
Selection.Replace What:=",", Replacement:=".", LookAt:=xlPart, _
SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
ReplaceFormat:=False
Range("A1").Select
End Sub
Sub abtest()
Dim Zelle As Range, varSplit, varJahr As Long
'In Spalte A die Zahl in Datum umwandeln
varJahr = Application.InputBox( _
Prompt:="Welches Jahr soll bei TT.MM angefügt werden?", _
Title:="Import von RTF-File", Default:=Year(Date))
With ActiveSheet
For Each Zelle In .Range(.Cells(1, 1), .Cells(Rows.Count, 1).End(xlUp))
If IsNumeric(Zelle) Then
varSplit = Split(Zelle.Text, ",")
Zelle.Value = CDate(varJahr & "-" & Format(varSplit(1), "00") & "-" & Format(varSplit(0) _
, "00"))
End If
Next Zelle
.Columns(1).NumberFormat = "DD.MM"
End With
Columns("B:C").Select
Selection.Replace What:=",", Replacement:=".", LookAt:=xlPart, _
SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
ReplaceFormat:=False
Range("A1").Select
End Sub

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

320 Forumthreads zu ähnlichen Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Komma durch Punkt ersetzen

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

320 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread