Das Archiv des Excel-Forums
Dateiname und Pfad in Zelle???
Betrifft: Dateiname und Pfad in Zelle???
von: Albrecht
Geschrieben am: 19.09.2003 10:25:24
Hallo,
wer kann mir den Befehl hier mitteilen, wie ich in das EXCELBLATT in eine Zelle
den 'Dateiname und Pfad' einfügen kann??
Danke vorab.
Gruß Albrecht
Betrifft: AW: ZELLE
von: Galenzo
Geschrieben am: 19.09.2003 10:38:24
schau dir mal die Funktion ZELLE ("Dateiname") an.
Betrifft: AW: ZELLE
von: Hajo_Zi
Geschrieben am: 19.09.2003 10:41:58
Hallo
aber nicht ;A1 vergessen.
Gruß Hajo
Betrifft: AW: Dateiname und Pfad in Zelle???
von: Hajo_Zi
Geschrieben am: 19.09.2003 15:30:48
Hallo Albrecht
obwohl es mir scheint das hier keine Rückmeldung mehr kommt. Hier nochmal die komplett Lösung.
|
Tabelle1 |
| A | B | 1 | D:\Eigene Dateien\Hajo\Internet\Ohne Makro\[dateiname_ in_zelle.xls]Tabelle1 | Phad + Datei + Register | 2 | dateiname_ in_zelle.xls | Dateiname mit Endung | 3 | dateiname_ in_zelle | Dateiname ohne Endung | 4 | Tabelle1 | Register von WF | 5 | D:\Eigene Dateien\Hajo\Internet\Ohne Makro\ | nur Phad | 6 | D:\Eigene Dateien\Hajo\ | nur Phad | 7 | Eigene Dateien\Hajo\Internet\Ohne Makro\ | nur Phad ohne Laufwerk | 8 | | | 9 | | | 10 | Bitte Beachten es wird die formel in den Foren auch oft ohne "A1" geschrieben | | 11 | Dies führt aber zu Problemen, wenn mehere Dateien auf sind und gewechselt wird. | |
Formeln der Tabelle | A1 : =ZELLE("Dateiname";A1)
A2 : =TEIL(ZELLE("Dateiname";A1);FINDEN("[";ZELLE("Dateiname";A1))+1;FINDEN("]";ZELLE("Dateiname";A1))-FINDEN("[";ZELLE("Dateiname";A1))-1)
A3 : =TEIL(ZELLE("Dateiname";A1);FINDEN("[";ZELLE("Dateiname";A1))+1;FINDEN("]";ZELLE("Dateiname";A1))-FINDEN("[";ZELLE("Dateiname";A1))-5)
A4 : =TEIL(ZELLE("dateiname";A1);FINDEN("]";ZELLE("dateiname";A1))+1;255)
A5 : =TEIL(ZELLE("Dateiname";A1);1;FINDEN("[";ZELLE("Dateiname";A1))-1)
A6 : =INFO("Verzeichnis")
A7 : =TEIL(ZELLE("Dateiname";A1);4;FINDEN("[";ZELLE("Dateiname";A1))-4)
|
|
|
Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 2.0 Download
Falls Code vorhanden wurde dieser getestet unter Betriebssystem XP Pro und Excel Version XP SBE.
Bitte kein Mail, Probleme sollen im Forum gelöst werden.
Microsoft MVP für Excel
Das Forum lebt auch von den Rückmeldungen.
Zurzeit gibt es wieder Probleme mit der E-Mail Benachrichtigung.
Ich bekomme Mails zu Beiträgen an denen ich nicht beteiligt bin und zusätzlich noch Mails zu meinen eigenen Beiträgen.
Das Problem mit den eigenen Benachrichtigung kann gelöst werden durch Lösche und Neuanmelden. Dieses möchte ich aber nicht jeden Tag machen.
Um dieses Problem erstmal zu beseitigen habe ich die automatische Mailbenachrichtigung abgeschaltet.
Aus diesem Grunde ist es dem Zufall überlassen ob auf Rückfragen Antworten von mir kommen.
http://home.media-n.de/ziplies/
Betrifft: AW: Dateiname und Pfad in Zelle???
von: Albrecht
Geschrieben am: 19.09.2003 16:52:16
Vielen Dank für alle Rückmeldungen, es hat funktioniert.
Danke und ein schönes Wochenende.
Gruß Albrecht
Excel-Beispiele zum Thema " Dateiname und Pfad in Zelle???"