Kalender Steuerelement mit Doppelklick aufrufen?

Forumthread: Kalender Steuerelement mit Doppelklick aufrufen?

30.10.2005 12:38:46

Winfried

Hallo miteinander,
vielleicht könnt Ihr mir helfen, ich bin nicht sicher ob es überhaupt geht.
Ich habe eine Userform mit dem Namen frmPopupKalender und dem Calendar 1 angelegt, welche ich über einen Button aufrufe. Könnte das über einen Doppelklick auf eine Zelle im Range H4:I4 geschehen? Das maximale was ich geschafft habe, ist dass der Kalender nach Doppelklick und verlassen der Zelle geöffnet hat. Das nützt mir natürlich nichts.
Ausserdem habe ich noch folgendes Problem: Wenn in der Zelle bereits ein Datum steht, soll dieses in den Kalender übernommen werden (Datums Vorschlag). Das soll verhinden, dass aus Versehen ein in der Zelle vorhandenens Datum überschrieben wird. Bei leerer Zelle soll der Kalender das aktuelle Datum angezeigen. Das geht auch nicht, er zeigt immer das aktuelle Datum. Ich habe das so gemacht:


Private Sub frmPopupKalender_Initialize()
If IsDate(AvtiveCell.Value) Then
Calendar1.Value = DateValue(ActiveCell.Value)
Else
Calendar1.Value = Date
End If
End Sub

Sub Calendar1_Click()
ActiveCell.Value = Calendar1.Value
Unload Me
End Sub
Danke für die Mühe
Winfried

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Kalender Steuerelement mit Doppelklick aufrufe

30.10.2005 12:47:02

Matthias

Hallo Winfried,
egal, wie die Userform heißt, es heißt immer:
Private Sub UserForm_Initialize()
Gruß Matthias

Anmerkung zu Initialize

30.10.2005 12:58:00

Nepumuk

Hi,
hier mal lesen, und dann an Stelle von Initialize, vielleicht doch besser Activate benutzen.
Guckst Du: Userform Unload kann Userform starten - und andere Nickligkeiten
Gruß
Nepumuk

AW: Kalender Steuerelement mit Doppelklick aufrufe

30.10.2005 13:03:22

Winfried

Hallo Matthias,
ich muss doch die Userforms unterscheiden, ich habe im Programm 3 Stück. Aus meinem Verständnis ist es egal ob ich sie dann Userform 1, 2, 3 nenne oder ihnen einen Namen gebe. Mit dem Namen weiss ich wenigstens im script sofort um welche es sich handelt. Oder sehe ich da was falsch?
Winfried

AW: Kalender Steuerelement mit Doppelklick aufrufe

30.10.2005 13:10:41

Matthias

Hallo Winfried,
Oder sehe ich da was falsch?
Durchaus. Userform_Initialize() ist eine Ereignisprozedur, wenn du sie umbenennst, wird sie nicht mehr beim Eintreten des Ereignisses ausgeführt.
Unterscheiden kannst du die Prozeduren doch, weil sie alle in einem anderen Modul stehen.
Gruß Matthias

AW: Kalender Steuerelement mit Doppelklick aufrufe

30.10.2005 13:54:53

Winfried

Hallo Matthias und Nepumuk,
erstmal Danke für die Hinweise. Ich habe dem Code abgeschrieben und dabei das Hirn ausgeschaltet. Also unload me durch Me.Hide ersetzt wie mal gelernt.
Auch das Initialize kann ich nun wieder nachvollziehen. Problem ist, dass ich vorher


Private Sub userform_Initialize() hatte,
da kam auf das Kommando
Sub PopupKalenderZeigen()
frmPopupKalender.Show
End Sub

Laufzeitfehler 424 Objekt erforderlich.
So wie jetzt wieder und ich weiss nicht was ich falsch gemacht habe. Als ich frmPopupKalender_Initialize() hatte kam der Kalender und hat auch das Datum übertragen.
Winfried

AW: Kalender Steuerelement mit Doppelklick aufrufe

30.10.2005 14:28:21

Josef

Hallo Winfried!
Probier's mal so!

' **********************************************************************
' Modul: Tabelle1 Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Not Intersect(Target, Range("H4:I4")) Is Nothing Then
  Cancel = True
  With frmPopupKalender
    If IsDate(Target) Then
      .Calendar1 = Target
    Else
      .Calendar1 = Date
    End If
    .Show
  End With
End If
End Sub

' **********************************************************************
' Modul: frmPopupKalender Typ: Userform
' **********************************************************************

Option Explicit

Private Sub CommandButton1_Click()
'OK-Button > Datum übernehmen!
ActiveCell = CDate(Calendar1)
Unload Me
End Sub

Private Sub CommandButton2_Click()
'Abbrechen-Button > UF schliessen ohne Datum zu übernehmen!
Unload Me
End Sub

'******************************
'* Gruß Sepp
'*
'* Rückmeldung wäre nett!
'******************************

AW: Kalender Steuerelement mit Doppelklick aufrufe

30.10.2005 15:27:27

Winfried

Hallo Sepp,
funktioniert sauber, musste nur den Range berichtigen und das unload durch hide ersetzen (siehe Antwort von Nepumuk).
Ich hatte es auch in dieser Richtung versucht, aber da fehlte halt das Können.
Danke und schönen Sonntag noch
Winfried

AW: Kalender Steuerelement mit Doppelklick aufrufe

30.10.2005 16:46:03

Josef

Hallo Winfried!
Freud mich das es klappt!
Da in meinem Code weder in "Initialize" noch im "Activate" Ereigniss
Code ausgeführt wird, kann man hier ruhig "Hide" verwenden!
Gruß Sepp

Beliebteste Forumthreads (12 Monate)

Kalender Steuerelement mit Doppelklick aufrufen?

Forumthread: Kalender Steuerelement mit Doppelklick aufrufen?

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Kalender Steuerelement mit Doppelklick aufrufen?

Forumthread: Kalender Steuerelement mit Doppelklick aufrufen?

8 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread