Live-Forum - Die aktuellen Beiträge
Datum
Titel
26.09.2025 22:18:24
Liste mit Links - tricky
26.09.2025 18:34:36
Welches Datum gibt mein M-Code aus?
26.09.2025 10:29:46
Wert aus einer Zelle bei jeder Eingabe in neue Zelle
26.09.2025 08:51:00
Teilinhalt einer Zelle vergleichen
Keine passende Antwort im Forumarchiv gefunden?
Stelle deine Frage im Live-Forum
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
828to832
828to832
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Über mehrere Tabellen Zeilen löschen

Forumthread: Über mehrere Tabellen Zeilen löschen

Über mehrere Tabellen Zeilen löschen
25.12.2006 14:58:00
Julia
hi,
vielleicht kann mir jemand einen Tip geben, wie man bei folgendem Skript die For...next-Schleife umgehen kann (oder so umschreiben kann, dass es schneller läuft), da es sehr lange dauert bis die ganzen Blätter abgearbeitet sind!?
Das Skript löscht über mehrere Blätter, die Zeilen bei denen in einem bestimmten Bereich keine Einträge stehen:

Sub LeereZeilenLöschen()
HDB = "gesamt"
For i = Sheets(HDB).index + 1 To Sheets.Count
a = Sheets(i).Cells(Rows.Count, 1).End(xlUp).Row
For zz = a To 7 Step -1
strName = ""
For Each e In Sheets(i).Range("F" & zz & ":IV" & zz)
strName = strName & e.Value
Next e
If strName = "" Then Sheets(i).Range("A" & zz).EntireRow.Delete
Next zz
Next i
End Sub

Wäre super, wenn mir jemand helfen könnte.
Gruß Julia
Anzeige

