Makro bzw. Modul in Forms als Dropdown einbinden

Forumthread: Makro bzw. Modul in Forms als Dropdown einbinden

20.04.2015 12:23:08

Michael

Hallo zusammen,
ich bin leider noch unerfahren mit Makros daher folgende Frage an euch:
ich hab ich einem Modul etwa 50 Makros. Diese würde ich gerne über ein Dropdown Menü ansteuern können. Ich weiß das ich mir ein Button erstellen und diesem dann ein Makro zuweisen kann. Das klappt auch ganz gut. Das gleiche hätte ich aber lieber als Dropdown wo mir alle Makros in dem Modul zur Auswahl stehen. 50 Buttons mit den dazugehörigen Makros würde ich nur ungern erstellen. Ich denke es gibt eine Lösung für mein Anliegen. Leider bin ich noch nicht von selbst darauf gekommen :(
Gruß
Michael

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Makro bzw. Modul in Forms als Dropdown einbinden

20.04.2015 12:27:51

Hajo_Zi

Hallo Michael,
warum nicht
Ansicht, Makros, Makros, Makros anzeigen?

AW: Makro bzw. Modul in Forms als Dropdown einbinden

20.04.2015 12:33:47

Michael

Hallo Hajo,
das Dropdown ist für den EndUser gedacht. Er soll einfacher an die Auswahl kommen. Ich persönlich arbeite so wie du beschrieben hast. Der Anwender soll aber auf dem Master Tab dies zur Selektion bekommen.
Gruß

AW: Makro bzw. Modul in Forms als Dropdown einbinden

20.04.2015 19:32:26

Nepumuk

Hallo,
folgender Code in ein Standardmodul:

Option Explicit

Public Sub ProcedurList()
    Dim lngLine As Long
    Dim strProcedurName As String, strTempProcedurName As String
    Dim strValiationText As String
    With ThisWorkbook.VBProject.VBComponents("Modul1").CodeModule 'Modulname anpassen
        For lngLine = 1 To .CountOfLines
            If .ProcOfLine(lngLine, 0) <> "" Then
                strProcedurName = .ProcOfLine(lngLine, 0)
                If strProcedurName <> strTempProcedurName Then
                    strTempProcedurName = strProcedurName
                    strValiationText = "," & strValiationText & strProcedurName
                End If
            End If
        Next
    End With
    strValiationText = Mid$(strValiationText, 2)
    With Cells(1, 1).Validation 'Zelle anpassen
        .Delete
        .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:= _
            xlBetween, Formula1:=strValiationText
        .IgnoreBlank = True
        .InCellDropdown = True
    End With
End Sub

Den folgenden Code in die Tabelle mit in der das Dropdown angezeigt werden soll.

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address = "$A$1" Then If Not IsEmpty(Target.Value) Then _
Call Application.Run(Target.Text)
End Sub

Anpassen kannst du das sicher selbst.
Gruß
Nepumuk

nicht ganz......

21.04.2015 11:50:50

Helmut

eher so..
.........
strValiationText = strValiationText & "," & strProcedurName
.............
Gruß

AW: nicht ganz......

21.04.2015 12:01:52

Nepumuk

Hallo,
stimmt ich hab nur mit einer Prozedur getestet. Schäm !!!
Gruß
Nepumuk

Beliebteste Forumthreads (12 Monate)

Makro bzw. Modul in Forms als Dropdown einbinden

Forumthread: Makro bzw. Modul in Forms als Dropdown einbinden

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Makro bzw. Modul in Forms als Dropdown einbinden

Forumthread: Makro bzw. Modul in Forms als Dropdown einbinden

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread