Microsoft Excel

Herbers Excel/VBA-Archiv

Problem mit: ZELLE("dateiname")

Betrifft: Problem mit: ZELLE("dateiname") von: Matze
Geschrieben am: 24.08.2004 22:06:37

Hallo zusammen,

ich habe folgendes Problem:
in der Tabelle "Entwicklung Mitglieder" habe ich in der Spalte A verschieden Namen und in den Spalten B bis N monatliche Werte. Für jeden Namen in der Tabelle habe ich einzelne weitere Tabellenblätter (40 Stück). Mit der folgenden Formel:

=INDEX('Entwicklung Mitglieder'!$A$14:$N$58;VERGLEICH(RECHTS(ZELLE("dateiname");LÄNGE(ZELLE("dateiname"))-FINDEN("]";ZELLE("dateiname")));'Entwicklung Mitglieder'!$A$14:$A$58;0);3)

wollte ich erreichen, dass die einzelnen Werte in Abhängigkeit vom Tabellenblattname aus der Matrix entnommen werden.

Die Funktion "ZELLE("dateiname")" funktioniert nur für das letzte! bearbeitete Tabellenblatt, ich habe damit in jedem Tabellenblatt die gleichen Werte!

Woran liegt das?

Ich brauche eine Lösung ohne Makro.

Danke im voraus.
Matze

  


Betrifft: AW: Problem mit: ZELLE("dateiname") von: ExceL
Geschrieben am: 24.08.2004 22:11:52

hi

haste das schon versucht

=INDEX('Entwicklung Mitglieder'!$A$14:$N$58;VERGLEICH(RECHTS(ZELLE("dateiname";A1);LÄNGE(ZELLE("dateiname";A1))-FINDEN("]";ZELLE("dateiname";A1)));'Entwicklung Mitglieder'!$A$14:$A$58;0);3)

Gruß
Christian


  


Betrifft: AW: Problem mit: ZELLE("dateiname") von: Matze
Geschrieben am: 24.08.2004 22:16:49

Hallo Christian,

so habe ich es noch nie versucht, was erreiche ich mit dem Bezug auf A1? Ich werde aus der Hilfe leider nicht ganz schlau.

mfg
Matze


  


Betrifft: AW: Problem mit: ZELLE("dateiname") von: ExceL
Geschrieben am: 24.08.2004 22:21:40

hi

damit veramkerst du die Tabell in dem blatt wo die Formel steht

=ZELLE("dateiname";A1)
=ZELLE("dateiname")

schreibe mal beides in ein Tabellenblatt

es erscheint bei beiden der gleiche Name
(vorausgesetzt die Mappe ist schon gespeichert :-))

klicke eine andere Tabelle an schreibe etwas in eine Zelle
und wechsle zurück auf die vorige Tabelle dann wirst du den unterschied erkennen

Gruß
Christian


  


Betrifft: zusatz !! es muss nicht A1 sein jeder Zellname von: ExceL
Geschrieben am: 24.08.2004 22:23:25

geht

:-)

Gruß
Chris


  


Betrifft: AW: Problem mit: ZELLE("dateiname") von: Matze
Geschrieben am: 24.08.2004 22:30:12

Hallo Christian,

Super, DANKE!! Du hast mir gerade den Feierabend gerettet. Meine Haare können so auf dem Kopf bleiben :-))

mfg
Matze


  


Betrifft: freut mich das es geht __ot von: ExceL
Geschrieben am: 24.08.2004 22:36:23




 

Beiträge aus den Excel-Beispielen zum Thema "Problem mit: ZELLE("dateiname")"