ich möchte in einer UF alle Blätter der Datei listen und in einer CHK-Box anhaken können. Danach sollen nur die Markiereten Blätter kopiert werden.
Wie kann ich das am Besten lösen?
Danke für jegliche Hilfe.
Gruß
marcl
Option Explicit
Dim arrTabellen()
Dim inTabellen As Integer
Private Sub CheckBox1_Click()
ReDim Preserve arrTabellen(0 To inTabellen)
arrTabellen(inTabellen) = "Tabelle1"
inTabellen = inTabellen + 1
End Sub
Private Sub CheckBox2_Click()
ReDim Preserve arrTabellen(0 To inTabellen)
arrTabellen(inTabellen) = "Tabelle2"
inTabellen = inTabellen + 1
End Sub
Private Sub CheckBox3_Click()
ReDim Preserve arrTabellen(0 To inTabellen)
arrTabellen(inTabellen) = "Tabelle3"
inTabellen = inTabellen + 1
End Sub
Private Sub CommandButton1_Click()
Worksheets(arrTabellen).Copy
End Sub
Option Explicit
Private Sub CommandButton1_Click()
Dim myAr() As String
Dim i As Integer, ii As Integer
With ListBox1
For i = 0 To .ListCount - 1
If .Selected(i) Then
Redim Preserve myAr(ii)
myAr(ii) = .List(i)
ii = ii + 1
End If
Next i
End With
If ii > 0 Then
ThisWorkbook.Sheets(myAr).Copy
End If
End Sub
Private Sub UserForm_Initialize()
Dim i As Integer
With ListBox1
.ListStyle = fmListStyleOption
.MultiSelect = fmMultiSelectMulti
End With
With ThisWorkbook
For i = 1 To .Sheets.Count
If .Sheets(i).Visible Then
ListBox1.AddItem .Sheets(i).Name
End If
Next i
End With
End Sub
Gruß Tino