12
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Über mehrere Tabellen Zeilen löschen
25.12.2006 19:16:18
Erich
Hallo Julia,
teste mal diesen Code: 
Option Explicit
Sub LeereZeilenLöschen()
Dim ii As Integer, zz As Long, rngF As Range
Const HDB = "gesamt"
For ii = Sheets(HDB).Index + 1 To Sheets.Count
With Sheets(ii)
For zz = .Cells(Rows.Count, 1).End(xlUp).Row To 7 Step -1
Set rngF = Range(.Cells(7, 6), .Cells(zz, 256)).Find(What:="*", _
LookIn:=xlValues, LookAt:=xlPart, SearchOrder:=xlByRows, _
SearchDirection:=xlPrevious)
If rngF Is Nothing Then
Range(.Rows(7), .Rows(zz)).Delete
Exit Sub
ElseIf rngF.Row < zz Then
Range(.Rows(rngF.Row + 1), .Rows(zz)).Delete
zz = rngF.Row
End If
Next zz
End With
Next ii
End Sub
Rückmeldung wäre nett! - Erich aus Kamp-Lintfort wünscht dir schöne Feiertage!
Anzeige
AW: Über mehrere Tabellen Zeilen löschen
25.12.2006 19:30:55
Erich
Hallo Julia,
falls deine Tabellen sehr groß sind und/oder viele Formeln enthalten, geht es damit schneller: 
Option Explicit
Sub LeereZeilenLöschen()
Dim ii As Integer, zz As Long, rngF As Range
Const HDB = "gesamt"
Dim Calc As XlCalculation
Calc = Application.Calculation
Beschleuniger xlCalculationManual
For ii = Sheets(HDB).Index + 1 To Sheets.Count
With Sheets(ii)
For zz = .Cells(Rows.Count, 1).End(xlUp).Row To 7 Step -1
Set rngF = Range(.Cells(7, 6), .Cells(zz, 256)).Find(What:="*", _
LookIn:=xlValues, LookAt:=xlPart, SearchOrder:=xlByRows, _
SearchDirection:=xlPrevious)
If rngF Is Nothing Then
Range(.Rows(7), .Rows(zz)).Delete
Exit Sub
ElseIf rngF.Row < zz Then
Range(.Rows(rngF.Row + 1), .Rows(zz)).Delete
zz = rngF.Row
End If
Next zz
End With
Next ii
Beschleuniger Calc
End Sub
'   Beschleuniger _______ Parameter: Calc-Status ______ gi/12.03.2006
'Aufruf:
'   Dim Calc As XlCalculation
'   Calc = Application.Calculation: Beschleuniger xlCalculationManual
'   ....Code....
'   Beschleuniger Calc
Sub Beschleuniger(StatCal As XlCalculation)
Application.Calculation = StatCal
If StatCal = xlCalculationManual Then
Application.ScreenUpdating = False
Else
Application.ScreenUpdating = True
End If
End Sub
Rückmeldung wäre nett! - Erich aus Kamp-Lintfort wünscht nochmal schöne Feiertage!
Anzeige
AW: Zeilen löschen - Korrektur
25.12.2006 19:38:48
Erich
Hallo Julia,
sorry, in der Routine hatte ich das "Exit ..." stehen lassen.
Es soll aber natürlich in jedem Fall der Beschleuniger wieder ausgeschaltet werden. Also noch mal: 
Sub LeereZeilenLöschen()
Dim ii As Integer, zz As Long, rngF As Range
Const HDB = "gesamt"
Dim Calc As XlCalculation
Calc = Application.Calculation
Beschleuniger xlCalculationManual
For ii = Sheets(HDB).Index + 1 To Sheets.Count
With Sheets(ii)
For zz = .Cells(Rows.Count, 1).End(xlUp).Row To 7 Step -1
Set rngF = Range(.Cells(7, 6), .Cells(zz, 256)).Find(What:="*", _
LookIn:=xlValues, LookAt:=xlPart, SearchOrder:=xlByRows, _
SearchDirection:=xlPrevious)
If rngF Is Nothing Then
Range(.Rows(7), .Rows(zz)).Delete
GoTo XEnd
ElseIf rngF.Row < zz Then
Range(.Rows(rngF.Row + 1), .Rows(zz)).Delete
zz = rngF.Row
End If
Next zz
End With
Next ii
XEnd:
Beschleuniger Calc
End Sub
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: Zeilen löschen - Korrektur
25.12.2006 22:27:08
Julia
Hi Erich,
vielen Dank für deine Hilfe!
Geht um einiges schneller...eine echte Zeitersparnis :)
Vielleicht kannst du mir bei folgenden Problem noch zur Seite stehen?
Möchte bei diesen Blättern (wo Zeilen gelöscht wurden) noch die Spalten löschen, die als Summe den Wert 0 haben. Es sollen von "G4" bis "IV4" die Werte geprüft werden.
Eigentlich sollte als erstes das Skript mit "Spalten löschen", danach das mit "Zeilen löschen" laufen.
Gruß aus München
Julia
Anzeige
AW: Zeilen löschen - Korrektur
25.12.2006 22:39:41
Erich
Hi Julia,
danke für deine Rückmeldung, freut mich!
Jetzt noch zwei Rückfragen:
- Gibt es Spalten von G bis IV, in denen nur Text steht? Die würden auch gelöscht.
- Sollen 0-Spalten komplett gelöscht werden (ab Zeile 1) oder erst ab Zeile 4?
Weihnachtliche Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: Zeilen löschen - Korrektur
25.12.2006 23:15:47
Julia
Hi Erich,
in den Spalten G:IV-Zeile 4 sind nur Summenformeln und wenn eine von den Zellen den SummenWert 0 hat soll die komplette Spalte gelöscht werden.
Hoffe das war verständlich was ich möchte?
Gruß Julia
AW: Zeilen löschen - Korrektur
25.12.2006 23:57:52
Erich
Hallo Julia,
noch nicht wirklich getestet, sollte aber funzen (hoffentlich): 
Sub NullSpalten_LeerZeilen_Löschen()
Dim ii As Integer, zz As Long, rngF As Range
Dim ssV As Integer, ssB As Integer, ssAnz As Integer
Const HDB = "gesamt"
Dim Calc As XlCalculation
Calc = Application.Calculation
Beschleuniger xlCalculationManual
For ii = Sheets(HDB).Index + 1 To Sheets.Count
With Sheets(ii)
' ------------------------------------------------- Spalten löschen
ssB = 256
Do While ssB > 7
Do While ssB > 7 And Cells(4, ssB) <> 0
ssB = ssB - 1
Loop
ssV = ssB + 1
Do While ssV > 7 And Cells(4, ssV - 1) = 0
ssV = ssV - 1
Loop
If ssV <= ssB Then
Range(Columns(ssV), Columns(ssB)).Delete
ssAnz = ssAnz + ssB - ssV + 1
ssB = ssV - 1
End If
Loop
' ------------------------------------------------- Zeilen löschen
For zz = .Cells(Rows.Count, 1).End(xlUp).Row To 7 Step -1
Set rngF = Range(.Cells(7, 6), .Cells(zz, 256 - ssAnz)).Find(What:="*", _
LookIn:=xlValues, LookAt:=xlPart, SearchOrder:=xlByRows, _
SearchDirection:=xlPrevious)
If rngF Is Nothing Then
Range(.Rows(7), .Rows(zz)).Delete
GoTo XEnd
ElseIf rngF.Row < zz Then
Range(.Rows(rngF.Row + 1), .Rows(zz)).Delete
zz = rngF.Row
End If
Next zz
End With
Next ii
XEnd:
Beschleuniger Calc
End Sub
Rückmeldung wäre nett! - Erich aus Kamp-Lintfort wünscht dir schöne Rest-Feiertage!
Anzeige
Spalten u. Zeilen löschen - Druckbereich?
26.12.2006 20:35:20
Julia
Hi Erich,
sorry das ich mich erst jetzt melde.
Echt klasse!!! Vielen Dank nochmal für deine Hilfe.
waren zwar noch kleine Fehler drin, aber jetzt klappts:
Die Punkte haben gefehlt z.b. bei: .Cells, .Range, .Columns
hab bei die 0en in "0", sonst löscht es mir alle Spalten (in Zeile 4,die mit Summenwert 0 und die keinen Inhalt in der Zelle haben). Jetzt löscht es nur die mit Summenwert 0 raus.

