Rangnr. (rückwärts) aus Liste mit gleichen Namen

Bild

Betrifft: Rangnr. (rückwärts) aus Liste mit gleichen Namen
von: Joerschi
Geschrieben am: 21.06.2015 17:19:29

Hallo liebes Forum,
ich suche eine Lösung für folgende Situation (Skizze + Musterdatei unten):
In Spalte A stehen untereinander Namen; viele davon gleich.
In Spalte B stehen je Name zugehörige Werte.
In Spalte C und D soll nun der Rang der jeweiligen Prozentzahl in B zu allen Werten des Namens in Spalte A ausgegeben werden (es sollen also nur die Werte des jeweiligen Namens beachtet werden).
In Spalte C mit Beachtung von doppelten Werte je Name; in Spalte D ohne Beachtung von Dopplungen (einfach von unten nach oben durchzählen).
Wichtig ist außerdem, das der Rang rückwärts gezählt werden soll (also kleinste Zahl ist Rang 1).
Für den Namen "F127" hab ich das mal beispielhaft in die Skizze eingetragen (Gelb ist der Bereich, welcher via Formel gesucht wird):
Userbild
Musterdatei: https://www.herber.de/bbs/user/98354.xlsx
Hat jemand einen Ratschlag, wie man das angehen können?
Viele Grüße
joerschi

Bild

Betrifft: AW: Rangnr. (rückwärts) aus Liste mit gleichen Namen
von: Sepp
Geschrieben am: 21.06.2015 17:29:03
Hallo joerschi,
so?
Tabelle1

 ABCD
1NameWertRang-Nr. (doppelte Werte beachten)Rang-Nr. (doppelte Werte ignorieren)
2F12699%56
3F12699%55
4F12692%44
5F12683%33
6F12649%22
7F12625%11
8F12799%78
9F12799%77
10F12795%66
11F12791%55
12F12780%44
13F12749%23
14F12749%22
15F12725%11
16F12899%77
17F12898%66
18F12895%55
19F12890%44
20F12865%33
21F12848%22
22F12826%11
23F12999%23
24F12999%22
25F12956%11
26F13099%33
27F13077%22
28F13049%11
29F13199%44
30F13186%33
31F13172%22
32F13136%11

Formeln der Tabelle
ZelleFormel
C2=SUMMENPRODUKT(($A$2:$A$32=A2)*($B$2:$B$32<B2))+1
D2=SUMMENPRODUKT(($A$2:$A$32=A2)*($B$2:$B$32-ZEILE($2:$32)*10^-9<B2-ZEILE()*10^-9))+1


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Sepp


Bild

Betrifft: AW: Rangnr. (rückwärts) aus Liste mit gleichen Namen
von: Joerschi
Geschrieben am: 21.06.2015 17:39:32
wow. Da wäre ich nicht drauf bekommen. Besonders die Formel für D2 erscheint sehr tricky (aber funktioniert :D).
Vielen herzlichen Dank @ Sepp
Beste Grüße
Joerschi

Bild

Betrifft: doch noch eine ergänzende Frage...
von: Joerschi
Geschrieben am: 21.06.2015 17:50:37
Die Werte und Namen in meiner Tabelle erstrecken sich über ca. 5000 Zeilen.
Überschreibt man nun den Wert 32 der Beispieldatei mit 5000, so wird nur noch "#Wert" angezeigt. Wahrscheinlich auf Grund der Berechnungskonstellation.
Kann man das umgehen?
Viele Grüße
Joerschi

Bild

Betrifft: AW: doch noch eine ergänzende Frage...
von: Sepp
Geschrieben am: 21.06.2015 17:53:17
Hallo,
kann ich nicht nachvollziehen.
Tabelle1

 ABCDE
1NameWertRang-Nr. (doppelte Werte beachten)Rang-Nr. (doppelte Werte ignorieren) 
2F12699%56 
3F12699%55 
4F12692%44 
5F12683%33 
6F12649%22 
7F12625%11 
8F12799%78 
9F12799%77 
10F12795%66 
11F12791%55 
12F12780%44 

