beim öffnen von dokument automatisch makro starten

Informationen und Beispiele zu den hier genannten Dialog-Elementen:


Excel-Version: exel mac 98
nach unten

Betrifft: beim öffnen von dokument automatisch makro starten
von: lars
Geschrieben am: 11.04.2002 - 18:08:26

ich habe ein formular und möchte gerne dass einige voreinstellungen beim öffnen des dokumentes automatisch gemacht werden, wie zum beispiel kopf von spalten und zeilen nicht sichtbar, oben soll das eingabefeld nicht erscheinen usw., wie kann ich das machen?

nach oben   nach unten

Re: beim öffnen von dokument automatisch makro starten
von: GraFri
Geschrieben am: 11.04.2002 - 18:24:30

Hallo

--------------------------------------------------------

Option Explicit
Dim Cn%
Dim CdbList()

Dim Status_FormulaBar As Boolean
Dim Status_HorScroll As Boolean
Dim Status_VerScroll As Boolean
Dim Status_StatusBar As Boolean
Dim Status_Gridlines As Boolean
Dim Status_Headings As Boolean


Sub Auto_Open()
Dim Cdb As CommandBar

'Wenn Titelleiste von Excel geändern werden soll
'Application.Caption = "Meine Mustervorlage"


'falls die eigenen Symbolleisten auch ausgeblendet werden sollen, dann den
'Code 'And Cdb.BuiltIn = True' aus nachstehender Zeile entfernen
Cn = 1
For Each Cdb In Application.CommandBars
If Cdb.Visible And Cdb.Type <> msoBarTypeMenuBar And Cdb.BuiltIn = True Then
ReDim Preserve CdbList(Cn)
CdbList(Cn) = Cdb.Name
Cn = Cn + 1
Cdb.Visible = False
End If
Next

'Stellt den Status fest und blendet alles aus
With ActiveWindow
Status_HorScroll = .DisplayHorizontalScrollBar
If .DisplayHorizontalScrollBar = True Then .DisplayHorizontalScrollBar = False

Status_VerScroll = .DisplayVerticalScrollBar
If .DisplayVerticalScrollBar = True Then .DisplayVerticalScrollBar = False

Status_Gridlines = .DisplayGridlines
If .DisplayGridlines = True Then .DisplayGridlines = False

Status_Headings = .DisplayHeadings
If .DisplayHeadings = True Then .DisplayHeadings = False
End With

With Application
Status_StatusBar = .DisplayStatusBar
If .DisplayStatusBar = True Then .DisplayStatusBar = False

Status_FormulaBar = .DisplayFormulaBar
If .DisplayFormulaBar = True Then .DisplayFormulaBar = False
End With

'Menüleiste
CommandBars(1).Enabled = False

End Sub


Sub Auto_Close()
Dim Cdb As CommandBar
Dim Ci%


For Ci = 1 To Cn - 1
Application.CommandBars(CdbList(Ci)).Visible = True
Next Ci

With ActiveWindow
.DisplayHeadings = Status_Headings
.DisplayHorizontalScrollBar = Status_HorScroll
.DisplayVerticalScrollBar = Status_VerScroll
.DisplayGridlines = Status_Gridlines
End With

With Application
.DisplayStatusBar = Status_StatusBar
.DisplayFormulaBar = Status_FormulaBar
End With

CommandBars(1).Enabled = True
End Sub
--------------------------------------------------------

mfg, GraFri


nach oben   nach unten

Re: beim öffnen von dokument automatisch makro starten
von: Bernd
Geschrieben am: 11.04.2002 - 18:27:30

Hi,
im VBA-Editor links "Diese Arbeitsmappe" doppelklick.
rechts im Editor folgendes eingenben:

Private Sub Workbook_Open()
Dein Makro
End Sub

Datei speicher, schliessen, öffnen. Makro sollte laufen.
cu Bernd

 nach oben

Beiträge aus den Excel-Beispielen zum Thema "beim öffnen von dokument automatisch makro starten"