Excel-daten in Word-Datei einlesen

Forumthread: Excel-daten in Word-Datei einlesen

24.11.2002 14:18:37

Heinz A. Wankmüller

Hallo Excel-Freunde,
ich habe in der Recherche leider nichts zu meinem Problem gefunden. Es gibt zwar einige Beispiel Bereiche aus Excel in eine Word-Datei zu kopieren und dann z.B. auszudrucken.
Ich möchte aber mehrere verschiedene Daten aus verschiedenen Excel-Zellen in ein Word-Dokument eintragen. Z.B. den Namen eines Kunden an die richtige Stelle im Word-Dokument. Die Straße in die nächste Zeile, dann den Ort. Einen bestimmten Textteil wieder an eine andere Stelle, Zahlen (das Ergebnis einer Berechnung) wieder an eine andere Stelle usw. Wie füge ich solche Daten an den richtigen Stellen ein, und zwar nicht in Form einer Tabelle, sondern einfach als Text?

Danke
Heinz

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Re: Excel-daten in Word-Datei einlesen

24.11.2002 14:49:56

Jens Huthmann
Re: Excel-daten in Word-Datei einlesen

24.11.2002 15:05:25

Panicman
Re: Excel-daten in Word-Datei einlesen

24.11.2002 15:13:48

Heinz A. Wankmüller
DANKE

24.11.2002 15:31:17

Heinz A. Wankmüller

Re: Excel-daten in Word-Datei einlesen

24.11.2002 14:49:56

Jens Huthmann

Hallo Heinz,

kleines Beispiel hierfür:

Sub Export()

Dim Kunde As String
Dim Artikel As String
Dim Menge As Integer
Dim MwStSatz As Double
Dim EP As Currency
Dim Netto As Currency
Dim MwSt As Currency
Dim Brutto As Currency
Dim Pfad As String
Dim Excel As Workbook

'Pfad der Exceldatei bestimmen
Pfad = ActiveWorkbook.Path
Set Excel = ActiveWorkbook

'Einlesen der Exceldaten in Variablen
Sheets(1).Select
Kunde = [c6]
Artikel = [c7]
Menge = [c8]
EP = [c9]
MwStSatz = [c10]
Netto = [c12]
MwSt = [c13]
Brutto = [c14]

'Word aktivieren, bzw. falls noch nicht geöffnet (-->Fehler), dann Word öffnen
On Error Resume Next
Set wordobj = GetObject(, "word.application.8")
If Err.Number = 429 Then
Set wordobj = CreateObject("word.application.8")
GoTo weiter
End If
On Error GoTo 0

weiter:
'Word sichtbar machen und zum aktiven Fenster erheben
wordobj.Visible = True
wordobj.Activate

'auf Word-Dokumentvorlage zugreifen und neues Dokument erstellen
wordobj.Documents.Add Template:=Pfad & "\Datenimport aus Excel.dot", newtemplate:=False
'Alternativ mit dem kompletten Pfadnamen, wenn die Vorlage in einem anderen Ordner
'als die Exceldatei liegt:
'wordobj.Documents.Add Template:="e:\aufträge\angebot.dot", newtemplate:=False
wordobj.WindowState = wdWindowStateMaximize

'Exceldaten aus den Variablen an vordefinierte Textmarken des Worddokuments schreiben
wordobj.activedocument.bookmarks("Kunde").Range = Kunde
wordobj.activedocument.bookmarks("Artikel").Range = Artikel
wordobj.activedocument.bookmarks("Menge").Range = Menge
wordobj.activedocument.bookmarks("EP").Range = FormatNumber(EP, 2) & " "
wordobj.activedocument.bookmarks("MwStSatz").Range = FormatNumber(MwStSatz * 100, False) & "%"
wordobj.activedocument.bookmarks("Netto").Range = FormatNumber(Netto, 2) & " "
wordobj.activedocument.bookmarks("MwSt").Range = FormatNumber(MwSt, 2) & " "
wordobj.activedocument.bookmarks("Brutto").Range = FormatNumber(Brutto, 2) & " "

End Sub

Maile mich direkt an, wenn ich dir die Exceldatei und das Wordtemplate zumailen soll.

Gruß
Jens Huthmann

Re: Excel-daten in Word-Datei einlesen

24.11.2002 15:05:25

Panicman

Hallo Heinz,

schau dir mal in Ruhe die Wordhilfe zu "Serienbrief" an. Dort kannst du deine Exceltabelle als Datenbank hinterlegen und die die Zellen als Text anzeigen lassen.
Du solltes aber deine Exceltabelle so aufbauen, das in der 1 Zeile Überschriften stehen (Name;Vorname;usw.) und dann die Daten ab Zeile 2, wobei alle Daten zu einem Namen in der gleichen Zeile stehen müssen.

Viel Spaß
Holger

Re: Excel-daten in Word-Datei einlesen

24.11.2002 15:13:48

Heinz A. Wankmüller

Hallo Holger,
danke für deine Antwort. Den Serienbrief kenne ich, ich möchte aber aus Excel heraus Word öffnen, in eine Vorlage verschiedene Daten eintragen, ausdrucken und dann wieder in Excel weiterarbeiten.

Gruß
Heinz

DANKE

24.11.2002 15:31:17

Heinz A. Wankmüller

Halo Jens,
funktioniert prima. Werde es gleich in mein Beispiel umsetzen.

Gruß
Heinz

Beliebteste Forumthreads (12 Monate)

Excel-daten in Word-Datei einlesen

Forumthread: Excel-daten in Word-Datei einlesen

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread