Microsoft Excel

Herbers Excel/VBA-Archiv

Informationen und Beispiele zum Thema MsgBox
BildScreenshot zu MsgBox MsgBox-Seite mit Beispielarbeitsmappe aufrufen

Suchmakro, nur nach einem Teiltext suchen? | Herbers Excel-Forum


Betrifft: Suchmakro, nur nach einem Teiltext suchen? von: Kasimir
Geschrieben am: 15.02.2012 19:31:00

Hallo an alle!

Ich habe da mal eine Frage zu einem Suchmakro. Mit nachfolgendem Makro lasse ich mir die gefundenen Zellenadressen eines Suchwortes anzeigen.

Sub Test3()
Dim rngBereich          As Range

Dim strSuche            As String
Dim strFirstAddress     As String
Dim strFind()           As String

Dim lngIndex1           As Long
Dim lngIndex2           As Long
Dim lngLastRow          As Long

strSuche = "20110708-1"

lngLastRow = Lagerausgang.Cells(Rows.Count, 4).End(xlUp).Row

Set rngBereich = Lagerausgang.Range("D1:D" & lngLastRow).Find(what:=strSuche, LookIn:=xlValues,  _
LookAt:=xlWhole, MatchCase:=True)
    
If Not rngBereich Is Nothing Then
    strFirstAddress = rngBereich.Address
    Do
        lngIndex1 = lngIndex1 + 1
        ReDim Preserve strFind(1 To lngIndex1)
        
        strFind(lngIndex1) = rngBereich.Address
        
        Set rngBereich = Lagerausgang.Range("D1:D" & lngLastRow).FindNext(rngBereich)
    Loop While Not rngBereich Is Nothing And rngBereich.Address <> strFirstAddress
    Do
        lngIndex2 = lngIndex2 + 1
            
        MsgBox Range(strFind(lngIndex2)).Address

        If lngIndex2 = lngIndex1 Then Exit Do
    Loop
End If

End Sub

Nun möchte ich aber nicht nach dem Suchtext "20110708-1", sondern nur nach der Zahl vor dem Minus, also "20110708“ suchen lassen. Wie muss ich denn obiges Makro abändern, dass es nur nach einem Teil des Suchtextes, also "20110708“ und nicht nach "20110708-1" sucht. In der Spalte, in der gesucht werden soll, können nur Zahlen z.B. "20110708“ oder auch Zahlen getrennt mit einem Minus, z.B. "20110708-1“, stehen.

Kann mir da jemand behilflich sein? Wäre super!

Danke und Gruß,
Kasimir

  

Betrifft: AW: Suchmakro, nur nach einem Teiltext suchen? von: Uwe (:o)
Geschrieben am: 15.02.2012 19:47:55

Hallo Kaimir,
ich denke, es müsst reichen, wenn Du -natürlich- strSuche = "20110708" setzt, und dann nicht nach xlWhole, sondern nach xlPart suchen lässt:
Set rngBereich = Lagerausgang.Range("D1:D" & lngLastRow).Find(what:=strSuche, LookIn:=xlValues, _
LookAt:=xlPart, MatchCase:=True)

Klappt es?

Gruß
Uwe
(:o)


  

Betrifft: AW: Suchmakro, nur nach einem Teiltext suchen? von: Kasimir
Geschrieben am: 15.02.2012 20:36:02

Hallo!

Danke Uwe, das war's.

Wünsche Dir noch einen schönen Abend,
Kasimir


Beiträge aus den Excel-Beispielen zum Thema "Suchmakro, nur nach einem Teiltext suchen?"