Sub NullSpalten_LeerZeilen_Löschen()
Dim ii As Integer, zz As Long, rngF As Range
Dim ssV As Integer, ssB As Integer, ssAnz As Integer
Const HDB = "gesamt"
Dim Calc As XlCalculation
Calc = Application.Calculation
Beschleuniger xlCalculationManual
For ii = Sheets(HDB).Index + 1 To Sheets.Count
With Sheets(ii)
' ------------------------------------------------- Spalten löschen
ssB = 256
Do While ssB > 7
Do While ssB > 7 And .Cells(4, ssB) <> "0"
ssB = ssB - 1
Loop
ssV = ssB + 1
Do While ssV > 7 And .Cells(4, ssV - 1) = "0"
ssV = ssV - 1
Loop
If ssV <= ssB Then
.Range(.Columns(ssV), .Columns(ssB)).Delete
ssAnz = ssAnz + ssB - ssV + 1
ssB = ssV - 1
End If
Loop
' ------------------------------------------------- Zeilen löschen
For zz = .Cells(Rows.Count, 1).End(xlUp).Row To 7 Step -1
Set rngF = Range(.Cells(7, 6), .Cells(zz, 256)).Find(What:="*", _
LookIn:=xlValues, LookAt:=xlPart, SearchOrder:=xlByRows, _
SearchDirection:=xlPrevious)
If rngF Is Nothing Then
Range(.Rows(7), .Rows(zz)).Delete
GoTo XEnd
ElseIf rngF.Row < zz Then
Range(.Rows(rngF.Row + 1), .Rows(zz)).Delete
zz = rngF.Row
End If
Next zz
End With
XEnd:
Beschleuniger Calc
Next ii
End Sub

