UserForm schließen, wenn keine Tastaturaktivität

Hallo!
Ich komme leider nicht alleine weiter und suche Rat. Mein Problem:
Eine UserForm soll nach Ablauf von z.B. 120 sec. geschlossen werden, wenn keine Tastatur- oder Mausaktivität vorliegt, sprich niemand im Programm arbeitet ("Auto-Log off"). Hintergrund: Es soll dann eine erneute Anmeldung mit Password erforderlich sein.
Folgender Code funktioniert für die Feststellung von Mausaktivität gut:
Private Type POINTAPI
x As Long
y As Long
End Type
Private Declare


Function GetCursorPos Lib "user32" (lpPoint As POINTAPI) As Long

Function MausPositionVeraendert() As Boolean
lRetVal = GetCursorPos(pTargetPoint)
If pTargetPoint.x = x_alt And pTargetPoint.y = y_alt Then
MausPositionVeraendert = False
Else
MausPositionVeraendert = True
End If
x_alt = pTargetPoint.x
y_alt = pTargetPoint.y
End Function

Sub TimerRoutine()
If MausPositionVeraendert = True Then
timer_count = timer_multiplier
Else
timer_count = timer_count - 1
End If
If timer_count = 0 Then
LogIn.Show  ' Anmeldebildschirm
Else
Call TimerSetzen(timer_count)
End If
End Sub

Sub TimerSetzen(c As Integer)
TimerGestartet = Now
Application.OnTime earliestTime:=TimerGestartet + TimeValue(timerintervall$), Procedure:="  _
_
TimerRoutine"
timer_count = c
End Sub

Sub TimerAktualisieren()
Call TimerLoeschen
Call TimerSetzen(timer_multiplier)
End Sub

Leider weiß ich jetzt nicht weiter, wie ich die Tastatur analog zur Mausposition abfragen soll, um Aktivität festzustellen.

Ich habe mit GetInputState experimentiert, aber keine Lösung gefunden.

Hat jemand eine zündende Idee?

Vielen Dank für jede Antwort

Oliver

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo,
du kannst die Maus und Tastatur gleichzeitig überwachen.
Im Modul des Userforms:

Option Explicit

Private Sub UserForm_Activate()
Call StartTimer
End Sub

In einem Standardmodul:

Option Explicit
Option Private Module

Private Declare PtrSafe Sub GetLastInputInfo Lib "user32.dll" ( _
    ByRef plii As LASTINPUTINFO)
Private Declare PtrSafe Function GetTickCount Lib "kernel32.dll" () As Long
Private Declare PtrSafe Function SetTimer Lib "user32.dll" ( _
    ByVal hwnd As LongPtr, _
    ByVal nIDEvent As LongPtr, _
    ByVal uElapse As Long, _
    ByVal lpTimerFunc As LongPtr) As LongPtr
Private Declare PtrSafe Function KillTimer Lib "user32.dll" ( _
    ByVal hwnd As LongPtr, _
    ByVal nIDEvent As LongPtr) As Long

Private Type LASTINPUTINFO
    cbSize As Long
    dwTime As Long
End Type

Private Const TIME_TO_CLOSE As Single = 120 ' Zeit nach das Userform geschlossen werden soll in Sekunden

Public Sub StartTimer()
    Call SetTimer(Application.hwnd, 0, 1000&, AddressOf TimerRun)
End Sub

Private Sub StopTimer()
    Call KillTimer(Application.hwnd, 0)
End Sub

Sub TimerRun(ByVal hwnd As LongPtr, ByVal uMsg As LongPtr, _
        ByVal nIDEvent As Long, ByVal dwTimer As LongPtr)
    If IdleTime >= TIME_TO_CLOSE Then
        Call StopTimer
        Call Unload(Object:=UserForm1)
    End If
End Sub

Private Function IdleTime() As Single
    Dim udtInputInfo As LASTINPUTINFO
    udtInputInfo.cbSize = LenB(udtInputInfo)
    Call GetLastInputInfo(udtInputInfo)
    IdleTime = (GetTickCount - udtInputInfo.dwTime) / 1000
End Function

Gruß
Nepumuk

Beliebteste Forumthreads (12 Monate)

UserForm schließen, wenn keine Tastaturaktivität

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

UserForm schließen, wenn keine Tastaturaktivität

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread