Hallo,
Ich möchte in einer Zelle den letzten Wert (Datum) eines anderen Tabellenblattes (Tabellenblattname = eine Variable) wiedergeben.
Meine Array-Formel sieht so aus:
{=INDEX(INDIREKT($F$4&"!B10:B3000");MAX(ZEILE(INDIREKT($F$4&"!B10:B3000")) *(INDIREKT($F$4&"!B10:B3000")""))) }
Das funktioniert aber nicht - Es wird eine 0 geliefert. Zur besseren Darstellung lade ich die Mappe hoch:
https://www.herber.de/bbs/user/64237.xls
Würde mich freuen, wenn sich das mal jemand anschauen könnte.
Viele Grüße, Larissa

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

AW: Letzte Eintragung in einer Spalte wiedergeben

{Boris}
{ } sind natürlich überflüssig...

{Boris}
AW: Letzte Eintragung in einer Spalte wiedergeben

Josef
Mit Verweis klappt es

Larissa
AW: Mit Verweis klappt es

Larissa
AW: Mit Verweis klappt es

Tino
funktioniert für Text und Zahlen

Larissa
AW: Mit Verweis klappt es

Tino
Megacoool - Danke Tino !!!

Larissa
das hört man gern...

Tino

AW: Letzte Eintragung in einer Spalte wiedergeben

06.09.2009 13:17:17

{Boris}

Hi,
da die Datümer aufsteigend sortiert sind (und somit das unterste auch immer das jüngste ist), reicht doch:
{=MAX(INDIREKT($F$4&"!B10:B3000"))}
Grüße Boris

{ } sind natürlich überflüssig...

06.09.2009 14:13:38

{Boris}

...is also ne ganz "normale" Formel.
Grüße Boris

AW: Letzte Eintragung in einer Spalte wiedergeben

06.09.2009 13:17:28

Josef

Hallo Larissa,
http://www.excelformeln.de/formeln.html?welcher=50


=VERWEIS(2;1/INDIREKT($F$4&"!B10:B3000");INDIREKT($F$4&"!B10:B3000"))

Gruß Sepp

Mit Verweis klappt es

06.09.2009 14:09:11

Larissa

Oh, dankeschön, da lag ich ja ganz falsch mit meiner Formel.
Liebe Grüße,
Larissa

AW: Mit Verweis klappt es

06.09.2009 14:38:41

Larissa

Hi nochmal,
ich möchte auch den Wert der nächsten Spalte C angeben, das ist aber Text und keine Zahl.
Dann funktioniert die Formel leider nicht und auch nicht die andere: =VERWEIS(1E+307;C:C)
Beide liefern einen #NV Wert. Wie kann man sich denn Text anzeigen lassen?
Gruß, Larissa

AW: Mit Verweis klappt es

06.09.2009 15:49:57

Tino

Hallo,
habe Dir mal was zusammengebastelt, dies funktioniert für Text und auch für Zahlen.

	A	B	C	D
1	5			s
2	9
3	8
4	7
5	6
6	10
7	s

Formeln der Tabelle

Zelle	Formel
D1	=INDEX($A:$A;MAX(WENN(ISTNV(VERGLEICH(10^308;$A:$A;1)); 1;VERGLEICH(10^308;$A:$A;1)); WENN(ISTNV(VERGLEICH("";$A:$A;-1)); 1;VERGLEICH("";$A:$A;-1))))

Gruß Tino

funktioniert für Text und Zahlen

06.09.2009 16:15:39

Larissa

Das ist cool, Danke Tino ;.)

AW: Mit Verweis klappt es

06.09.2009 16:07:43

Tino

Hallo,
hier noch auf Deine Tabelle angepasst.

	E	F
4	Kennzeichen:	MF_459
5
6	letztes Datum:	09.08.2009
7
8	letzter Tag	6
19
20	letzte Schicht	Nacht

Formeln der Tabelle

Zelle	Formel
F6	=INDIREKT($F$4&"!B"&MAX(WENN(ISTNV(VERGLEICH(10^308;INDIREKT($F$4&"!B:B"); 1)); 1;VERGLEICH(10^308;INDIREKT($F$4&"!B:B"); 1)); WENN(ISTNV(VERGLEICH("";INDIREKT($F$4&"!B:B"); -1)); 1;VERGLEICH("";INDIREKT($F$4&"!B:B"); -1))))
F8	=INDIREKT($F$4&"!A"&MAX(WENN(ISTNV(VERGLEICH(10^308;INDIREKT($F$4&"!A:A"); 1)); 1;VERGLEICH(10^308;INDIREKT($F$4&"!A:A"); 1)); WENN(ISTNV(VERGLEICH("";INDIREKT($F$4&"!A:A"); -1)); 1;VERGLEICH("";INDIREKT($F$4&"!A:A"); -1))))
F20	=INDIREKT($F$4&"!C"&MAX(WENN(ISTNV(VERGLEICH(10^308;INDIREKT($F$4&"!C:C"); 1)); 1;VERGLEICH(10^308;INDIREKT($F$4&"!C:C"); 1)); WENN(ISTNV(VERGLEICH("";INDIREKT($F$4&"!C:C"); -1)); 1;VERGLEICH("";INDIREKT($F$4&"!C:C"); -1))))

Gruß Tino

Megacoool - Danke Tino !!!

06.09.2009 16:22:17

Larissa

Hey, das ist ja irre!!!!
Ich hatte mir so beholfen, dass ich deine Formel irgendwo auf der Seite mit den Spalten platziert hatte und auf der ersten Seite nur einen Bezug hergestellt hatte. Das war mir eigentlich nicht so recht, aber eine Lösung.
Jetzt brauchte ich Deine megacoolen Formeln nur mit copy/paste einzupflanzen und es funzt sofort.
You make me happy - Thank you!!!

das hört man gern...

06.09.2009 16:28:34

Tino

Hallo,
, gerade weil ich nicht der Formelspezi bin.
Danke für die Rückmeldung und noch einen schönen Sonntag.
Gruß Tino