Kommentare mit Makro in Zelle einfügen

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
Frame InputBox
Bild

Betrifft: Kommentare mit Makro in Zelle einfügen
von: Torsten
Geschrieben am: 21.05.2015 21:12:43

Hallo zusammen,
ich freue mich rieisg endlich ein Teil dieses Forums zu sein.
Zu meiner Frage.
Ich möchte gerne Kommentare mittels Makro erstellen.
Knifflig ist, dass ich auch mehrere Zellen gleichzeitig mit einem und dem selben Kommentar befüllen will.
Bereits eingetragene (individuelle) Kommentare sollen nicht gelöscht, sondern ergänzt werden.
Das bereits vorhandene Makro behält bereits Kommentare bei und ergänzt diese.


Sub KommentareErgänzen()
Dim sAlt As String
Dim sNeu As String
    sNeu = InputBox("Geben Sie einen Kommentar ein", "Kommentar ergänzen")
    If sNeu = "" Then Exit Sub
 
  With ActiveCell
    On Error Resume Next
    sAlt = .Comment.Text
    If sAlt = "" Then .AddComment
    sNeu = sAlt & Chr(10) & Application.UserName _
        & Chr(10) & Date & "/" & Time & _
        Chr(10) & sNeu & Chr(10)
    .Comment.Text sNeu
    .Comment.Visible = False
    .Comment.Shape.TextFrame.AutoSize = True
  End With
 
End Sub

Freue mich über jede Hilfe

Bild

Betrifft: AW: Kommentare mit Makro in Zelle einfügen
von: Gerd L
Geschrieben am: 21.05.2015 21:33:02
Hallo Torsten!

Sub KommentareErgänzen_2()
Dim objZelle As Range
Dim sAlt As String
Dim sNeu As String
    sNeu = InputBox("Geben Sie einen Kommentar ein", "Kommentar ergänzen")
    If sNeu = "" Then Exit Sub
 
  
'For Each objZelle In Range("A2:G7")
'oder über die Markierung
For Each objZelle In Selection
  
  With objZelle
    On Error Resume Next
    sAlt = .Comment.Text
    If sAlt = "" Then .AddComment
    sNeu = sAlt & Chr(10) & Application.UserName _
        & Chr(10) & Date & "/" & Time & _
        Chr(10) & sNeu & Chr(10)
    .Comment.Text sNeu
    .Comment.Visible = False
    .Comment.Shape.TextFrame.AutoSize = True
  End With
 
Next
End Sub
Gruß Gerd

Bild

Betrifft: AW: Kommentare mit Makro in Zelle einfügen
von: Torsten
Geschrieben am: 21.05.2015 21:47:35
Hallo Gerd,
vielen Dank für die Blitzantwort.
Der Kommentar wird hierbei zwar in alle markierten Zellen geschrieben,
jedoch verdoppelt sich der Wert bei jeder Zelle.
Markiert z.B.: A2 bis G2
Text:"Hallo"
A2= Hallo
B2= Hallo , Hallo
C2= Hallo, Hallo, Hallo
D2= Hallo, Hallo, Hallo, Hallo
Irgendwie ist es das noch nicht.

Bild

Betrifft: AW: Kommentare mit Makro in Zelle einfügen
von: Gerd L
Geschrieben am: 21.05.2015 22:21:42
Hallo Torsten,
vieleicht gefällt es dir so besser?

Sub KommentareErgänzen_3()
Dim objZelle As Range
Dim sAlt As String
Dim sNeu As String
    sNeu = InputBox("Geben Sie einen Kommentar ein", "Kommentar ergänzen")
    If sNeu = "" Then Exit Sub
 
  
'For Each objZelle In Range("A2:G7")
'oder über die Markierung
For Each objZelle In Selection
  
  With objZelle
    On Error Resume Next
    sAlt = .Comment.Text
    If sAlt = "" Then .AddComment
    
    .Comment.Text sAlt & Chr(10) & Application.UserName _
        & Chr(10) & Date & "/" & Time & _
        Chr(10) & sNeu & Chr(10)
    
    .Comment.Visible = False
    .Comment.Shape.TextFrame.AutoSize = True
  
  End With
 
Next
End Sub
Gruß Gerd

Bild

Betrifft: AW: Kommentare mit Makro in Zelle einfügen
von: Torsten
Geschrieben am: 21.05.2015 23:33:00
Hallo Gerd,
jetzt sind die Dopllungen raus.
Das sieht gut aus.
Wenn nun aber in A2 und B2 z.B. "Hallo" steht.
Und ich beim zweiten mal B2 und C2 markiere und das Makro starte, setzt er den jetzigen Wert nur auf die bereits ausgefüllte Zelle in B2 und lässt C2 leer.
Ich versuche und versuche nun selbst auch schon seit ca. 9Std. und kann einfach nicht von lassen.
Man könnte sich die Haare ausreißen.
Komischerweise gibt es nur das Problem, wenn in den markierten Zellen eine bereits beschriftete Zelle vorhanden ist. Dann werden die nachfolgenden Zellen, nach der bereits beschrifteten nicht befüllt.
Ich werde es auch noch weiter versuchen.
Wenn noch jemand eine Idee hat, dann bin ich sehr dankbar.
Trotzdem, vielen Dank Gerd das du dich so schnell der Sache angenommen hast.

Bild

Betrifft: AW: Kommentare mit Makro in Zelle einfügen
von: Torsten
Geschrieben am: 22.05.2015 10:59:02
Habe noch bis 3Uhr Morgens versucht und versucht, leider ohne Erfolg.
Vielleicht findet sich ja noch jemand mit einer Blitzidee die das Problem löst.

Bild

Betrifft: AW: Kommentare mit Makro in Zelle einfügen
von: Torsten
Geschrieben am: 22.05.2015 11:32:46
Habe noch bis 3Uhr Morgens versucht und versucht, leider ohne Erfolg.
Vielleicht findet sich ja noch jemand mit einer Blitzidee die das Problem löst.

Bild

Betrifft: AW: Kommentare mit Makro in Zelle einfügen
von: Torsten
Geschrieben am: 22.05.2015 11:34:52
Habe noch bis 3Uhr Morgens versucht und versucht, leider ohne Erfolg.
Vielleicht findet sich ja noch jemand mit einer Blitzidee die das Problem löst.

Bild

Betrifft: AW: Kommentare mit Makro in Zelle einfügen
von: Daniel
Geschrieben am: 22.05.2015 16:23:55
Hi
der code von Gerd sollte schon funktionieren, aber er hat ne kleinigkeit vergessen:
...
On Error Resume Next
sAlt = ""
sAlt = .Comment.Text
on Error Goto 0
If sAlt = "" Then .AddComment
...

das sAlt muss bei jedem Schleifendurchlauf erstmal wieder auf "" gesetzt werden, sonst nimmst du ja den Inhalt des Vorgängerkommentars in den nächsten Kommentar mit.
Gruß Daniel

Bild

Betrifft: AW: Kommentare mit Makro in Zelle einfügen
von: Torsten
Geschrieben am: 22.05.2015 16:58:55
Ach du liebes bisschen!
Es klappt ! Es Klappt !
DANKE GERD UND DANKE DANIEL !
Ein Hoch auf euch.
Ihr habt ja kein Gefühl wie glücklich ihr mich damit macht!
Vielen Dank! (Mache Freudensprünge)

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Kommentare mit Makro in Zelle einfügen"