Aus Userform PDF Datei öffnen

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
UserForm MsgBox
Bild

Betrifft: Aus Userform PDF Datei öffnen
von: Sigi
Geschrieben am: 02.08.2015 04:06:42

Guten Morgen,
ich möchte aus einer Userform heraus eine PDF-Datei anzeigen lassen.
Leider funktioniert mein Code nicht.

Private Sub cmdPhoto_oeffnen_Click()
   Dim sFile As String
   Dim sPath As String
   If cboPhoto_Ornder.Value = "" Then Exit Sub
   sPath = "C:\Users\Documents\PDF_Dateien\" & cboName.Value & "\" & cboTitel.Value & "\" 
   sFile = cboPhoto_Ornder.Value
   If Dir(sPath & sFile) = "" Then
      Beep
      MsgBox "Datei " & sFile & " wurde nicht gefunden!"
   Else
      Unload Me
CreateObject("WScript.Shell").Run "FoxitReader.exe"
'CreateObject("WScript.Shell").Open sPath & sFile
'CreateObject (sPath & sFile)
Shell (sPath & sFile)
   End If
End Sub

Danke!
Gruß
Sigi

Bild

Betrifft: AW: Aus Userform PDF Datei öffnen
von: Nepumuk
Geschrieben am: 02.08.2015 08:13:52
Hallo,
teste mal:

Option Explicit

Private Declare PtrSafe Function ShellExecuteA Lib "shell32.dll" ( _
    ByVal hwnd As LongPtr, _
    ByVal lpOperation As String, _
    ByVal lpFile As String, _
    ByVal lpParameters As String, _
    ByVal lpDirectory As String, _
    ByVal nShowCmd As Long) As LongPtr

Private Const SW_SHOWMAXIMIZED As Long = 3

Private Sub cmdPhoto_oeffnen_Click()
    Dim sFile As String
    Dim sPath As String
    If cboPhoto_Ornder.Value <> "" Then
        sPath = "C:\Users\Documents\PDF_Dateien\" & cboName.Value & "\" & cboTitel.Value & "\"
        sFile = cboPhoto_Ornder.Value
        If Dir(sPath & sFile) = "" Then
            Beep
            MsgBox "Datei " & sFile & " wurde nicht gefunden!"
        Else
            Unload Me
            Call ShellExecuteA(0, "open", sPath & sFile, _
                vbNullString, vbNullString, SW_SHOWMAXIMIZED)
        End If
    End If
End Sub

Gruß
Nepumuk

Bild

Betrifft: o.T. Vielen Dank!
von: Sigi
Geschrieben am: 03.08.2015 02:13:21
.

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Aus Userform PDF Datei öffnen"