Herbers Excel-Forum - das Archiv

Zeichen bei Doppelklick

Bild

Betrifft: Zeichen bei Doppelklick
von: Gerhard

Geschrieben am: 24.12.2006 10:40:19
Hallo zusammen,
wie kann ich in einer Tabelle:
1.) in Spalte E5-E20 bei einem Doppelklick das Wingdings Symbol 251 in roter Farbe übernommen werden. Bei einem erneuten Doppelklick in die gleiche Zelle sollte das Zeichen wieder gelöscht werden.
2.) in Spalte F5-F20 bei einem Doppelklick das Wingdings Symbol 252 in grüner Farbe darstellen übernommen werden. Bei einem erneuten Doppelklick in die gleiche Zelle sollte das Zeichen wieder gelöscht werden.
3.) in Zelle C3 bei einem Doppelklick das aktuelle Tagesdatum eingetragen werden.Bei einem erneuten Doppelklick in die Zelle C3 sollte das Datum wieder gelöscht werden.
Vielen Dank für Eure Hilfe
Gruß
Gerhard
Bild

Betrifft: AW: Zeichen bei Doppelklick
von: Peter Feustel

Geschrieben am: 24.12.2006 11:09:31
Hallo Gerhard,
das könnte z. B. so gehen
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Target.Count > 1 Then Exit Sub
If Target.Column = 5 And Target.Row > 4 And Target.Row < 21 Then
If Target.Value = "" Then
Target.Font.Name = "Wingdings"
Target.Font.ColorIndex = 3
Target.Value = Chr(251)
Else
Target.Font.Name = "Arial"
Target.Font.ColorIndex = 0
Target.Value = ""
End If
ElseIf Target.Column = 6 And Target.Row > 4 And Target.Row < 21 Then
If Target.Value = "" Then
Target.Font.Name = "Wingdings"
Target.Font.ColorIndex = 10
Target.Value = Chr(252)
Else
Target.Font.Name = "Arial"
Target.Font.ColorIndex = 0
Target.Value = ""
End If
ElseIf Target.Address = "$C$3" Then
If Target.Value = "" Then
Target.Value = Date
Else
Target.Value = ""
End If
End If
End Sub

Kopiere das Makro in das Klassenmodul des Tabellenblattes.
Rechtsklick auf den Tabellenblattreiter
Linksklick auf Code anzeigen
Makro in deas sich önnende Fenster kopieren
mit Alt + Q schließen
und testen.
Viele Grüße Peter
Eine kurze Nachricht, ob es läuft, wäre nett - danke.
Bild

Betrifft: AW: Zeichen bei Doppelklick
von: Gerhard
Geschrieben am: 24.12.2006 13:37:08
Halllo Peter,
Vielen Dank für Deine Hilfe, funktioniert prima!
Frohe Weihnachten wünsch ich Dir.
Gruß
Gerhard
Bild

Betrifft: AW: Zeichen bei Doppelklick
von: Erich G.

Geschrieben am: 24.12.2006 11:22:27
Hallo Gerhard,
noch 'ne Version:
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Not Intersect(Target, Range("E5:E20")) Is Nothing Then
Cancel = True: DKlick Target, 1
ElseIf Not Intersect(Target, Range("F5:F20")) Is Nothing Then
Cancel = True: DKlick Target, 2
ElseIf Not Intersect(Target, Range("C3")) Is Nothing Then
Cancel = True: DKlick Target, 3
End If
End Sub
Private Sub DKlick(rng As Range, art As Byte)
If Not IsEmpty(rng) Then
rng.Clear
Else
With rng.Font
Select Case art
Case 1: .Name = "Wingdings": .ColorIndex = 3: rng = "û"
Case 2: .Name = "Wingdings": .ColorIndex = 50: rng = "ü"
Case 3: rng = Date
End Select
End With
End If
End Sub
Rückmeldung wäre nett! - Erich aus Kamp-Lintfort wünscht euch schöne Feiertage!
Bild

Betrifft: AW: Zeichen bei Doppelklick
von: Gerhard
Geschrieben am: 24.12.2006 13:40:47
Hallo Erich,
auch Dir vielen Dank für Deine Hilfe, Deine Version funktioniert genauso gut!
Wünsch Dir Frohe Weihnachten und ein Gutes neues Jahr.
Gruß
Gerhard
 Bild
Excel-Beispiele zum Thema "Zeichen bei Doppelklick"
Summe bilden, wenn Kriterium Zeichenfolge Leerzeichen aus einem Bereich löschen
Anfügen des Zeichens für Durchmesser Zeichenfolge aufteilen
Filtern einer Zahl aus einer Zeichenfolge Zeichenfolgen in Zahlen nach Textimport
Zeichenfolge korrigieren Zeichenfolge umkehren
Zeichen separieren Die Ereignisse Zellauswahl, Eingabe und Doppelklick