SUMMEWENNS mit multiplen Bedingungen

Bild

Betrifft: SUMMEWENNS mit multiplen Bedingungen
von: Nik
Geschrieben am: 25.06.2015 14:26:07

Hallo erstmal,
ich würde gerne das Summieren einer Spalte an mehrere Bedingungen knüpfen.
Meine Formel lautet bisher so: =SUMMEWENNS(Q2:Q90;$F$2:$F$90;"BH";$B$2:$B$90;"MUHR UND BENDER KG";C2:C90;ODER("13369660""13369661""13369662""13400096""13400097""13400098""13400099""13451113""95384360"))
In Zelle Q91 soll die Formel rein.
Habe versucht in die SUMMEWENNS FOrmel ein Oder zu basteln, aber ich kriege als ergebnis immer 0 raus.
https://www.herber.de/bbs/user/98475.xlsx
Damit man mal sieht was ich bisher immer gemacht habe, in Zelle Q92 kann man das sehen.
Hoffe das ist verständlich :-/
Liebe Gruß
Nik

Bild

Betrifft: mit SUMMENPRODUKT() ... und ...
von: der neopa C
Geschrieben am: 25.06.2015 14:46:33
Hallo Nik,
... Deine Datenwerte in B2:B90 entsprechen vom Typ nicht den Werte in B96:J96
Deshalb das doppelte - in der Formel:
=SUMMENPRODUKT(($F2:$F90="BH")*($B2:$B90="MUHR UND BENDER KG")*(--C2:C90=B96:J96))
Gruß Werner
.. , - ...

Bild

Betrifft: AW: mit SUMMENPRODUKT() ... und ...
von: Nik
Geschrieben am: 26.06.2015 06:26:23
Hallo Werner,
danke erstmal für deine Antwort.
Die Formel funktioniert.
Nur wollte ich eigentlich, dass die Formel alle Zahlen von Q2:Q90 in Q91 summiert ausgibt, welche den Kriterien entsprechen.
Also: Wenn in Spalte F2:F90 ein "BH" steht
UND in B2:B90 ein "MUHR UND BENDER KG" steht
UND in Spalte C2:90 die 13369660 oder 13369661 oder 13369662 oder 13400096 oder 13400097 oder 13400098 oder 13400099 oder 13451113 oder 95384360.
Das Ergebnis was in Q91 eigentlich stehen müsste ist "2344"

Bild

Betrifft: AW: mit SUMMENPRODUKT() ... und ...
von: Nik
Geschrieben am: 26.06.2015 06:29:49
Sorry, .. Das Ergebnis was in Q91 eigentlich stehen müsste ist "256"

Bild

Betrifft: AW: mit SUMMENPRODUKT() ... und ...
von: MCO
Geschrieben am: 26.06.2015 07:13:40
Guten Morgen!
erweitere die Formel um die Spalte Q

=SUMMENPRODUKT(($F2:$F90="BH")*($B2:$B90="MUHR UND BENDER KG")*(--C2:C90=B93:J93)*Q2:Q90) 
Gruß, MCO

Bild

Betrifft: AW: mit SUMMENPRODUKT() ... und ...
von: Nik
Geschrieben am: 26.06.2015 08:00:37
Danke MCO, das hat super geklappt!
Jetzt würde ich normalerweise diese Formel nehmen und für verschiedene PLT´s in Spalte F addieren
=SUMMENPRODUKT(($F2:$F90="BH")*($B2:$B90="MUHR UND BENDER KG")*(--C2:C90=B93:J93)*Q2:Q90)
+SUMMENPRODUKT(($F2:$F90="BO")*($B2:$B90="MUHR UND BENDER KG")*(--C2:C90=B93:J93)*Q2:Q90)
+SUMMENPRODUKT(($F2:$F90="ZA")*($B2:$B90="MUHR UND BENDER KG")*(--C2:C90=B93:J93)*Q2:Q90)
+SUMMENPRODUKT(($F2:$F90="EP")*($B2:$B90="MUHR UND BENDER KG")*(--C2:C90=B93:J93)*Q2:Q90)
usw...
https://www.herber.de/bbs/user/98489.xlsx
Kann ich das auch irgendwie eleganter lösen?

Bild

Betrifft: das VERGLEICH()en der zusätzl. Werte einbinden ...
von: der neopa C
Geschrieben am: 26.06.2015 08:39:45
Hallo Nik,
... die gewünschte Verkürzung der Formel wäre so: =SUMMENPRODUKT(ISTZAHL(VERGLEICH(F2:F90;B96:J96;))*($B2:$B90="MUHR UND BENDER KG")*(--C2:C90=B93:J93)*Q2:Q90) zu erreichen.
Gruß Werner
.. , - ...

Bild

Betrifft: AW: das VERGLEICH()en der zusätzl.
von: Nik
Geschrieben am: 26.06.2015 10:08:41
Perfekt !!
Vielen vielen Dank Werner und MCO :-)
Gruß
Nik

 Bild

Beiträge aus den Excel-Beispielen zum Thema "SUMMEWENNS mit multiplen Bedingungen"