Formeln der Tabelle
ZelleFormel
C2=SUMMENPRODUKT(($A$2:$A$5000=A2)*($B$2:$B$5000<B2))+1
D2=SUMMENPRODUKT(($A$2:$A$5000=A2)*($B$2:$B$5000-ZEILE($2:$5000)*10^-9<B2-ZEILE()*10^-9))+1


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Sepp


Bild

Betrifft: AW: doch noch eine ergänzende Frage...
von: Joerschi
Geschrieben am: 21.06.2015 19:13:45
ok, es liegt an meiner Tabelle.
Die Prozentwerte sind veränderlich, sprich immer eine andere Anzahl von Zeilen wird belegt.
Dadurch gibt es dann z. B. von Zeile 4000:5000 bei den Werten eine leere Zelle, die mit "" gefüllt ist. Sobald das "" in den Wertebereich mit reinkommt, ergibt die Formel #Wert.
Könnte man das mit IstWert etc. lösen?
Viele Grüße
Joerschi

Bild

Betrifft: AW: doch noch eine ergänzende Frage...
von: Sepp
Geschrieben am: 21.06.2015 19:33:11
Hallo joerschi,
und warum schreibst du "" in die Zelle? Schreib stattdessen eine 0 und blende die Nullwerte per Format aus, dann braucht man sich bei den Formeln nicht verrenken!

Gruß Sepp


Bild

Betrifft: weitere ergänzende Frage...
von: Joerschi
Geschrieben am: 24.06.2015 09:07:06
Vielen Dank Sepp, so habe ich das Problem dann auch auch angepackt.
Eine weitere ergänzende Frage zu einem Ranking habe ich noch...
Wie müsste man es verformeln, wenn das Ranking wieder aufsteigend nach Namen erfolgt, jedoch jeder Wert (egal wie oft er vorkommt) einen bestimmten Rang (der immer nur um 1 steigt) besitzt?
Also so:
Der erste (=niedrigste) Wert besitzt Rang 1 - egal wie oft er sich wiederholt.
Der zweitniedrigste Wert besitzt immer Rang 2 - egal wie oft er sich wiederholt.
usw.
Händisch als Beispiel:
Userbild
Würde mich freuen, wenn Du oder jemand anders hier einen Ansatz hättest :-)
Danke vorab und Liebe Grüße
Joerschi

Bild

Betrifft: AW: weitere ergänzende Frage...
von: Sepp
Geschrieben am: 24.06.2015 20:06:47
Hallo joerschi,
Tabelle1

 ABE
1NameWertRang-Nr.absolut (jedder Wert = ein bestimmter Rang)
2F12699%5
3F12699%5
4F12692%4
5F12683%3
6F12649%2
7F12625%1
8F127100%7
9F12799%6
10F12799%6
11F12795%5
12F12791%4
13F12780%3
14F12749%2
15F12749%2
16F12725%1
17F12898%6
18F12895%5
19F12890%4

Formeln der Tabelle
ZelleFormel
E2{=ANZAHL((B2&"")/HÄUFIGKEIT(WENN(($A$2:$A$32=A2)*($B$2:$B$32<=B2); $B$2:$B$32); $B$2:$B$32))}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Quelle: http://www.excelformeln.de/formeln.html?welcher=230
Gruß Sepp


Bild

Betrifft: AW: weitere ergänzende Frage...
von: Joerschi
Geschrieben am: 24.06.2015 20:39:08
und wiederum möchte ich mich herzlichen bedanken :-)
Mit HÄUFIGKEIT auch gleich einen neuen Namen gelernt, mit dem man sich beschäftigen kann/sollte...
Liebe Grüße
Joerschi

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Rangnr. (rückwärts) aus Liste mit gleichen Namen"