Matrix: {Summe(Wenn(Oder...}

Forumthread: Matrix: {Summe(Wenn(Oder...}

Matthias

Hallo Excel-Welt,
ich benötige wenn möglich eine generelle Aussage, keine Lösung.
Ich habe innerhalb einer Matrix {Summe(Wenn - Funktion mit ca. 4 Wenn's und ein wenn(oder
Ohne oder funktioniert es prima sobal ich ein wenn um oder ein oder ergänze werden beide Kriterien ignoriert..
Geht das {Summe(wenn(oder - in der Matrix generell nicht oder mache ich einen Denkfehler?
Derzeit löse ich es über 2 Matrix-Funktionen welche sich addieren.
Vielen Dank im Voraus für den Support.
Gruss Matthias

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

AW: Matrix: {Summe(Wenn(Oder...}

07.04.2010 15:50:43

Mike

Hallo Matthias,
wenn dann sonst sonst dann dann sonst .. ;-) ... versuch Dein Anliegen anhand
eines (neutralisierten) Beispiels hochzuladen.
Gruss
Mike

AW: Matrix: {Summe(Wenn(Oder...}

08.04.2010 08:09:16

Matthias

Hallo Mike,
sorry für unprofessionelles Beispiel.
Hier mein Muster:
{=SUMME(WENN(G$5=SAP!$A$3:$A$2111;
WENN($E39=SAP!$B$3:$B$2111;
WENN($AJ39=SAP!$H$3:$H$2111;
WENN(ODER($AI39=SAP!$J$3:$J$2111;$AK39=SAP!$J$3:$J$2111);
WENN($AL39SAP!$I$3:$I$2111;
SAP!$L$3:$L$2111))))))/1000000}
Die eingerückte Zeile wird nicht berücksichtigt, erst wenn mann das oder und das zweite Kriterium wieder rausnimmt.
Danke & Gruss
Matthias

ODER in Matrixformel

08.04.2010 20:56:21

Erich

Hi Matthias,
das ODER erschlägt deine Matrixformel. Es wertet eine Matrix aus - zu einem einzigen Wahrheitswert,
nicht zu einer Matrix, wie du es bräuchtest.
Das kannst du dir mit Extras - Formelüberwachung - Formelauswertung ansehen.
Du könntest das wie in C19 vermeiden (ungetestet und ungeprüft, es gibt sicher auch schönere Möglichkeiten):

	C
17	0
18
19	0

Formeln der Tabelle

Zelle	Formel
C17	{=SUMME(WENN(G$5=SAP!$A$3:$A$2111; WENN($E39=SAP!$B$3:$B$2111; WENN($AJ39=SAP!$H$3:$H$2111; WENN(ODER($AI39=SAP!$J$3:$J$2111;$AK39=SAP!$J$3:$J$2111); WENN($AL39<>SAP!$I$3:$I$2111; SAP!$L$3:$L$2111))))))/1000000}
C19	{=(SUMME(WENN(G$5=SAP!$A$3:$A$2111; WENN($E39=SAP!$B$3:$B$2111; WENN($AJ39=SAP!$H$3:$H$2111; WENN($AI39=SAP!$J$3:$J$2111; WENN($AL39<>SAP!$I$3:$I$2111; SAP!$L$3:$L$2111)))))) +SUMME(WENN(G$5=SAP!$A$3:$A$2111; WENN($E39=SAP!$B$3:$B$2111; WENN($AJ39=SAP!$H$3:$H$2111; WENN(($AI39<>$AK39)*($AK39=SAP!$J$3:$J$2111); WENN($AL39<>SAP!$I$3:$I$2111; SAP!$L$3:$L$2111)))))))/1000000}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

P.S.:
Die Einrückungen in der Formel hat der Internet-Browser verschluckt.
Um sie zu erkennen, habe ich mir den html-Quelltext deines Beitrags angesehen.
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

AW: ODER in Matrixformel

12.04.2010 07:28:51

Matthias

Hallo Erich,
besten Dank für die Infos.
Sorry für verspätete Antwort.
Ich sehe es mir gerne an.
Gruss Matthias

AW: ODER in Matrixformel

12.04.2010 07:30:26

Matthias

Hallo Erich,
besten Dank für die Infos.
Sorry für verspätete Antwort.
Ich sehe es mir gerne an.
Gruss Matthias

A+B>0 statt ODER(A;B) in Matrixformel

08.04.2010 23:31:15

Erich

Hi Matthias,
hier noch eine wohl etwas geschicktere Alternative - in C18:

	C
17	0
18	0

Formeln der Tabelle

Zelle	Formel
C17	{=SUMME(WENN(G$5=SAP!$A$3:$A$2111; WENN($E39=SAP!$B$3:$B$2111; WENN($AJ39=SAP!$H$3:$H$2111; WENN(ODER($AI39=SAP!$J$3:$J$2111;$AK39=SAP!$J$3:$J$2111); WENN($AL39<>SAP!$I$3:$I$2111; SAP!$L$3:$L$2111))))))/1000000}
C18	{=SUMME(WENN(G$5=SAP!$A$3:$A$2111; WENN($E39=SAP!$B$3:$B$2111; WENN($AJ39=SAP!$H$3:$H$2111; WENN(($AI39=SAP!$J$3:$J$2111)+($AK39=SAP!$J$3:$J$2111)>0; WENN($AL39<>SAP!$I$3:$I$2111; SAP!$L$3:$L$2111))))))/1000000}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

AW: A+B>0 statt ODER(A;B) in Matrixformel

13.04.2010 08:34:33

Matthias

Hallo Erich,
vielen Dank für die Mühe, es funktiniert selbstverständlich.
Mir ist nur das größer 0 unklar, es geht mit und auch ohne?
Gruss Matthias

zum Knobeln und Verstehen

13.04.2010 12:02:06

Erich

Hi Matthias,
hier mal ein paar kleine Formeln zum Tüfteln und Probieren.
(Die Formeln von den Zeilen 1, 7 und 13 musst du jeweils auf die drei Zeilen darunter kopieren.)

	A	B	C	D	E	F	G	H
1	0	0	FALSCH	FALSCH	FALSCH	0	nicht	nicht
2	0	1	WAHR	WAHR	WAHR	1	ok	ok
3	1	0	WAHR	WAHR	WAHR	1	ok	ok
4	1	1	WAHR	WAHR	WAHR	2	ok	ok
5
6
7			FALSCH	FALSCH	FALSCH	0	0	0
8			FALSCH	WAHR	WAHR	0	0	0
9			WAHR	FALSCH	WAHR	1	1	1
10			WAHR	WAHR	WAHR	1	1	1
11
12
13			FALSCH	FALSCH	nicht	nicht	nicht
14			FALSCH	WAHR	ok	ok	ok
15			WAHR	FALSCH	ok	ok	ok
16			WAHR	WAHR	ok	ok	ok

Formeln der Tabelle

Zelle	Formel
C1	=ODER(A1;B1)
D1	=UND(F1)
E1	=ODER(F1)
F1	=A1+B1
G1	=WENN(F1;"ok";"nicht")
H1	=WENN(F1>0;"ok";"nicht")
E7	=ODER(C7;D7)
F7	=GANZZAHL(C7)
G7	=1*C7
H7	=0+C7
E13	=WENN(ODER(C13;D13); "ok";"nicht")
F13	=WENN(C13+D13>0;"ok";"nicht")
G13	=WENN(C13+D13;"ok";"nicht")

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

Beliebteste Forumthreads (12 Monate)

Forumthread: Matrix: {Summe(Wenn(Oder...}

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Matrix: {Summe(Wenn(Oder...}

Forumthread: Matrix: {Summe(Wenn(Oder...}

8 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread