Werte von einer Mappe in eine andere Mappe kopiere

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
MsgBox
Bild

Betrifft: Werte von einer Mappe in eine andere Mappe kopiere
von: Luna
Geschrieben am: 28.08.2015 00:00:00

Hola ihr hier im Forum. Ich hab mal wieder was.
Wie ändert man diesen Code das er nur den Bereich A-D kopiert?

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim myrow
Dim mycell
Dim wksQ As Worksheet
Dim wksZ As Worksheet
mycell = ActiveCell.Address
Set wksQ = Worksheets("Tabelle2") ' Anpassen deine Quelldatei
Set wksZ = Worksheets("Ziel")     ' Anpassen deine Zieldatei
wksZ.Activate
myrow = wksZ.Cells(Rows.Count, 1).End(xlUp).Row + 1 'die erste freie Zeile in der Zieldatei
wksZ.Cells(myrow, 1).Select
wksQ.Range(mycell).EntireRow.Copy  ' Wenn Copy durch Cut ersetzt wird, wird ausgeschnitten
wksZ.Paste
Application.CutCopyMode = False  'Kopier- oder Ausschneidemodus wird beendet
End Sub
Der Code kopiert mir per Doppelklick in einer Zelle von Spalte A die ganze Zeile und kopiert sie mir in anderes Tabellenblatt. Ich möchte aber nur den Bereich bis Spalte D kopieren.
Wie immer an euch
Meinen herzlichsten Dank für eure Unterstützung
Luna

Bild

Betrifft: AW: Werte von einer Mappe in eine andere Mappe kopiere
von: Werner
Geschrieben am: 28.08.2015 01:41:32
Hallo Luna,
so vielleicht?

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim myrow As Long
Dim mycell As Long
Dim wksQ As Worksheet
Dim wksZ As Worksheet
mycell = ActiveCell.Row
Set wksQ = Worksheets("Tabelle2") ' Anpassen deine Quelldatei
Set wksZ = Worksheets("Ziel")     ' Anpassen deine Zieldatei
Application.ScreenUpdating = False 'Bildschirmaktualisierung abschalten
myrow = wksZ.Cells(Rows.Count, 1).End(xlUp).Row + 1 'die erste freie Zeile in der Zieldatei
wksQ.Range(wksQ.Cells(mycell, 1), wksQ.Cells(mycell, 4)).Copy wksZ.Cells(myrow, 1) 'Wenn Copy  _
durch Cut ersetzt wird, wird ausgeschnitten
Application.CutCopyMode = False  'Kopier- oder Ausschneidemodus wird beendet
Application.ScreenUpdating = True 'Bildschirmaktualisierung einschalten
End Sub
Gruß Werner

Bild

Betrifft: Werte von einer Mappe in eine andere Mappe kopiere
von: Luna
Geschrieben am: 28.08.2015 23:07:05
Hola Werner, vielen Dank für deine Mühe. Das Makro macht genau das was ich will.
Saludos
Luna

Bild

Betrifft: AW: Danke für die Rückmeldung. o.w.T.
von: Werner
Geschrieben am: 28.08.2015 23:28:12


Bild

Betrifft: AW: Werte von einer Mappe in eine andere Mappe kopiere
von: Case
Geschrieben am: 28.08.2015 01:43:40
Hallo, :-)
probiere es mal so:

Option Explicit
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    Dim lngRow As Long
    On Error GoTo Fin
    ' Gültig für Doppelklick auf Spalte A
    If Not Target.Column <> 1 Then
        ' Zeile 1 wegen Überschrift nicht übertragen
        If Not Target.Row = 1 Then
            ' Nur wenn was drinsteht
            If Not Target.Value = "" Then
                With ThisWorkbook.Worksheets("Ziel")
                    Application.EnableEvents = False
                    lngRow = IIf(IsEmpty(.Cells(.Rows.Count, 1)), _
                        .Cells(.Rows.Count, 1).End(xlUp).Row, .Rows.Count) + 1
                    ' Falls Du kopieren willst - wegen Format, dann bei der
                    ' folgenden Zeile das Kommentarzeichen entfernen
                    ' und bei (.Range("A" & lngRow).Resize....) eines setzen
                    'Target.Resize(, 4).Copy .Range("A" & lngRow).Resize(, 4)
                    .Range("A" & lngRow).Resize(, 4).Value = Target.Resize(, 4).Value
                    Cancel = True
                End With
            End If
        End If
    End If
Fin:
    Application.EnableEvents = True
    If Err.Number <> 0 Then MsgBox "Error: " & _
        Err.Number & " " & Err.Description
End Sub
Servus
Case


Bild

Betrifft: Werte von einer Mappe in eine andere Mappe kopiere
von: Luna
Geschrieben am: 28.08.2015 23:08:40
Hola Case, auch dir vielen Dank für deine tolle Arbeit. Funktioniert einwandfrei und macht das was ich will.
Saludos
Luna

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Werte von einer Mappe in eine andere Mappe kopiere"