Hast du vielleicht (möchte dich nicht nerven:)) eine Idee, wie man schnell den einen Druckbereich für den benutzten Bereich für diese Blätter festlegen kann? Hab hier schon ein Skript, aber vielleicht fällt dir noch etwas dazu ein?
For i = Sheets(HDB).Index + 1 To Sheets.Count
'letzte benutzte Zeile ermitteln
LetzteZeile = Sheets(i).UsedRange.Rows.Count + 5
'letzte benutzte Spalte ermitteln
intNr = Sheets(i).UsedRange.Columns.Count - 3 'hier steuert man, welche Spalten weggelassen werden
'Ermitteln des Spalten-Buchstabens
On Error Resume Next
Cells(1, intNr).Select
ac = ActiveCell.Address
ab = Right(ac, Len(ac) - 1)
ac = Left(ab, Len(ab) - 2)
'Druckbereich festlegen
Sheets(i).PageSetup.PrintArea = ("A1:" & ac & LetzteZeile)
Next i
Application.ScreenUpdating = True
End Sub
Gruß Julia
Anzeige
AW: Spalten+Zeilen löschen + Druckbereich
27.12.2006 13:18:33
Erich
Hi Julia,
da war ich wohl etwas schlampig mit den Punkten - sorry! - aber du hast es ja gleich ausgebügelt :-)
Beim Festlegen des Druckbereichs würde ich nicht vom UsedRange ausgehen. Der ist mitunter viel größer als der gewünschte Bereich.
In dem Makro war noch ein fetter Fehler (meinerseits):
Durch das "Goto XEnd" passiert es, dass etliche Blätter überhaupt nicht bearbeitet werden...
Da steht jetzt "Exit For".
Gleich im Löschen-Makro würde ich es so machen: 
Sub NullSpalten_LeerZeilen_Löschen()
Dim ii As Integer, zz As Long, rngF As Range
Dim ssV As Integer, ssB As Integer, ssAnz As Integer
Const HDB = "gesamt"
Dim Calc As XlCalculation
Calc = Application.Calculation
Beschleuniger xlCalculationManual
For ii = Sheets(HDB).Index + 1 To Sheets.Count
With Sheets(ii)
' ------------------------------------------------- Spalten löschen
ssB = 256
Do While ssB > 7
Do While ssB > 7 And .Cells(4, ssB) <> "0"
ssB = ssB - 1
Loop
ssV = ssB + 1
Do While ssV > 7 And .Cells(4, ssV - 1) = "0"
ssV = ssV - 1
Loop
If ssV <= ssB Then
Range(.Columns(ssV), .Columns(ssB)).Delete
ssAnz = ssAnz + ssB - ssV + 1
ssB = ssV - 1
End If
Loop
' ------------------------------------------------- Zeilen löschen
For zz = .Cells(Rows.Count, 1).End(xlUp).Row To 7 Step -1
Set rngF = Range(.Cells(7, 6), .Cells(zz, 256 - ssAnz)).Find(What:="*", _
LookIn:=xlValues, LookAt:=xlPart, SearchOrder:=xlByRows, _
SearchDirection:=xlPrevious)
If rngF Is Nothing Then
Range(.Rows(7), .Rows(zz)).Delete
Exit For
ElseIf rngF.Row < zz Then
Range(.Rows(rngF.Row + 1), .Rows(zz)).Delete
zz = rngF.Row
End If
Next zz
' ------------------------------------------------- Druckbereich festlegen
zz = .Cells(Rows.Count, 1).End(xlUp).Row            ' Spalte A ist maßgebend
ssB = .Cells(4, Columns.Count).End(xlToLeft).Column ' Zeile 4  ist maßgebend
Sheets(ii).PageSetup.PrintArea = Range(.Cells(1, 1), .Cells(zz, ssB)).Address
End With
Next ii
Beschleuniger Calc
End Sub
Rückmeldung wäre nett! - Erich aus Kamp-Lintfort wünscht euch einen guten Rutsch!
Anzeige
AW: Spalten+Zeilen löschen + Druckbereich
27.12.2006 23:00:35
Julia
Hi Erich,
nett, dass du Dich nochmal gemeldet hast!
Wenn man das Skript beim ersten Mal ablaufen lässt, läuft es super schnell, doch wenn man es mehrmals hintereinander benutzt, ist es um einiges langsamer als zuvor?:(?
Was mich auch wundert, dass das Skript so langsam ist, wenn man bei
Sheets(ii).PageSetup.PrintArea = Range(.Cells(1, 1)
nachfolgend z. b. noch einige Befehle für die Druckeigenschaften hinzufügt:
Sheet(ii).PrintTitleRows = WZE
Sheet(ii).PrintTitleColumns = WSP
Sheet(ii).RightFooter = "&10" & "Seite " & pj & "&P/&N"
Sheet(ii).PrintGridlines = True
Sheet(ii).Orientation = xlPortrait
Sheet(ii).BlackAndWhite = True
Sheet(ii).Zoom = 90
Hast du eine Ahnung was da los ist? Muss man vielleicht irgendwas reseten?!?!?
Gruß Julia
Anzeige
AW: Spalten+Zeilen löschen + Druckbereich
28.12.2006 00:00:26
Erich
Hi Julia,
einen Grund für längere Laufzeiten bei mehrmaliger Ausführung sehe ich nicht.
Was ich nun aber auch nicht sehe, ist ein Grund, das Makro überhaupt mehrmals laufen zu lassen.
Wozu soll das gut sein?
Zu deiner zweiten Frage:
Zum Abarbeiten der Druck-Einstellungen benötigt Excel viel Zeit. Da habe ich keinen Dreh zum Beschleunigen gefunden.
Eventuell helfen Bedingungen der folgenden Art etwas (Beispielcode, am Ende des Makros): 
         ' ------------------------------------------------- Druckbereich festlegen
zz = .Cells(Rows.Count, 1).End(xlUp).Row            ' Spalte A ist maßgebend
ssB = .Cells(4, Columns.Count).End(xlToLeft).Column ' Zeile 4  ist maßgebend
.PageSetup.PrintArea = Range(.Cells(1, 1), .Cells(zz, ssB)).Address
With .PageSetup
If .Orientation <> xlPortrait Then .Orientation = xlPortrait
End With
End With
Next ii
Beschleuniger Calc
End Sub
Noch eine Bemerkung:
Sheet(ii).Orientation = xlPortrait
ist wohl kaum lauffähig. Sheets fehlte das s, und Orientation ist keine Worksheet-Eigenschaft,
sondern eine PageSetup-Eigenschaft. Ausführlich müsste es
Sheets(ii).PageSetup.Orientation = xlPortrait
heißen.
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: Spalten+Zeilen löschen + Druckbereich
28.12.2006 00:53:30
Julia
Hi Erich,
bei Sheet(ii).PrintTitleRows = WZE..., das war ein Schreib/Kopierfehler! Sorry.
(sonst würde ich doch gar nicht bemerken, dass es so ewig dauert:)
Das mit der wiederholten Markoausführung, hat was damit zu tun, dass wenn ich bei den einzelnen Blättern Daten ändere z.B. das durch eine Änderung eventuell bei einigen Blättern Spalten einen neuen Summenwert mit 0 ergeben.
Dieses Skript nehme ich dann zur Aktualisierung dieser geänderten Blätter.
Hoffe das war einigermaßen verständlich...
Schade das Du keine Lösung für mein Problem hast. Da muss man einfach damit leben.
Ich danke Dir nochmals für Deine sehr hilfreiche Unterstützung!
Gruß Julia
Dir auch einen guten Rutsch ins neue Jahr 2007
Anzeige
;

Forumthreads zu verwandten Themen

Makro zum Löschen von Tabellenblätterm
Tabellenblätterm

Hallo, ich wollte fragen ob es möglich ist mit Hilfe eines VBAs Tabellenblätter nach bestimmten Gesichtspunkten zu löschen.
Folge Ausgangslage:
Ich habe eine Excel mit vielen Tabellenblättern.
Auf Blatt "Gesamt" werden Daten erfasst.
Auf diesem Blatt werden in Spalte K ab K2 Nam...
22.08.2008 12:38:00
Thread-ID: 1003812
11 Beiträge
Anzeige
Datei schließen -> Tabellenblätter löschen
Gordon

Moin,
ist es möglich einen VBA-Code zu schreiben, der sobald man eine Exceldatei schließt, noch vorher bestimmte Tabellennlätter gelöscht werden. Ich stelle mir das so vor:
Ich drücke "Schließen" und bevor die datei geschlossen wird, werden alle Tabellenblätter dieser Datei, außer den...
24.08.2008 23:59:20
Thread-ID: 1004344
6 Beiträge
aus ausgewählter Datei Tabellenblätter kopieren
Katrin

Hallo, wer kann mir helfen?
Ich möchte aus einer, vorher in einem Dialogfenster ausgewählten Datei (immer unterschiedlich), den Inhalt mehrerer Tabellenblätter in eine andere Datei kopieren. Dabei sind die Bezeichnungen der Tabellenblätter in den beiden Dateien identisch. Bis zum 1. Tabelle...
17.09.2008 10:35:00
Thread-ID: 1010267
2 Beiträge
Übertragen in Tabelle2
Uwe

Hallo,
ich habe mal wieder eine Frage wo ich nicht weiter weiß.
Ich habe in Tabelle1 folgende Tabelle.
Tabelle1

 ABCD1Produktnamemonatlichvierteljährlichjährlich2    3Produkt 1220,21  4Produkt 2110,65  5Produkt 3 277,98 ...
24.09.2008 10:42:00
Thread-ID: 1011973
5 Beiträge
Datensätze in Tabellenblätter schreiben
TomTom


Hi,
ich habe eine Excelmappe mit 4 Bättern. Auf dem ersten Blatt (Spalte A) stehen die Rohdaten drin. Die sehen in etwar so aus:
START;flag,2,23,,,,34,45,33,45,,,,,,,56
ATTEMPT;flag,1,45,,12,,34,,,45,,,,,7,,56
START;flag,2,23,,,,34,45,33,45,,,,,,,56
STOP;flag,3,45,,5,,,...
30.09.2008 13:43:00
Thread-ID: 1013375
3 Beiträge
Bedingte Formatierung über Tabellenblätter
Thomas

Hallo,
ich habe in einem extra Datenblatt welches Stammdaten enthält einen Code für die Formatierung
erzeugt (vier verschiedene Farbe Sollen Verwendung finden).
Wie kann ich ohne Verwendung des Menüs Bedingte Formatierung, in dem mir nur 3 Bedingungen
zur Verfügung stehen, ohne...
12.11.2008 14:06:30
Thread-ID: 1023831
2 Beiträge
Anzeige
zählenwenn über mehrere Tabellenblätter
Andreas

Hallo,
in einer Tabell mit 14 Tabellenblättern wollte ich eine Spalte auswerten in der Werte mit Gültigkeit in form einer Liste vorgegeben werden (nein/20;ja/24;ja/36;ja/32 usw.). Dazu habe ich 2 Fragen.
Ist es möglich nur die Zahlen beim zählen einzubeziehen, da ich ja und nein drin st...
03.12.2008 18:44:00
Thread-ID: 1029920
3 Beiträge
Formatübernahme in mehrere Tabellenblätter
Anja

Hallo Allerseits!
Ich habe ein Makro, welches mir das gewünschte Format in ein anderes Tabellenblatt übernimmt. Nun möchte ich gerne das Format in mehrere Tabellenblätter gleichzeitig übernommen haben.
Zur genauen Erklärung schaut doch bitte einmal angehängte Datei an.
Danke im Vorr...
24.12.2008 07:00:31
Thread-ID: 1035070
8 Beiträge
Summe/Häufigkeit mehrere Tabellenblätter möglich?
Marcel

Hallo,
ich habe eine Excel-Arbeitsmappe mit drei Tabellenblättern.
Diese sind folgendermaßen aufgebaut:
NAME__VORNAME__NUMMER
hans__meiser______3
hans__meiser1_____2
hans__meiser2_____2
hans__meiser3_____1
hans__meiser4_____4
hans__meiser5_____4
Nun möcht...
09.01.2009 14:03:53
Thread-ID: 1038228
2 Beiträge
Makro für kopieren von tabellenblättern
tabellenblättern

Hallo Entwicklergemeinde,
bin auf der suche nach einer smarten lösung für folgendes problem
ausgangsituation:
eine tabelle mit ca. 100 spalten mit informationen wo ich für ca. 250
artikel verschiedenste informationen angeben kann (alter container der
verwendet wurde, neuer c...
09.01.2009 23:00:54
Thread-ID: 1038372
10 Beiträge
Wie Säulendiagramm mit Tabelle mit gestapelten Säu
sohsoh

Hallo,
ich habe folgendes Problem und schon wie ein Irrer probiert, aber bis jetzt noch keine Lösung gefunden.
Ich habe zu Verschiedenen Stoffen jeweils 2 Messwerte in 3 Verschiedenen Zuständen. Jetzt möchte ich ein Säulendigramm erstellen in denen ich 3 Säulen (zu den drei Zuständen je...
14.01.2009 10:48:22
Thread-ID: 1039519
2 Beiträge
Sortieren mit Abhängigkeit zweier Tabellenblätter
Nils

Hallo,
ich habe hier ein Problem der etwas komplizierteren Art.
Eine Musterdatei habe ich hier abgelegt:
https://www.herber.de/bbs/user/58414.xls
Nun geht es um folgendes:
Grundsätzlich würde ich gern die Liste_Jobs (und auch die Liste Kalender) auch sortieren können. Dann...
16.01.2009 15:36:00
Thread-ID: 1040604
3 Beiträge
Entdecke relevante Threads

Schau dir verwandte Threads basierend auf dem aktuellen Thema an

Alle relevanten Threads mit Inhaltsvorschau entdecken
Anzeige

Beliebteste Forumthreads (12 Monate)

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Entdecke mehr
Finde genau, was du suchst

Die erweiterte Suchfunktion hilft dir, gezielt die besten Antworten zu finden

Suche nach den besten Antworten
Unsere beliebtesten Threads

Entdecke unsere meistgeklickten Beiträge in der Google Suche

Top 100 Threads jetzt ansehen
Anzeige