Send Keys funktioniert nur teilweise

Hallo,
ich habe eine Datei mit 3 Sheets, aus welcher der Sheet Daten einen Datenabgleich mit dem Internet durchführt. Es könnte aber auch über die ganze Arbeitsmappe eine Aktualisierung durchgeführt werden, wenn es das ganze vereinfacht. Dies muss ich aktuell immer mit STRG+ALT+F5 aktualisieren, was auch klappt. Jetzt habe ich gesehen, dass man mit der Send Key Funktion das auch erledigen könnte. Ich habe dann übers www auch etwas gefunden, wo ich dachte das sollte gehen, auch wenn noch etwas als Kleinigkeit fehlt, der Timer.
~


Sub Test()
Sheets("Daten").Activate
Application.SendKeys "^%{F5}" + "{Enter}"
End Sub

~
Wenn ich das Makro ausführe, dann springt er in den Sheet, aber er führt dann keine Aktualisierung durch. Die Keys sind laut https://www.herber.de/mailing/vb/html/vastmsendkeys.htm
passend. Aber es geht nicht :-(. Was ist falsch und wie kann ich einen Timer dazubauen, der dann so alle 5 Minuten das Makro ausführt? Vielen Dank vorab für eure Ideen und Hilfe.
mfG
Andreas

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Andreas,
achte darauf, welcher Code-Teil wohin gehört!

' **********************************************************************
' Modul: DieseArbeitsmappe  Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Workbook_Open()
StartTimer
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
StopTimer
End Sub

' **********************************************************************
' Modul: Modul1  Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Public RunWhen As Double
Public Const cRunIntervalSeconds = 600    ' Intervall in Sekunden
Public Const cRunWhat = "updateQuery"

Sub StartTimer()
RunWhen = Now + TimeSerial(0, 0, cRunIntervalSeconds)
Application.OnTime earliesttime:=RunWhen, procedure:=cRunWhat, _
  schedule:=True
End Sub

Sub updateQuery()

ThisWorkbook.Worksheets("Tabellenname").QueryTables(1).Refresh BackgroundQuery:=False

StartTimer

End Sub

Sub StopTimer()
On Error Resume Next
Application.OnTime earliesttime:=RunWhen, _
  procedure:=cRunWhat, schedule:=False
End Sub

Gruß Sepp

Beliebteste Forumthreads (12 Monate)

Send Keys funktioniert nur teilweise

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

303 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Send Keys funktioniert nur teilweise

7 Beiträge zum Forumthread Beiträge zu diesem Forumthread

303 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread