vorletzter Wert (mit Bedingung)

Bild

Betrifft: vorletzter Wert (mit Bedingung)
von: Benny
Geschrieben am: 31.05.2015 10:10:15

Hallo zusammen,
ich habe hier ein etwas komplizierteres Problem auf das ich leider auch nach sehr langer Recherche keine Antwort gefunden habe :-(
https://www.herber.de/bbs/user/97942.xlsx
Grundsätzlich sollen einfach 2 Zahlenwerte miteinander verglichen werden. Der Vergleich an sich soll in Spalte F stattfinden und für jeden Namen durchgeführt werden.
Verglichen soll jeweils der letzte Wert in der Spalte Startwert mit dem vorletzten Wert aus der Spalte Endwert.
Die Tabelle ist monatlich anwachsend (siehe auch Datumsspalte), es sollen aber immer nur der letzte Wert mit dem vorletzten verglichen werden - der gleichen PersNr. (Name)!
Es könnten ggf. beliebig viele Hilfsspalten angefügt werden. Ich will jedoch eine VBA-Lösung um jeden Preis vermeiden.
Um das ganze nochmal an einem konkreten Beispiel festzumachen: In der Bsp.-Datei ist der letzte Wert für den Namen Benny (PersNr. 2) in der Spalte Startwert 7,48. Der vorletzte Wert in der Spalte Endwert ist ebenfalls 7,48. Die neue Formel sollte demnach WAHR sein, da die Werte exakt übereinstimmen. Für „Nadine“ (PersNr. 6) wäre die „Vergleichsformel“ FALSCH da der letzte Wert der Spalte Startwert 5,48 ist und der vorletzte Wert der Spalte Endwert -2,02.
Ich bin echt gespannt ob sich hier jemand finden lässt der das Problem lösen kann! Wäre klasse!
Viele Grüße
Benny

Bild

Betrifft: AW: vorletzter Wert (mit Bedingung)
von: ransi
Geschrieben am: 31.05.2015 10:20:34
hallo,
in welcher zelle soll denn die formel stehen ?

Bild

Betrifft: AW: vorletzter Wert (mit Bedingung)
von: Sepp
Geschrieben am: 31.05.2015 10:28:55
Hallo Benny,
so?
Tabelle1

 ABCDEFGHIJKLMNO
1PersNrNameStartwertEndwertDatum      PersNrNameStartwert=Endwert 
22Benny34,471501.01.2015      1   
36Nadine1,48-2,0201.01.2015      2BennyWAHR 
44Andi1522,1701.01.2015      3   
52Benny14,327,4801.02.2015      4AndiWAHR 
67Christian2526,6201.02.2015      5   
74Andi22,1739,3701.02.2015      6NadineFALSCH 
82Benny7,4816,1801.03.2015      7   
96Nadine5,4816,3401.03.2015      8   
104Andi39,3752,7901.03.2015      9   
11           10   
12               
13               
14               

Formeln der Tabelle
ZelleFormel
M2=WENN(ZÄHLENWENN($A$2:$A$10;L2)>1;INDEX($B$2:$B$10;VERGLEICH(L2;$A$2:$A$10;0)); "")
N2{=WENN(M2="";"";INDEX($C$2:$C$10;MAX(WENN($B$2:$B$10=M2;ZEILE($1:$9))))=INDEX($D$2:$D$10;KGRÖSSTE(WENN($B$2:$B$10=M2;ZEILE($1:$9)); 2)))}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Sepp


Bild

Betrifft: letzter der einen = vorletzter der anderen Spalte
von: WF
Geschrieben am: 31.05.2015 10:32:31
Hi,
folgende Arrayformel:
{=INDEX(C:C;MAX((B2:B99="Nadine")*ZEILE(2:99)))=INDEX(D:D;KGRÖSSTE((B2:B99="Nadine")*ZEILE(2:99);2)) }
Salut WF

Bild

Betrifft: AW: vorletzter Wert (mit Bedingung)
von: Hajo_Zi
Geschrieben am: 31.05.2015 10:34:33
Lese mal Forum FAQ.
Zu Crossposting lies diese Seite Hajo-Excel.de
Durch Crosspostuing werden mehrere Gruppen von Leuten mit dem gleichen Thema befasst, ohne dass sie voneinander wissen.
Naturgemäß laufen dann die Antworten, die im einen Forum "zu spät" gegeben wurden, ins Leere und bleiben ohne Resonanz.
Es reicht also, zunächst in einem Forum zu posten - wenn die Antworten dann unbefriedigend sein sollten, steht es einem anschließend immer noch offen, ein anderes Forum zu Rate zu ziehen.
Ich mache keine Werbung für andere Foren und verzichte darum auf den Link.


Bild

Betrifft: mit AGGREGAT() ...
von: der neopa C
Geschrieben am: 31.05.2015 11:01:08
Hallo Benny,
... in einer MATRIXfunktion(alitäts)formel (ohne {}). In nachfolgender Formel (nach unten kopieren) habe ich den auszuwertenden Bereich bewusst auf Datensätze bis Zeile 999 eingeschränkt. Du kannst diesen noch erhöhen, wenn es unbedingt nötig sein sollte. Allerdings reduziert sich dadurch die Auswertungsgeschwindigkeit. Das Fragezeichens in der Formel kannst Du durch das von Dir gewünschte Ergebnis ersetzen. Denkbar wäre sowohl WAHR als auch "":

 ABCDEF
1PersNrNameStartwertEndwertDatum 
22Benny34,471501.01.2015 
36Nadine1,48-2,0201.01.2015 
44Andi1522,1701.01.2015 
52Benny14,327,4801.02.2015 
67Christian2526,6201.02.2015?
74Andi22,1739,3701.02.2015 
82Benny7,4816,1801.03.2015WAHR
96Nadine5,4816,3401.03.2015FALSCH
104Andi39,3752,7901.03.2015WAHR
11      

Formeln der Tabelle
ZelleFormel
F2=WENN((ZÄHLENWENN(A:A;A2)<>ZÄHLENWENN(A$1:A2;A2))+(A2=""); "";WENNFEHLER(INDEX(C:C;AGGREGAT(14;6;ZEILE(A:A)/(A$1:A$999=A2); 1))=INDEX(D:D;AGGREGAT(14;6;ZEILE(A:A)/(A$1:A$999=A2); 2)); "?"))


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...

Bild

Betrifft: AW: vorletzter Wert (mit Bedingung)
von: Benny
Geschrieben am: 31.05.2015 12:03:42
Hallo zusammen,
vielen vielen Dank für die schnellen Antworten! Ich bin echt begreistert, auf den ersten Blick ist die Lösung von ransi genau das was ich gesucht habe.
Vielen Dank nochmal und noch einen schönen Sonntag!
Benny

Bild

Betrifft: AW: vorletzter Wert (mit Bedingung)
von: Benny
Geschrieben am: 31.05.2015 12:06:05
Sorry ich meinte natürlich die Lösung von "der neopa C"

 Bild

Beiträge aus den Excel-Beispielen zum Thema "vorletzter Wert (mit Bedingung)"