Textmarke in Word aus Excel anspringen

Forumthread: Textmarke in Word aus Excel anspringen

14.03.2004 18:25:54

Fritz Sanne

Liebe Helfer.
Trotz Suche in meinen Büchern und im Archiv kriege ich es nicht gebacken (dabei habe ich es schon mal vor drei Jahren oder so geschafft), aus Excel heraus eine Textmarke in einer Word-Vorlage anzuspringen.
Seht Euch doch bitte mal an, was mir da fehlt.
Ich danke schon mal.


Sub ZellenInBericht()
Dim wd As Object
Dim wdbericht As Object
Set wd = CreateObject("word.application")
Set wdbericht = wd.documents.Open _
("c:\Windows\Desktop\bericht.dot")
wd.Visible = True
Sheets("Daten").Activate
wordDoc.bookmarks("Geschlecht").Range = _
ActiveCell.Offset(0, 23).Value
'''''''Fehler 424: Object erforderlich
'Selection.Goto what:=wdgotobookmark, Name:="Geschlecht"
'Fehler
End Sub

Fritz

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Textmarke in Word aus Excel anspringen

14.03.2004 18:32:58

Ramses
AW: Textmarke in Word aus Excel anspringen

14.03.2004 18:39:13

Fritz Sanne
Merci ;-))). Geschlossen o.T.

14.03.2004 18:41:57

Ramses

AW: Textmarke in Word aus Excel anspringen

14.03.2004 18:32:58

Ramses

Hallo
hier noch mal ein Code den du sicher anpassen kannst

Sub Word_Dokument_von_Excel_aus_steuern()
Dim myWord As Object
'Fehlerroutine für die Objectabfrage aktivieren
On Error Resume Next
'Abfragen einer besthenden WORD-Instanz um wiederholtes starten zu verhindern
'9 = Word 2000, 10 = Word XP
Set myWord = GetObject("Word.Application.10")
If Err.Number <> 0 Then
    'Fehlervariable leeren wenn Instanz noch nicht besteht
    Err.Clear
    'Zuweisung der Instanz
    Set myWord = CreateObject("Word.Application.10")
    'Instanz öffnen
    'Um das ganze etwas im Hintergrund laufen zu lassen
    'kann man den Status "wdWindowStateMinimize" verwenden
    myWord.Visible = True: myWord.WindowState = wdWindowStateMaximize
Else
    'Instanz besteht bereits
    myWord.Activate
    'Instanz in der Vordergrund bringen oder
    'mit "wdWindowStateMinimize" im Hintergrund ausführen
    myWord.Visible = True: myWord.WindowState = wdWindowStateMaximize
End If
'Hier muss der der Dateiname stehen der verwendet werden soll
'Es sollte aber eine Dokumentvorlage verwendet werden
'um keine Änderungen an den Textmarken beim einfügen zu verursachen
myWord.Application.Documents.Open "C:\Test.doc"
'Die Textmarken "a1, a2, a3" müssen im Dokument bereits bestehen
'Dann werden nach dem öffnen des Dokuments die Werte von Tabelle1
'A1, B1 und C1 in die jeweiligen Textmarken geschrieben
myWord.ActiveDocument.Bookmarks("a1").Range.Text = Worksheets("Tabelle1").Range("A1")
myWord.ActiveDocument.Bookmarks("a2").Range.Text = Worksheets("Tabelle1").Range("B1")
myWord.ActiveDocument.Bookmarks("a3").Range.Text = Worksheets("Tabelle1").Range("C1")
'oder nur immer die Daten aus der aktuell markierten Zeile
'myWord.ActiveDocument.Bookmarks("a1").Range.Text = Worksheets("Tabelle1").Cells(ActiveCell.Row,1)
'myWord.ActiveDocument.Bookmarks("a2").Range.Text = Worksheets("Tabelle1").Cells(ActiveCell.Row,2)
'myWord.ActiveDocument.Bookmarks("a3").Range.Text = Worksheets("Tabelle1").Cells(ActiveCell.Row,3)
'-
'Das aktive WordDokument drucken
myWord.ActiveDocument.PrintOut
'Dokument schliessen ohne speichern
myWord.ActiveDocument.Close savechanges:=False
'---
'Speichern mit fixem Namen
'myWord.ActiveDocument.SaveAs Filename:="DokumentName", FileFormat:=wdFormatDocument
'Speichern mit Variable
'myWord.ActiveDocument.SaveAs Filename:=Variable, FileFormat:=wdFormatDocument
'---
'WORD-Instanz schliessen
myWord.Application.Quit (True)
'Variable leeren
Set myWord = Nothing
End Sub

Code eingefügt mit Syntaxhighlighter 2.5

Gruss Rainer

Beliebteste Forumthreads (12 Monate)

Textmarke in Word aus Excel anspringen

Forumthread: Textmarke in Word aus Excel anspringen

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread